Array Confusion

[TheDcoder]

Hello, I am having a problem with an array, here is the code:

#include <Array.au3>

Local $aAddNewFiles[4]

$aAddNewFiles[0] = 3 ; No. of files
$aAddNewFiles[1] = @DesktopDir & "FileX"
$aAddNewFiles[2] = @DesktopDir & "FileY"
$aAddNewFiles[3] = @DesktopDir & "FileZ"

Local $aAddNewFilesNames[$aAddNewFiles[0]] ; This array will contain File Names w/ Ext

For $i = 1 To UBound($aAddNewFiles) - 1
    $aAddNewFilesNames = StringRegExpReplace($aAddNewFiles[$i], "^.*\\", "") ; Extract File Name w/ Ext
Next

_ArrayDisplay($aAddNewFilesNames)

_ArrayDisplay sets @error to 1 (meaning $aAddNewFilesNames is not an array)

Thanks in advance, TD

Edited April 30, 2015 by TheDcoder

[ajag]

Hi TheDecoder,

$aAddNewFilesNames = StringRegExpReplace(...)

 I think StringRegExpReplace returns a string (not an array) so $aAddNewFilesNames contains a string and not an array.

Try

For $i = 1 To UBound($aAddNewFiles) - 1
    $aAddNewFilesNames[$i] = StringRegExpReplace($aAddNewFiles[$i], "^.*\\", "") ; Extract File Name w/ Ext
Next

btw:

$aAddNewFiles[1] = @DesktopDir & "FileX"

@DesktopDir does not contain a trailing backslash!

Ajag

 

 

Edited April 30, 2015 by ajag

[TheDcoder]

Thanks @ajag, Note the [$i]

TD

[Melba23]

TheDcoder,

Spot the differences:

#include <Array.au3>

Local $aAddNewFiles[4]

$aAddNewFiles[0] = 3 ; No. of files
$aAddNewFiles[1] = @DesktopDir & "\FileX"
$aAddNewFiles[2] = @DesktopDir & "\FileY"
$aAddNewFiles[3] = @DesktopDir & "\FileZ"

Local $aAddNewFilesNames[$aAddNewFiles[0] + 1] ; This array will contain File Names w/ Ext

For $i = 1 To UBound($aAddNewFiles) - 1
    $aAddNewFilesNames[$i] = StringRegExpReplace($aAddNewFiles[$i], "^.*\\", "") ; Extract File Name w/ Ext
Next

_ArrayDisplay($aAddNewFilesNames)

M23

[TheDcoder]

@Melba23 I spotted 3 4 differences. Thanks Melba!

Sorry everyone, I was working non-stop & i was tired. I make silly mistakes like this when I do this

Edited May 1, 2015 by TheDcoder
Spotted another difference

[TheDcoder]

Erm... Where can I find "Mark as Solved"?

[guinness]

Doesn't exist anymore

[guinness]

Oh and why do you have a count when you don't use it? You can save space by removing it.

[TheDcoder]

I need the count in my main project

[232showtime]

@Melba23 i did not start this topic but please one question, i checked the help file and still confused about this need some clarification...

For $i = 1 To UBound($aAddNewFiles) - 1 ;Im confused with this line, whats the use of Ubound?

 

Edited May 3, 2015 by 232showtime

[Melba23]

232showtime,

UBound tells you how many elements there are in the array - you use the Dimension parameter to determine whether it returns the number of dimensions, rows or columns. That is why you need the "- 1" in the line you quoted because the highest indexed element is one less than the number of elements as AutoIt starts at element [0].

All clear?

M23

[TheDcoder]

@232showtime To count no. of elements in an array, TD (-1 because UBound returns no. of elements +1

[TheDcoder]

@Melba23 Was faster

[jchd]

@232showtime To count no. of elements in an array, TD (-1 because UBound returns no. of elements +1

​Wrong explanation: -1 because array index starts at 0

[iamtheky]

also with no regex

#include <Array.au3>

Local $aAddNewFiles[4]

$aAddNewFiles[0] = 3 ; No. of files
$aAddNewFiles[1] = @DesktopDir & "\FileX"
$aAddNewFiles[2] = @ScriptDir & "\FileY"
$aAddNewFiles[3] = @WindowsDir & "\FileZ"

Local $aAddNewFilesNames[$aAddNewFiles[0] + 1] ; This array will contain File Names w/ Ext

For $i = 1 To UBound($aAddNewFiles) - 1
    $aAddNewFilesNames[$i] = stringmid($aAddNewFiles[$i] , stringinstr($aAddNewFiles[$i] , "\" , 0 , -1) + 1)
Next

_ArrayDisplay($aAddNewFilesNames)

 

Edited May 3, 2015 by boththose

[232showtime]

@ALL

thanks

@Melba23

all clear