(Solved) Blocking Address via Hosts file

[Exit]

or the short version:

; disable "www.facebook.com"
#RequireAdmin
$sURL = "www.facebook.com"
$sHostsFile = @WindowsDir & "\system32\drivers\etc\hosts"
$iReadonly = StringInStr(FileGetAttrib($sHostsFile), "R")
If $iReadonly Then FileSetAttrib($sHostsFile, "-R")
If Not StringInStr(FileRead($sHostsFile), $sURL) Then FileWrite($sHostsFile, @CRLF & "127.0.0.1" & @TAB & @TAB & $sURL & @CRLF)
If $iReadonly Then FileSetAttrib($sHostsFile, "+R")
ShellExecute("Notepad.exe", $sHostsFile)

 

[PHAK]

@Exit

1

I did run from a desktop

Because you asked for a consul I put in C

2

I did what you brought

You are a king 😃👍

The problem seems to have been

hosts

The file is write-protected.
3

I did not want him to open Notepad

So I deleted the lines below

; disable "www.facebook.com"
#RequireAdmin
$sURL = "www.facebook.com"
$sHostsFile = @WindowsDir & "\system32\drivers\etc\hosts"

ConsoleWrite(@CRLF & "Admin rights are " & (IsAdmin() ? "" : "NOT ") & "detected." & @CRLF & @CRLF)
ConsoleWrite($sHostsFile & " is " & (StringInStr(FileGetAttrib($sHostsFile), "R") ? "readonly." : "writable.") & @CRLF & @CRLF)

$sText = FileRead($sHostsFile)
ConsoleWrite("Error: " & @error & " Extended: " & @extended & " Line: " & @ScriptLineNumber & @CRLF & @CRLF & $sText & @CRLF & @CRLF)

If StringInStr($sText, $sURL) Then
    ConsoleWrite("URL already present" & @CRLF)
Else
    $iReadonly = StringInStr(FileGetAttrib($sHostsFile), "R")
    If $iReadonly Then FileSetAttrib($sHostsFile, "-R")
    ConsoleWrite($sHostsFile & " is " & (StringInStr(FileGetAttrib($sHostsFile), "R") ? "readonly." : "writable.") & @CRLF & @CRLF)
    $rc = FileWrite($sHostsFile, @CRLF & "127.0.0.1" & @TAB & @TAB & $sURL & @CRLF)
    ConsoleWrite("Error: " & @error & " Extended: " & @extended & " Line: " & @ScriptLineNumber & " RC: " & $rc & @LF)
    If $iReadonly Then FileSetAttrib($sHostsFile, "+R")
    ConsoleWrite($sHostsFile & " is " & (StringInStr(FileGetAttrib($sHostsFile), "R") ? "readonly." : "writable.") & @CRLF & @CRLF)
    $sText = FileRead($sHostsFile)
    ConsoleWrite("Error: " & @error & " Extended: " & @extended & " Line: " & @ScriptLineNumber & @CRLF & @CRLF & $sText & @CRLF & @CRLF)
EndIf

 

Now there is another problem
Going down a row
And he put a profit

Example

127.0.0.1 prod.adobegenuine.com

127.0.0.1        www.facebook.com

There is something to do?

It does not bother
But if there is a solution I would be happy 😀

[GokAy]

If I understand you correctly, change this line

    $rc = FileWrite($sHostsFile, @CRLF & "127.0.0.1" & @TAB & @TAB & $sURL & @CRLF)

to include extra CRLF's

    $rc = FileWrite($sHostsFile, @CRLF & @CRLF & "127.0.0.1" & @TAB & @TAB & $sURL & @CRLF & @CRLF)

Edited December 23, 2020 by GokAy

[Exit]

13 hours ago, PHAK said:

Now there is another problem
Going down a row
And he put a profit

We have a language barrier here.
I can't understand the word profit.
Can you describe the problem in your language?
I will then translate it into German.

[Jos]

26 minutes ago, Exit said:

I can't understand the word profit.

advance...extra tabs...????

[PHAK]

@Exit @GokAy

I got along

I had to remove

@CRLF  @TAB

It's revised

; disable "www.facebook.com"
#RequireAdmin
$sURL = "www.facebook.com"
$sHostsFile = @WindowsDir & "\system32\drivers\etc\hosts"
$iReadonly = StringInStr(FileGetAttrib($sHostsFile), "R")
If $iReadonly Then FileSetAttrib($sHostsFile, "-R")
If Not StringInStr(FileRead($sHostsFile), $sURL) Then FileWrite($sHostsFile, @CRLF & "127.0.0.1" & @TAB & $sURL )
If $iReadonly Then FileSetAttrib($sHostsFile, "+R")

Thank you all

[PHAK]

enable www.facebook.com

how do I do it?

[spudw2k]

By enable, you mean remove it from the hosts file / undo adding it?

You could either get fancy with some regex, or check line by line.

[Exit]

; enable "www.facebook.com"
#RequireAdmin
#include <Array.au3>
$sURL = "www.facebook.com"
$sHostsFile = @WindowsDir & "\system32\drivers\etc\hosts"
$iReadonly = StringInStr(FileGetAttrib($sHostsFile), "R")
If $iReadonly Then FileSetAttrib($sHostsFile, "-R")
$aFile = FileReadToArray($sHostsFile)
For $i = @extended - 1 To 0 Step -1
    If StringInStr($aFile[$i], $surl) Then _ArrayDelete($aFile, $i)
Next
FileDelete($sHostsFile)
FileWrite($sHostsFile,_ArrayToString($aFile,@CRLF))
If $iReadonly Then FileSetAttrib($sHostsFile, "+R")

 

[PHAK]

2 hours ago, Exit said:

; enable "www.facebook.com"
#RequireAdmin
#include <Array.au3>
$sURL = "www.facebook.com"
$sHostsFile = @WindowsDir & "\system32\drivers\etc\hosts"
$iReadonly = StringInStr(FileGetAttrib($sHostsFile), "R")
If $iReadonly Then FileSetAttrib($sHostsFile, "-R")
$aFile = FileReadToArray($sHostsFile)
For $i = @extended - 1 To 0 Step -1
    If StringInStr($aFile[$i], $surl) Then _ArrayDelete($aFile, $i)
Next
FileDelete($sHostsFile)
FileWrite($sHostsFile,_ArrayToString($aFile,@CRLF))
If $iReadonly Then FileSetAttrib($sHostsFile, "+R")

 

Excellent
Amazing
This is what I wanted
Thank you
Champion