[SOLVED] Wrong Pagenumbers when printing with word.au3

[water]

Hi AutoIt and Word gurus,

I have a strange problem with word and word.au3 and would very much appreciate your help

I use the following code to print word documents to a printer driver that generates PDF-files:

expandcollapse popup

Func _Word2PDF($File)
    
    Dim $WordExists = False          ; Words not running yet
    
    If ProcessExists("winword.exe") Then $WordExists = True
    
    ; create MS Word application
    $oWordApp = _WordCreate("")
    If @error then _ShowError("_WordCreate Error")
    
    ; Close empty document
    $oDoc = _WordDocGetCollection ($oWordApp, 0)
    _WordDocClose($oDoc,0)
    
    $oWordApp.Options.WarnBeforeSavingPrintingSendingMarkup = False
    $oWordApp.Options.UpdateLinksAtOpen = False
    
    ; open document
    $oDoc = _WordDocOpen($oWordApp,$file,0,0,1)
    If @error then _ShowError("_WordDocOpen Error")
    
    $oWordApp.Activedocument.Subdocuments.Expanded = True
    $oWordApp.Activewindow.View.ShowRevisionsAndComments = False
    $oWordApp.Activewindow.View.Type = 3
    
    ; delete PDF file
    FileDelete($PDFverzeichnis & " " & $InName & ".PDF")
    
    ; print document
    _WordDocPrint($oDoc,0,1,-1,1,$PDFDrucker,0,"","","",0,0)
    If @error then _ShowError("_WordDocPrint Error")
    
    ; close document, don't save changes
    _WordDocClose($oDoc,0)
    If @error then _ShowError("_WordDocClose Error")
    
    ; close MS Word application
    If Not $WordExists Then _WordQuit($oWordApp)
    If @error then _ShowError("WordQuit Error")

EndFunc

I have several documents that print fine. But one document with 174 pages gets the page numbering wrong. EVERY page has "page 2 of 174".

The only difference to the other docs is that this is a master document with one subdocument.

The document prints fine when I do it manually.

What can I do to force page numbering?

I'm running AutoIt 3.3 on Windows XP with Word 2002 GERMAN.

Edited September 12, 2009 by water

[water]

After rearranging the function everything is now working fine

Func _Word2PDF($File)
    
    $oWordApp = _WordCreate($File)
    If @error <> 0 then _ShowError("_WordCreate Fehler")
    
    $oDoc = _WordDocGetCollection ($oWordApp, 0)
    If @error <> 0 then _ShowError("_WordDocGetCollection Fehler")
    
    $oWordApp.Options.WarnBeforeSavingPrintingSendingMarkup = False
    $oWordApp.Options.UpdateLinksAtOpen = False
    $oWordApp.Activedocument.Subdocuments.Expanded = True
    $oWordApp.Activewindow.View.ShowRevisionsAndComments = False
    $oWordApp.Activewindow.View.Type = 3

    _WordDocPrint($oDoc,0,1,-1,1,$PDFDrucker)
    If @error <> 0 then _ShowError("_WordDocPrint Fehler")
    
    _WordDocClose($oDoc,0)
    If @error <> 0 then _ShowError("_WordDocClose Fehler")
    
    _WordQuit($oWordApp)
    If @error <> 0 then _ShowError("WordQuit Fehler")

EndFunc