_FileListToArray versus _FileListToArrayRec

[mr-es335]

Good day,

A query...if I may..."Can _FileListToArray not be deployed in the same manner as _FileListToArrayRec?"

For example...from this...

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    $aFiles = _FileListToArrayRec("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_NOSORT, $FLTAR_FULLPATH)
    For $i = 1 To $aFiles[0]
        FileDelete($aFiles[$i])
    Next
EndFunc   ;==>example

...to this...

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    $aFiles = _FileListToArray("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES)
    For $i = 1 To $aFiles[0]
        FileDelete($aFiles[$i])
    Next
EndFunc   ;==>example

The former works, whilst the latter does not work.

Thanks!

Edited September 16, 2024 by mr-es335

[Andreik]

_FileListToArrayRec() search recursively for files in subdirectories and _FileListToArray() does not.

[mr-es335]

ioa747,

What if I do not need to perform a recursive operation?

For whatever reason, I cannot get the _FileListToArray() to work!!!

Any ideas?

 

[water]

What does "does not work" exactly mean? Do you get no result, missing data, error code ...?
The more information you can provide the easier it is for us to help you

[mr-es335]

water,

This example does absolutely nothing!

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    $aFiles = _FileListToArray("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES)
    For $i = 1 To $aFiles[0]
        FileDelete($aFiles[$i])
    Next
EndFunc   ;==>example

 

[ioa747]

in the former
you have the parameter $FLTAR_FULLPATH

in the latter not
and you don't give proper path

FileDelete("C:\RML\SAC\VST_PlugIns\" & $aFiles[$i])

Edit:
try and you will see

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    $aFiles = _FileListToArray("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES)
    For $i = 1 To $aFiles[0]
;~         FileDelete($aFiles[$i])
        ConsoleWrite($i & ") FileDelete: " & $aFiles[$i] & @CRLF)
    Next
EndFunc   ;==>example

 

Edit:
The right would be with $bReturnPath = True

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    
    ;_FileListToArray ( $sFilePath [, $sFilter = "*" [, $iFlag = $FLTA_FILESFOLDERS [, $bReturnPath = False]]] )

    $aFiles = _FileListToArray("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES, True)
    For $i = 1 To $aFiles[0]
;~         FileDelete($aFiles[$i])
        ConsoleWrite($i & ") FileDelete: " & $aFiles[$i] & @CRLF)
    Next
EndFunc   ;==>example

or without $bReturnPath = True  which entails with  $bReturnPath = False

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    
    ;_FileListToArray ( $sFilePath [, $sFilter = "*" [, $iFlag = $FLTA_FILESFOLDERS [, $bReturnPath = False]]] )

    $aFiles = _FileListToArray("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES)
    For $i = 1 To $aFiles[0]
;~         FileDelete($aFiles[$i])
        ConsoleWrite($i & ") FileDelete: " & "C:\RML\SAC\VST_PlugIns\" & $aFiles[$i] & @CRLF)
    Next
EndFunc   ;==>example

 

which could also be done with _FileListToArrayRec
with changing the parameter  $iRecur from $FLTAR_RECUR  to  FLTAR_NORECUR

#include <Constants.au3>
#include <File.au3>

example()

Func example()
    Local $aFiles[0]
    $aFiles = _FileListToArrayRec("C:\RML\SAC\VST_PlugIns", "*", $FLTAR_FILES,  $FLTAR_NORECUR, $FLTAR_NOSORT, $FLTAR_FULLPATH)
    For $i = 1 To $aFiles[0]
        FileDelete($aFiles[$i])
    Next
EndFunc   ;==>example

 

Edited September 16, 2024 by ioa747

[water]

One of my coding rules is to check the return value or error code after each call of an AutoIt function.
FileDelete returns 1 on success and 0 if there was a problem.

[ioa747]

3 hours ago, mr-es335 said:

ioa747,

What if I do not need to perform a recursive operation?

check again
https://www.autoitscript.com/forum/topic/212281-_filelisttoarray-versus-_filelisttoarrayrec/#comment-1536873