Radiobutton Help

[spudw2k]

Is there a way to make a radiobuttons not affect each other? I want a form that has multiple radio buttons that do not alter each other's selection. So radiobuttons that act like checkboxes, that make sense?

[covaks]

Maybe something like this:

expandcollapse popup

#include <GuiConstants.au3>

$hWnd = GuiCreate("")

Dim $radio[6]

$group_1 = GUICtrlCreateGroup ("Group 1", 30, 90, 165, 160)
GUIStartGroup()
$radio[0] = GUICtrlCreateRadio ("Radio &0", 50, 120, 70, 20)
GUIStartGroup()
$radio[1] = GUICtrlCreateRadio ("Radio &1", 50, 150, 60, 20)
GUIStartGroup()
$radio[2] = GUICtrlCreateRadio ("Radio &2", 50, 180, 60, 20)
GUIStartGroup()
$radio[3] = GUICtrlCreateRadio ("Radio &A", 120, 120, 70, 20)
GUIStartGroup()
$radio[4] = GUICtrlCreateRadio ("Radio &B", 120, 150, 60, 20)
GUIStartGroup()
$radio[5] = GUICtrlCreateRadio ("Radio &C", 120, 180, 60, 20)
GUIStartGroup()


GuiSetState()

While 1
    
    $msg = GuiGetMsg()
    
    Switch $msg
        Case -3
            ExitLoop
        Case $radio[0], $radio[1], $radio[2], $radio[3], $radio[4], $radio[5]
            For $x = 0 to 5
                If $msg = $radio[$x] Then 
                Else
                    GUICtrlSetState($radio[$x],$GUI_UNCHECKED)
                EndIf
            Next
    EndSwitch
WEnd

[spudw2k]

No, same effect.

[covaks]

Oh geez. Sorry, total brainfart there. That does exactly what the default behaviour does. lol. Try this:

expandcollapse popup

#include <GuiConstants.au3>

$hWnd = GuiCreate("")

Dim $radio[6]
Dim $bState[6]

For $x = 0 to 5
    $bState[$x] = False
Next

$group_1 = GUICtrlCreateGroup ("Group 1", 30, 90, 165, 160)
GUIStartGroup()
$radio[0] = GUICtrlCreateRadio ("Radio &0", 50, 120, 70, 20)
GUIStartGroup()
$radio[1] = GUICtrlCreateRadio ("Radio &1", 50, 150, 60, 20)
GUIStartGroup()
$radio[2] = GUICtrlCreateRadio ("Radio &2", 50, 180, 60, 20)
GUIStartGroup()
$radio[3] = GUICtrlCreateRadio ("Radio &A", 120, 120, 70, 20)
GUIStartGroup()
$radio[4] = GUICtrlCreateRadio ("Radio &B", 120, 150, 60, 20)
GUIStartGroup()
$radio[5] = GUICtrlCreateRadio ("Radio &C", 120, 180, 60, 20)
GUIStartGroup()


GuiSetState()

While 1
   
    $msg = GuiGetMsg()
   
    Switch $msg
        Case -3
            ExitLoop
        Case $radio[0], $radio[1], $radio[2], $radio[3], $radio[4], $radio[5]
            For $x = 0 to 5
                If $msg = $radio[$x] Then
                    $bState[$x] = Not $bState[$x]
                    If $bState[$x] = False Then
                        GUICtrlSetState($radio[$x],$GUI_UNCHECKED)
                    EndIf
                EndIf
            Next
    EndSwitch
WEnd

[spudw2k]

Sho nuff. That works. Now to convert my radio buttons into an array. Thanks