Add a visual counter to a loop!

[mr-es335]

Good day,

I require a visual counter to the following:

Func ViewCustomCmdsList()
    WinActivate($hSAWSTUDIO_MAIN)
    ; -----------------------------------------------
    ; Select Custom Cmds button
    Sleep($iTimeOut)
    MouseClick($MOUSE_CLICK_LEFT, 250, 378, 1, 0)
    Sleep(1000)
    ; ---------------------
    ; Select each Cmd in turn
    Sleep($iTimeOut)
    Send("{DOWN +3}")
    For $i = 2 To 26
            Sleep($iDelayTime)
        Send("{DOWN}")
    Next
    ; ---------------------
    Sleep(1000)
    Send("{ESC}")
EndFunc   ;==>ViewCustomCmdsList

Any ideas?

[ioa747]

Func ViewCustomCmdsList()
    WinActivate($hSAWSTUDIO_MAIN)
    ; -----------------------------------------------
    ; Select Custom Cmds button
    Sleep($iTimeOut)
    MouseClick($MOUSE_CLICK_LEFT, 250, 378, 1, 0)
    Sleep(1000)
    ; ---------------------
    ; Select each Cmd in turn
    Sleep($iTimeOut)
    Send("{DOWN +3}")
    For $i = 2 To 26
            ToolTip(" from 26", -1, -1, $i )
            Sleep($iDelayTime)
        Send("{DOWN}")
    Next
    ; ---------------------
    ToolTip("")
    Sleep(1000)
    Send("{ESC}")
EndFunc   ;==>ViewCustomCmdsList

 Merry Christmas and a happy new year

🎄

[mr-es335]

ioa747,

With  bit of "tweaking"...

Func ViewCustomCmdsList()
    WinActivate($hSAWSTUDIO_MAIN)
    ; -----------------------------------------------
    ; Select Custom Cmds button
    Sleep($iTimeOut)
    MouseClick($MOUSE_CLICK_LEFT, 250, 378, 1, 0)
    Sleep(1000)
    ; ---------------------
    ; Select each Cmd in turn
    Sleep($iTimeOut)
    Send("{DOWN +3}")
    For $i = 2 To 27
        Sleep($iTimeOut)
        ToolTip($i & " of 27", 450, 440)
        Sleep($iDelayTime)
        Send("{DOWN}")
    Next
    ; ---------------------
    ToolTip("")
    Sleep(1000)
    Send("{ESC}")
EndFunc   ;==>ViewCustomCmdsList
; -----------------------------------------------

...and the very, very same to you, iao747!!

[Gianni]

... or also with two counters ... one of which is a little more "visual"

#include <WindowsStylesConstants.au3>

Func ViewCustomCmdsList()
    Local $hwnd = GUICreate("", 200, 30, -1, -1, $WS_POPUP)
    Local $hwPrg = GUICtrlCreateProgress(0, 0, 200, 30)
    GUISetState(@SW_SHOWNOACTIVATE, $hwnd)
    WinActivate($hSAWSTUDIO_MAIN)
    ; -----------------------------------------------
    ; Select Custom Cmds button
    Sleep($iTimeOut)
    MouseClick($MOUSE_CLICK_LEFT, 250, 378, 1, 0)
    Sleep(1000)
    ; ---------------------
    ; Select each Cmd in turn
    Sleep($iTimeOut)
    Send("{DOWN +3}")
    For $i = 2 To 27
        Sleep($iTimeOut)
        ToolTip($i & " of 27", 450, 440)
        GUICtrlSetData($hwPrg, $i * (100 / 27))
        Sleep($iDelayTime)
        Send("{DOWN}")
    Next
    ; ---------------------
    ToolTip("")
    GUIDelete($hwnd)
    Sleep(1000)
    Send("{ESC}")
EndFunc   ;==>ViewCustomCmdsList
; -----------------------------------------------

 

[Nine]

Or this simple :

Example()

Func Example()
  Local Const $iTimeOut = 250, $iDelayTime = 150, $iLen = 27
  SplashTextOn("Counter", "Starting", 150, 60, -1, -1, Default, "Arial", 14)
  Sleep($iTimeOut)
  For $i = 2 To $iLen
    Sleep($iTimeOut)
    ControlSetText("Counter", "", "Static1", $i & " out of " & $iLen)
    Sleep($iDelayTime)
  Next
  SplashOff()
EndFunc   ;==>Example