Active Directory UDF

[water]

I created a test script and it works just fine.

Is there a change you can send me the output (only the relevant OUs) of _AD_GetAllOUs by PM?

[ptrex]

Info on AD NESTED Groups.

http://www.linkedin.com/news?viewArticle=&articleID=924756674&gid=104959&type=member&item=81455819&articleURL=http%3A%2F%2Fbriandesmond%2Ecom%2Fblog%2Factive-directory-group-nesting-reference%2F%3Futm_source%3Dfeedburner%26utm_medium%3Dfeed%26utm_campaign%3DFeed%253A%2BBrianDesmond%2B%2528Brian%2BDesmond%2527s%2BBlog%2529&urlhash=Oe0m&goback=%2Egde_104959_member_81455819

Can be interesting;

Rgds

ptrex

[HaeMHuK]

water, I've sent you information to PM

[water]

I found the problem (and posted a reply via PM)! It's caused by sorting the OUs (incorrectly).

I will have to check my code and will post as soon as I have found a solution.

[HaeMHuK]

OK. Thanks a lot.

[water]

Function _AD_GettAllOUs already supports a seperator character. You need to specify a character lower than space (hex 32).

Could you please replace

Local $aAD_OUs = _AD_GetAllOUs($sAD_OU, "\")

with

Local $aAD_OUs = _AD_GetAllOUs($sAD_OU, Chr(31))

[HaeMHuK]

same result

[water]

I will have to check _ArraySort tomorrow.

[water]

OK, another try. Please replace the following code:

Func _AD_GetOUTreeView($sAD_OU, $hAD_TreeView, $bAD_IsADOpen = False)

    If $bAD_IsADOpen = False Then
        _AD_Open()
        If @error Then Return SetError(@error, @extended, 0)
    EndIf
    $sSeparator = Chr(31)
    Local $aAD_OUs = _AD_GetAllOUs($sAD_OU, $sSeparator)
    If @error <> 0 Then Return SetError(@error, @extended, 0)
    Local $aAD_TreeView[$aAD_OUs[0][0] + 1][3] = [[$aAD_OUs[0][0], 3]]
    For $i = 1 To $aAD_OUs[0][0]
        $aAD_Temp = StringSplit($aAD_OUs[$i][0], $sSeparator)
        $aAD_TreeView[$i][0] = StringFormat("%" & $aAD_Temp[0] - 1 & "s", "") & "#" & $aAD_Temp[$aAD_Temp[0]]
        $aAD_TreeView[$i][1] = $aAD_OUs[$i][1]
    Next
    If $bAD_IsADOpen = False Then _AD_Close()

    _GUICtrlTreeView_BeginUpdate($hAD_TreeView)
    Local $ahAD_Node[50]
    For $iAD_Index = 1 To $aAD_TreeView[0][0]
        $sAD_Line = StringSplit(StringStripCR($aAD_TreeView[$iAD_Index][0]), @TAB)
        $iAD_Level = StringInStr($sAD_Line[1], "#")
        If $iAD_Level = 0 Then ExitLoop
        If $iAD_Level = 1 Then
            $ahAD_Node[$iAD_Level] = _GUICtrlTreeView_Add($hAD_TreeView, 0, StringMid($sAD_Line[1], $iAD_Level + 1))
            $aAD_TreeView[$iAD_Index][2] = $ahAD_Node[$iAD_Level]
        Else
            $ahAD_Node[$iAD_Level] = _GUICtrlTreeView_AddChild($hAD_TreeView, $ahAD_Node[$iAD_Level - 1], StringMid($sAD_Line[1], $iAD_Level + 1))
            $aAD_TreeView[$iAD_Index][2] = $ahAD_Node[$iAD_Level]
        EndIf
    Next
    _GUICtrlTreeView_EndUpdate($hAD_TreeView)
    Return $aAD_TreeView

EndFunc   ;==>_AD_GetOUTreeView

in AD UDF, function _AD_GetAllOUs, deactive this line

; If $sAD_Separator <= " " Or StringLen($sAD_Separator) > 1 Then $sAD_Separator = ""

Something else I noted:

Function _AD_GetAllOUs really just returns OUs. In the AD structure you often have containers (CN=) which are ignored (at the moment) by this function.

Edited November 25, 2011 by water

[HaeMHuK]

It didn't help (

[water]

The problem seems to be caused by _ArraySort in function _AD_GetAllOUs not sorting the records correctly even when a "correct" separator is used.

I have to rethink the solution (it's the original code written by John Clelland) - but don't hold your breath.

[water]

Just for the records:

I was able to pin down the problem to the StringCompare statement in _ArraySort. The solution will be to change the StringCompare flag from 0 (default) to 2. As _ArraySort doesn't allow to pass the flag I need to change the function and include it with the AD UDF.

I hope I can provide the changed functions in a few days.

[HaeMHuK]

OK. Thanks. I'm looking forward to it.

[water]

To solve this problem I would have to insert about 230 lines of code (a modified _ArraySort function + helper functions) with only 2 characters changed.

At the moment I would like to leave the AD UDF untouched. A comment in function _AD_GetAllOUs will tell what to do if an OU contains spaces.

To solve your problem you need to modify _AD_Example_GetOUTreeView.au3:

• Insert the functions _ArraySort and __ArrayQuickSort1D from the last post of trancexx of this
• Rename this functions to _ArraySortEX and __ArrayQuickSort1DEX
• Change all function calls for __ArrayQuickSort1D to __ArrayQuickSort1DEX
• Replace the separator character "" with @Tab (2 times)
• Call _ArraySortEX after line

  Local $aAD_OUs = _AD_GetAllOUs($sAD_OU, @TAB)
  If @error <> 0 Then Return SetError(@error, @extended, 0)

  using

  _ArraySortEX($aAD_OUs)

Edited December 3, 2011 by water

[HaeMHuK]

Hi water. Thanks for your help. But I have bad news again. It works only for one OU. With second one I see the same problem.

"Partners.Disabled" are still in "Partners.Disabled Never Used".

Edited December 5, 2011 by HaeMHuK

[HaeMHuK]

By the way, _ArraySortEX($aAD_OUs) do not anything. Same result with or without this line.

Edited December 5, 2011 by HaeMHuK

[water]

This line taken from trancexx's code should make the difference:

If (StringCompare($vTmp, $avArray[$j], 2) >= 0) Then ExitLoop ;<- !Here!

[HaeMHuK]

I've added it to AD.udf

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name...........: _AD_GetOUTreeView
; Description ...: Fills a given TreeView control with all OUs starting with a given OU.
; Syntax.........: _AD_GetOUTreeView($sAD_OU, $hAD_TreeView[, $bAD_IsADOpen = False])
; Parameters ....: $sAD_OU     - FQDN of the OU where to start. "" displays all OUs
;                 $hAD_TreeView - Handle of the TreeView where the OUs will be displayed. Has to be created in advance
;                 $bAD_IsADOpen - Pass as True if the connection to the AD has already been made by the calling script (default = False)
; Return values .: Success - 1
;                 Failure - Returns 0 and sets @error:
;                 |x - Function _AD_GetAllOUs failed. @error and @extended are set by _AD_GetAllOUs
; Author ........: ReFran - http://www.autoitscript.com/forum/topic/84119-treeview-read-to-from-file
; Modified.......: water
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _AD_GetOUTreeView($sAD_OU, $hAD_TreeView, $bAD_IsADOpen = False)

Local $aAD_OUs = _AD_GetAllOUs($sAD_OU, @TAB)
If @error <> 0 Then Return SetError(@error, @extended, 0)
_ArraySortEX($aAD_OUs)
  Local $aAD_TreeView[$aAD_OUs[0][0] + 1][3] = [[$aAD_OUs[0][0], 3]]
For $i = 1 To $aAD_OUs[0][0]
  $aAD_Temp = StringSplit($aAD_OUs[$i][0], @TAB)
  $aAD_TreeView[$i][0] = StringFormat("%" & $aAD_Temp[0] - 1 & "s", "") & "#" & $aAD_Temp[$aAD_Temp[0]]
  $aAD_TreeView[$i][1] = $aAD_OUs[$i][1]
Next

_GUICtrlTreeView_BeginUpdate($hAD_TreeView)
Local $ahAD_Node[50]
For $iAD_Index = 1 To $aAD_TreeView[0][0]
  $sAD_Line = StringSplit(StringStripCR($aAD_TreeView[$iAD_Index][0]), @TAB)
  $iAD_Level = StringInStr($sAD_Line[1], "#")
  If $iAD_Level = 0 Then ExitLoop
  If $iAD_Level = 1 Then
   $ahAD_Node[$iAD_Level] = _GUICtrlTreeView_Add($hAD_TreeView, 0, StringMid($sAD_Line[1], $iAD_Level + 1))
   $aAD_TreeView[$iAD_Index][2] = $ahAD_Node[$iAD_Level]
  Else
   $ahAD_Node[$iAD_Level] = _GUICtrlTreeView_AddChild($hAD_TreeView, $ahAD_Node[$iAD_Level - 1], StringMid($sAD_Line[1], $iAD_Level + 1))
   $aAD_TreeView[$iAD_Index][2] = $ahAD_Node[$iAD_Level]
  EndIf
Next
_GUICtrlTreeView_EndUpdate($hAD_TreeView)
Return $aAD_TreeView
EndFunc   ;==>_AD_GetOUTreeView
; #FUNCTION# ====================================================================================================================
; Name...........: _ArraySort
; Description ...: Sort a 1D or 2D array on a specific index using the quicksort/insertionsort algorithms.
; Syntax.........: _ArraySort(ByRef $avArray[, $iDescending = 0[, $iStart = 0[, $iEnd = 0[, $iSubItem = 0]]]])
; Parameters ....: $avArray  - Array to sort
;                 $iDescending - [optional] If set to 1, sort descendingly
;                 $iStart     - [optional] Index of array to start sorting at
;                 $iEnd     - [optional] Index of array to stop sorting at
;                 $iSubItem    - [optional] Sub-index to sort on in 2D arrays
; Return values .: Success - 1
;                 Failure - 0, sets @error:
;                 |1 - $avArray is not an array
;                 |2 - $iStart is greater than $iEnd
;                 |3 - $iSubItem is greater than subitem count
;                 |4 - $avArray has too many dimensions
; Author ........: Jos van der Zande <jdeb at autoitscript dot com>
; Modified.......: LazyCoder - added $iSubItem option, Tylo - implemented stable QuickSort algo, Jos van der Zande - changed logic to correctly Sort arrays with mixed Values and Strings, Ultima - major optimization, code cleanup, removed $i_Dim parameter
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _ArraySortEX(ByRef $avArray, $iDescending = 0, $iStart = 0, $iEnd = 0, $iSubItem = 0)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    Local $iUBound = UBound($avArray) - 1
    ; Bounds checking
    If $iEnd < 1 Or $iEnd > $iUBound Then $iEnd = $iUBound
    If $iStart < 0 Then $iStart = 0
    If $iStart > $iEnd Then Return SetError(2, 0, 0)
    ; Sort
    Switch UBound($avArray, 0)
        Case 1
            __ArrayQuickSort1DEX($avArray, $iStart, $iEnd)
            If $iDescending Then _ArrayReverse($avArray, $iStart, $iEnd)
        Case 2
            Local $iSubMax = UBound($avArray, 2) - 1
            If $iSubItem > $iSubMax Then Return SetError(3, 0, 0)
            If $iDescending Then
                $iDescending = -1
            Else
                $iDescending = 1
            EndIf
            __ArrayQuickSort2D($avArray, $iDescending, $iStart, $iEnd, $iSubItem, $iSubMax)
        Case Else
            Return SetError(4, 0, 0)
    EndSwitch
    Return 1
EndFunc   ;==>_ArraySort
; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __ArrayQuickSort1D
; Description ...: Helper function for sorting 1D arrays
; Syntax.........: __ArrayQuickSort1D(ByRef $avArray, ByRef $iStart, ByRef $iEnd)
; Parameters ....: $avArray - Array to sort
;                 $iStart  - Index of array to start sorting at
;                 $iEnd    - Index of array to stop sorting at
; Return values .: None
; Author ........: Jos van der Zande, LazyCoder, Tylo, Ultima
; Modified.......:
; Remarks .......: For Internal Use Only
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func __ArrayQuickSort1DEX(ByRef $avArray, ByRef $iStart, ByRef $iEnd)
    If $iEnd <= $iStart Then Return
    Local $vTmp
    ; InsertionSort (faster for smaller segments)
    If ($iEnd - $iStart) < 15 Then
        Local $vCur
        For $i = $iStart + 1 To $iEnd
            $vTmp = $avArray[$i]
            If IsNumber($vTmp) Then
                For $j = $i - 1 To $iStart Step -1
                    $vCur = $avArray[$j]
                    ; If $vTmp >= $vCur Then ExitLoop
                    If ($vTmp >= $vCur And IsNumber($vCur)) Or (Not IsNumber($vCur) And StringCompare($vTmp, $vCur) >= 0) Then ExitLoop
                    $avArray[$j + 1] = $vCur
                Next
            Else
                For $j = $i - 1 To $iStart Step -1
                    If (StringCompare($vTmp, $avArray[$j], 2) >= 0) Then ExitLoop ;<- !Here!
                    $avArray[$j + 1] = $avArray[$j]
                Next
            EndIf
            $avArray[$j + 1] = $vTmp
        Next
        Return
    EndIf
    ; QuickSort
    Local $L = $iStart, $R = $iEnd, $vPivot = $avArray[Int(($iStart + $iEnd) / 2)], $fNum = IsNumber($vPivot)
    Do
        If $fNum Then
            ; While $avArray[$L] < $vPivot
            While ($avArray[$L] < $vPivot And IsNumber($avArray[$L])) Or (Not IsNumber($avArray[$L]) And StringCompare($avArray[$L], $vPivot) < 0)
                $L += 1
            WEnd
            ; While $avArray[$R] > $vPivot
            While ($avArray[$R] > $vPivot And IsNumber($avArray[$R])) Or (Not IsNumber($avArray[$R]) And StringCompare($avArray[$R], $vPivot) > 0)
                $R -= 1
            WEnd
        Else
            While (StringCompare($avArray[$L], $vPivot) < 0)
                $L += 1
            WEnd
            While (StringCompare($avArray[$R], $vPivot) > 0)
                $R -= 1
            WEnd
        EndIf
        ; Swap
        If $L <= $R Then
            $vTmp = $avArray[$L]
            $avArray[$L] = $avArray[$R]
            $avArray[$R] = $vTmp
            $L += 1
            $R -= 1
        EndIf
    Until $L > $R
    __ArrayQuickSort1DEX($avArray, $iStart, $R)
    __ArrayQuickSort1DEX($avArray, $L, $iEnd)
EndFunc   ;==>__ArrayQuickSort1D

"Partners.Disabled" is still empty.

[water]

Unfortunately I'm quite busy at the moment (as always rount this time of the year).

Need to do some testing and will come back with a result - but don't hold your breath

[HaeMHuK]

It's not critical for me now. Please, let me know about any updates on your free time.

Thanks in advance.