ByRef Bug

[jugador]

cant pass value as dot notation if it's ByRef.

__ExampleA()
Func __ExampleA()
    ;~ AutoIt version: 3.3.14.5
    Local $o_SDist = ObjCreate( "Scripting.Dictionary" )
    $o_SDist.Add("keyA", "Apple")

    ;~ getting Error
    ;~ can't pass value this way if its Byref
    ;__Byref_Bug($o_SDist.Item( 'keyA' ))   ;<= uncomment this line

    Local $aValue = $o_SDist.Item( 'keyA' )
    __Byref_Bug($aValue)

    __Print($o_SDist.Item( 'keyA' ))
    $o_SDist = 0
EndFunc

Func __Byref_Bug(Byref $Value)
    ConsoleWrite('- ' & $Value & @Crlf)
EndFunc

Func __Print($Value)
    ConsoleWrite('> ' & $Value & @Crlf)
EndFunc

 

[argumentum]

4 hours ago, jugador said:

    ;~ getting Error
    ;~ can't pass value this way if its Byref
    ;__Byref_Bug($o_SDist.Item( 'keyA' ))   ;<= uncomment this line

Is not a bug. You are not referencing an object.

Edit: Maybe this can help you ?

__ExampleA()
Func __ExampleA()

    Local $o_SDist = ObjCreate( "Scripting.Dictionary" )
    $o_SDist.Add("keyA", "Apple")

    ;~ getting Error
    ;~ can't pass value this way if its Byref ; so don't ?
    __Byref_ExBug($o_SDist.Item( 'keyA' ))
    
    __Byref_func($o_SDist, "keyA")

    Local $aValue = $o_SDist.Item( 'keyA' )
    __Byref_func($aValue)

    __Print($o_SDist.Item( 'keyA' ))
    $o_SDist = 0
EndFunc

Func __Byref_func(Byref $Value, $sItem = Default)
    If $sItem = Default Then
        ConsoleWrite('- ' & $Value & @Crlf)
    ElseIf IsObj($Value) Then
        ConsoleWrite('--- ' & $Value.Item($sItem) & @Crlf)
    EndIf
EndFunc

Func __Byref_ExBug(Const $Value) ; meh, if you wanna have a declaration ?
    ConsoleWrite('- ' & $Value & @Crlf)
EndFunc

Func __Print($Value)
    ConsoleWrite('> ' & $Value & @Crlf)
EndFunc

 

Edited January 21 by argumentum
added the code

[jugador]

@argumentum It's not about Scripting.Dictionary 

try sending any abject / value as dot notation you will get error if its Byref

If you remove the Byref option then it's ok.
or if you make a Local copy before sending to Byref then it's ok.

So are you sure it's not Byref bug?
Op example perfectly demonstrate what I want to say 

[Nine]

As per help file :

Quote

Note that not only a named variable can be passed for a ByRef parameter - unnamed temporary variables, such as function return values, may be passed as ByRef parameters as well.

I would not consider it a bug but a well known documented limitation...

[argumentum]

3 hours ago, jugador said:

If you remove the Byref option then it's ok.

ByRef is to change the variable/object in the function and keep the change of the value passed to it.
If you pass a value of it ( $object.item('KeyA') ) then is not by ref. as autoit can not know how to handle each object that you ObjCreate().

I don't see it as a bug, and would not know how to write AutoIt3 to do what you want to have, because I can't imagine a logic for it. My 2 cents

[jchd]

Isn't precisely that the whole purpose for object encapsulation in OO paradigm: manipulating (esp. updating) members can only be done thru the object public interface?

AutoIt can't determine by itself that a Scripting.Dictionary object offers a method to update a value, when AutoIt only gets a reference to the variant containing the value.

OTOH objects known to AUtoIt pose no issue AFAICT:

Local $m[]
$m.Prime = "abc"
$m.Second = "def"

_ChangeMe($m.Prime)
ConsoleWrite($m.Prime & @LF)

Func _ChangeMe(ByRef $v)
    $v &= " whatever"
EndFunc

 

[TheDcoder]

@jchd I don't think they are trying to actually manipulate the value though.

Several years ago I encountered a similar problem with ByRef but it could be solved by simply treating the ByRef parameter like a normal non-ref one. So this is not a bug but could be a useful "feature" that can be added.

[jchd]

OK but even reading the value without knowing which method to use is impossible for objects not known to AutoIt itself.

Create a library with an object MyThing having a private member GetIt whose purpose is to send a command to a USB device requesting it to respond with a pressure value and the method returning this value.

How can you give AutoIt a reference to the value?

In case of a Map and since it's an object known to AutoIt, it's possible for the core to invoke the Item method for both read and write, just because it knows that's the correct thing to do.

[TheDcoder]

13 minutes ago, jchd said:

OK but even reading the value without knowing which method to use is impossible for objects not known to AutoIt itself.

There's no question of reading the value, the function totally disregards byref if the supplied expression is not a value that can be referenced

[jchd]

49 minutes ago, TheDcoder said:

the function totally disregards byref if the supplied expression is not a value that can be referenced

So what gets passed as argument to the function?

[TheDcoder]

4 hours ago, jchd said:

So what gets passed as argument to the function?

Same as what gets passed if the parameter weren't a byref

[jchd]

Call that a copy to a local variant. And then if you update it, what gives?

[TheDcoder]

@jchd I'm afraid I don't really understand what you said, but it sounds about right... except for the part about copying, I don't see why that's necessary since it is already in the memory and not used by anything else, so just use that directly instead.

All "updates" would be gone because the function would clean up all of the local variables.