Copy Listview data to clipboard - (Moved)

[KfirAsulin]

Hello,

I would like to copy a list view and past it ( to word or outlook) so it is pasted as a table - the same way it is presented in the control.

 

[Melba23]

Moved to the appropriate forum, as the AutoIt Example Scripts forum very clearly states:

Quote

Share your cool AutoIt scripts, UDFs and applications with others.

---

Do not post general support questions here, instead use the AutoIt Help and Support forums.

Moderation Team

[Nine]

What have you tried so far ?  Maybe copy/paste is not the best approach, hard to say.  What is the source ListView, your own GUI or another application.  Please post the code you have, so we can understand your issue.

[KfirAsulin]

I start with creating a list vew as follows:

    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")........

....

....

 

Then, after the list view has values, I would like to copy its data and paste it (to Word Document) so the data will show also as a table (like a table created by Word).

Is it possible?

 

[Nine]

I think that the easiest approach is to parse your entire List View into a 2D array and use Word UDF _Word_DocTableWrite function to write it at once into a document. 

 

 

[MrCreatoR]

3 hours ago, Nine said:

easiest approach is to parse your entire List View into a 2D array and use Word UDF _Word_DocTableWrite function to write it at once into a document

Yep, something like this:

 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <Word.au3>

Global $sFile = @DesktopDir & '\Test.doc'

$hGUI = GUICreate('Test', 240, 300)

$iLV = GUICtrlCreateListView('Col1|Col2|Col3', 20, 20, 200, 240)

For $i = 1 To 10
    GUICtrlCreateListViewItem('Item' & $i & '|SubItem 1|SubItem 2', $iLV)
Next

$iCopy_Bttn = GUICtrlCreateButton('Copy to word', 20, 270, 80, 20)
$iStatus_Lbl = GUICtrlCreateLabel('', 110, 273, 100, 15)
GUICtrlSetColor(-1, 0xFF0000)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $iCopy_Bttn
            Local $iCount = _GUICtrlListView_GetItemCount($iLV)
            Dim $aTable[$iCount][3] = [[$iCount]]
            
            For $i = 0 To $iCount - 1
                For $j = 0 To 2
                    $aTable[$i][$j] = _GUICtrlListView_GetItemText($iLV, $i, $j)
                Next
            Next
            
            GUICtrlSetData($iStatus_Lbl, 'Please wait...')
            FileClose(FileOpen($sFile, 2)) ;2 - Rewrite, use 1 to append
            
            Local $oWord = _Word_Create(False, True)
            Local $oDoc = _Word_DocOpen($oWord, $sFile)
            Local $oRange = _Word_DocRangeSet($oDoc, -2)
            
            _Word_DocTableWrite($oRange, $aTable, 0)
            _Word_DocClose($oDoc, $WdSaveChanges)
            _Word_Quit($oWord)
            
            GUICtrlSetData($iStatus_Lbl, '')
    EndSwitch
WEnd

But still it's also interesting for me to find a way to actually put the table to the clipboard (as RTF format for example) without using external tools.

[Skysnake]

Try this