Replace the 2 mouse buttons with 2 keys on keyboard?

[bobbyab9987]

Hi guys,

I would like to replace totally the 2 mouse buttons with 2 arbitrary keys on keyboard. By "totally" I mean not just replace "mouse click" but also replace "mouse down" as well.

So far I succeeded in replacing "mouse click" like this:

HotKeySet("`", "_left_mouse_click")

Func _left_mouse_click()

    ; Unset the HotKey
    HotKeySet("`") ; prevent hotkey recursion
    
    MouseClick($MOUSE_CLICK_LEFT)

    ; And now reset the HotKey
    HotKeySet("`", "_left_mouse_click")
    
EndFunc

However I couldn't do the same with "mouse down", I tried the following but it didn't work:

HotKeySet("{` down}", "_left_mouse_down")

Func _left_mouse_down()

    ; Unset the HotKey
    HotKeySet("{` down}") ; prevent hotkey recursion
    
    MouseDown($MOUSE_CLICK_LEFT) 

    ; And now reset the HotKey
    HotKeySet("{` down}", "_left_mouse_down")
    
EndFunc

In the function _left_mouse_down() above, I also tried removing the unset / reset statements, but it didn't work neither.

Is it even possible to replace "mouse down" with an arbitrary "key down" using AutoIt?

Thank you.

[MrCreatoR]

Once you press ` key, it sends MouseDown event.

Until you release the mouse button (MouseUp) it will be held down, so there is no point of press it down all the time, you do it only once.

 

Why you need to keep pressing the MouseDown button? It's either down or clicked.

Edited April 19, 2020 by MrCreatoR

[MrCreatoR]

Maybe something lkie this:

#include <Misc.au3>

Global $hUser32 = DllOpen('user32.dll')

HotKeySet('{ESC}', _KeyPressedDummy)
HotKeySet('`', _KeyPressedDummy)

While 1
    Sleep(10)
    
    If _IsPressed('C0', $hUser32) Then ;` key
        MouseDown('Main')
        
        While _IsPressed('C0', $hUser32)
            Sleep(10)
        WEnd
        
        MouseUp('Main')
    EndIf
WEnd

Func _KeyPressedDummy()
    If @HotKeyPressed = '{ESC}' Then
        Exit
    EndIf
EndFunc

 

Edited April 19, 2020 by MrCreatoR

[Nine]

Or this similar approach :

#include <Constants.au3>
#include <Misc.au3>

Global $bDown = False

HotKeySet ("{ESC}", _Exit)
HotKeySet("{« down}", "_left_mouse_down")

WinActivate ("Some Window")

While True
  Sleep (100)
WEnd

Func _left_mouse_down()
  ConsoleWrite ("test" & @CRLF)
  If $bDown Then Return
  $bDown = True
  MouseDown($MOUSE_CLICK_LEFT)
  While _IsPressed ("E2")
    Sleep (10)
  WEnd
  MouseUp($MOUSE_CLICK_LEFT)
  $bDown = False
EndFunc

Func _Exit ()
  Exit
EndFunc

Note : changed the hot key

[bobbyab9987]

@Nine: Thank you very much, I am testing your solution, it's working great! It can perform both clicking and dragging flawlessly in various applications.

@MrCreatoR: Thank you for your solution. I will try yours if Nine's solution fails (it is working great but in some edge cases something might be broken I don't know...). As for your question, well, my ultimate goal is to replace the 2 mouse buttons totally, and hence the solution must be able to replace not only mouse clicking but also mouse dragging.