Copy and Past from GUICtrlCreateList

[water]

I have created a GUI that lets me select one or more entries.

What needs to be done that the selected lines can be copied to the clipboard using CTRL-C?

Thanks in advance

Thomas

[smashly]

Hi,

#include <GUIConstantsEx.au3>
#Include <GuiListBox.au3>
#Include <Misc.au3>

$hGui = GUICreate(":-)", 110, 100)
$List = GUICtrlCreateList("", 5, 5, 100, 90, $LBS_MULTIPLESEL)
GUICtrlSetData(-1, "Item 1|Item 2|Item 3|Item 4|Item 5")
GUISetState(@SW_SHOW, $hGui)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            If WinActive($hGui) And _IsPressed("11") And _IsPressed("43") Then 
                Local $aTxtSel = _GUICtrlListBox_GetSelItemsText($List), $sTmp = ''
                If $aTxtSel[0] Then
                    For $i = 1 To $aTxtSel[0]
                        $sTmp &= $aTxtSel[$i] & @CRLF
                    Next
                    ClipPut(StringStripWS($sTmp, 2))
                EndIf   
            EndIf           
    EndSwitch
WEnd

Cheers

[water]

Hi smashly,

Thanks for your fast reply! Works like a charm.

Greetings

Thomas

[rasim]

water

Also you may use a HotKeySet function instead of _IsPressed