Capturing Output from Powershell

[DigDeep]

Hi,

I have a Powershell script which I cannot capture output in any external format of text or any other file and I want AutoIT to read the Output ($Result). Is that doable?

Powershell Output capture:

if ($data -match $GetOps) {
  $Result = "True"
}
ELse{
  $Result = "False"
}

 

AutoIT:

Local $PScript = "C:\Test.ps1"
Local $Txt = "", $sSTDout = ""
Local $RunCMD = "C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe -command . '" & $PScript & "'"
Local $pid = Run($RunCMD, @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)
    StdinWrite($pid)

    $GetOutput = StdoutRead($pid)
    While 1
        $GetOutput = StdoutRead($pid)
            If @error Then ExitLoop
        If $GetOutput <> "" Then
            MsgBox("", "", $GetOutput)
        EndIf
    WEnd

Problem is running this, I am able to capture the Powershell PID but not the output.

Please help...

Edited February 8, 2022 by DigDeep

[water]

I use the following code to grab the output of a PS script:

$sCMD = "C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe -file " & @ScriptDir & "\NM.ps1"
    $pid = Run($sCMD, @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)
    StdinWrite($pid, @CRLF) ; Close STDIN
    StdinWrite($pid)
    ; Get output from STDOUT
    $sSTDOUT = ""
    While 1
        $sOutput = StdoutRead($pid)
        If @error Then ExitLoop
        If $sOutput <> "" Then $sSTDOUT = $sSTDOUT & @CRLF & $sOutput ; Drops empty lines
    WEnd
    ; Get output from STDERR
    $sSTDERR = ""
    While 1
        $sOutput = StderrRead($pid)
        If @error Then ExitLoop
        If $sOutput <> "" Then $sSTDERR = $sSTDERR & @CRLF & $sOutput ; Drops empty lines
    WEnd

 

[nikink]

What about from a ps commandline?

I have a PShell function I want to pass commands to, and return the PS console output.

Like so:

PShell_ConsoleCapture("Get-ADComputer -Identity PC-Name") ; example PS only

Func PShell_ConsoleCapture($sCmdline)
    $sCMD = "C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe -command " & $sCmdline
    $pid = Run($sCMD, @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)
    StdinWrite($pid, @CRLF) ; Close STDIN
    StdinWrite($pid)
    ; Get output from STDOUT
    $sSTDOUT = ""
    While 1
        $sOutput = StdoutRead($pid)
        If @error Then ExitLoop
        If $sOutput <> "" Then $sSTDOUT = $sSTDOUT & @CRLF & $sOutput ; Drops empty lines
    WEnd
    ; Get output from STDERR
    $sSTDERR = ""
    While 1
        $sOutput = StderrRead($pid)
        If @error Then ExitLoop
        If $sOutput <> "" Then $sSTDERR = $sSTDERR & @CRLF & $sOutput ; Drops empty lines
    WEnd
    ConsoleWrite("Output:" & @CRLF & $sOutput)
    ConsoleWrite("$sSTDERR:" & @CRLF & $sSTDERR)
    Return
EndFunc

Neither $sOutput nor $sSTDERR contain data.

Any help would be appreciated.

[jugador]

@nikink

__ExampleA()
Func __ExampleA()
    Local $o_CmdString = ' -command get-module -listavailable'
    Local $o_powershell = "C:\Windows\System32\WindowsPowerShell\v1.0\powershell.exe"
    Local $o_Pid = Run($o_powershell & $o_CmdString, '', @SW_Hide, $STDERR_CHILD + $STDOUT_CHILD)
    ProcessWaitClose($o_Pid)

    Local $o_Output = StdoutRead($o_Pid)
    ConsoleWrite($o_Output & @CRLF)
EndFunc