Active Directory UDF

[water]

It's not critical for me now.

Good to know

I'll keep you informed.

[water]

OK, I have created a "small" test script with the changed functions and your test data. Can you please give it a try and post the result? It works great for me.

expandcollapse popup

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseX64=n
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <AD.au3>
#include <TreeviewConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <GuiTreeView.au3>

Global $sOU = "" ; FQDN of the OU where to start
Global $sTitle = "Active Direcory OU Treeview"
#region ### START Koda GUI section ### Form=
Global $hMain = GUICreate($sTitle, 743, 683, -1, -1)
Global $hTree = GUICtrlCreateTreeView(6, 6, 600, 666, -1, $WS_EX_CLIENTEDGE)
Global $bExit = GUICtrlCreateButton("Exit", 624, 8, 97, 33)
Global $bExpand = GUICtrlCreateButton("Expand", 624, 56, 97, 33)
Global $bCollapse = GUICtrlCreateButton("Collapse", 624, 104, 97, 33)
Global $bSelect = GUICtrlCreateButton("Select OU", 624, 152, 97, 33)
#endregion ### END Koda GUI section ###
Global $aTreeView = _AD_GetOUTreeView($sOU, $hTree)
If @error <> 0 Then MsgBox(16, "Active Direcory OU Treeview", "Error creating list of OUs starting with '" & $sOU & "'." & @CRLF & _
    "Error returned by function _AD_GetALLOUs: @error = " & @error & ", @extended =  " & @extended)
GUISetState(@SW_SHOW)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE, $bExit
            Exit
        Case $bExpand
            _GUICtrlTreeView_Expand($hTree)
        Case $bCollapse
            _GUICtrlTreeView_Expand($hTree, 0, False)
        Case $bSelect
            $hSelection = _GUICtrlTreeView_GetSelection($hTree)
            $sSelection = _GUICtrlTreeView_GetText($hTree, $hSelection)
            For $i = 1 To $aTreeView[0][0]
                If $hSelection = $aTreeView[$i][2] Then ExitLoop
            Next
            $sOU = $aTreeView[$i][1]
            MsgBox(16, $sTitle & " - Selected OU", "Name: " & $sSelection & @CRLF & "FQDN: " & $sOU)
    EndSwitch
WEnd

; #FUNCTION# ====================================================================================================================
; Name...........: _AD_GetOUTreeView
; Description ...: Fills a given TreeView control with all OUs starting with a given OU.
; Syntax.........: _AD_GetOUTreeView($sAD_OU, $hAD_TreeView[, $bAD_IsADOpen = False])
; Parameters ....: $sAD_OU     - FQDN of the OU where to start. "" displays all OUs
;                 $hAD_TreeView - Handle of the TreeView where the OUs will be displayed. Has to be created in advance
;                 $bAD_IsADOpen - Pass as True if the connection to the AD has already been made by the calling script (default = False)
; Return values .: Success - 1
;                 Failure - Returns 0 and sets @error:
;                 |x - Function _AD_Open or _AD_GetAllOUs failed. @error and @extended are set by _AD_Open or _AD_GetAllOUs
; Author ........: ReFran - http://www.autoitscript.com/forum/topic/84119-treeview-read-to-from-file
; Modified.......: water
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _AD_GetOUTreeView($sAD_OU, $hAD_TreeView, $bAD_IsADOpen = False)

    If $bAD_IsADOpen = False Then
;       _AD_Open()
        If @error Then Return SetError(@error, @extended, 0)
    EndIf
$sSeparator = @TAB
;   Local $aAD_OUs = _AD_GetAllOUs($sAD_OU, $sSeparator)
Local $aAD_OUs[9][2] = [[8,2]]
$aAD_OUs[1][0] = "Root" & @Tab & "Partners"
$aAD_OUs[1][1] = "Root" & @Tab & "Partners"
$aAD_OUs[2][0] = "Root" & @Tab & "Partners.Disabled"
$aAD_OUs[2][1] = "Root" & @Tab & "Partners.Disabled"
$aAD_OUs[3][0] = "Root" & @Tab & "Partners.Disabled Never Used"
$aAD_OUs[3][1] = "Root" & @Tab & "Partners.Disabled Never Used"
$aAD_OUs[4][0] = "Root" & @Tab & "Partners.Inactive - Migrated from Media"
$aAD_OUs[4][1] = "Root" & @Tab & "Partners.Inactive - Migrated from Media"
$aAD_OUs[5][0] = "Root" & @Tab & "Partners" & @Tab & "Example 1"
$aAD_OUs[5][1] = "Root" & @Tab & "Partners" & @Tab & "Example 1"
$aAD_OUs[6][0] = "Root" & @Tab & "Partners.Disabled" & @Tab & "Example 2"
$aAD_OUs[6][1] = "Root" & @Tab & "Partners.Disabled" & @Tab & "Example 2"
$aAD_OUs[7][0] = "Root" & @Tab & "Partners.Disabled Never Used" & @Tab & "Example 3"
$aAD_OUs[7][1] = "Root" & @Tab & "Partners.Disabled Never Used" & @Tab & "Example 3"
$aAD_OUs[8][0] = "Root" & @Tab & "Partners.Inactive - Migrated from Media" & @Tab & "Example 4"
$aAD_OUs[8][1] = "Root" & @Tab & "Partners.Inactive - Migrated from Media" & @Tab & "Example 4"
    If @error <> 0 Then Return SetError(@error, @extended, 0)
_ArraySortEX($aAD_OUs)
    Local $aAD_TreeView[$aAD_OUs[0][0] + 1][3] = [[$aAD_OUs[0][0], 3]]
    For $i = 1 To $aAD_OUs[0][0]
        $aAD_Temp = StringSplit($aAD_OUs[$i][0], $sSeparator)
        $aAD_TreeView[$i][0] = StringFormat("%" & $aAD_Temp[0] - 1 & "s", "") & "#" & $aAD_Temp[$aAD_Temp[0]]
        $aAD_TreeView[$i][1] = $aAD_OUs[$i][1]
    Next
;   If $bAD_IsADOpen = False Then _AD_Close()

    _GUICtrlTreeView_BeginUpdate($hAD_TreeView)
    Local $ahAD_Node[50]
    For $iAD_Index = 1 To $aAD_TreeView[0][0]
        $sAD_Line = StringSplit(StringStripCR($aAD_TreeView[$iAD_Index][0]), @TAB)
        $iAD_Level = StringInStr($sAD_Line[1], "#")
        If $iAD_Level = 0 Then ExitLoop
        If $iAD_Level = 1 Then
            $ahAD_Node[$iAD_Level] = _GUICtrlTreeView_Add($hAD_TreeView, 0, StringMid($sAD_Line[1], $iAD_Level + 1))
            $aAD_TreeView[$iAD_Index][2] = $ahAD_Node[$iAD_Level]
        Else
            $ahAD_Node[$iAD_Level] = _GUICtrlTreeView_AddChild($hAD_TreeView, $ahAD_Node[$iAD_Level - 1], StringMid($sAD_Line[1], $iAD_Level + 1))
            $aAD_TreeView[$iAD_Index][2] = $ahAD_Node[$iAD_Level]
        EndIf
    Next
    _GUICtrlTreeView_EndUpdate($hAD_TreeView)
    Return $aAD_TreeView

EndFunc   ;==>_AD_GetOUTreeView


; #FUNCTION# ====================================================================================================================
; Name...........: _ArraySort
; Description ...: Sort a 1D or 2D array on a specific index using the quicksort/insertionsort algorithms.
; Syntax.........: _ArraySort(ByRef $avArray[, $iDescending = 0[, $iStart = 0[, $iEnd = 0[, $iSubItem = 0]]]])
; Parameters ....: $avArray  - Array to sort
;                 $iDescending - [optional] If set to 1, sort descendingly
;                 $iStart     - [optional] Index of array to start sorting at
;                 $iEnd     - [optional] Index of array to stop sorting at
;                 $iSubItem - [optional] Sub-index to sort on in 2D arrays
; Return values .: Success - 1
;                 Failure - 0, sets @error:
;                 |1 - $avArray is not an array
;                 |2 - $iStart is greater than $iEnd
;                 |3 - $iSubItem is greater than subitem count
;                 |4 - $avArray has too many dimensions
; Author ........: Jos van der Zande <jdeb at autoitscript dot com>
; Modified.......: LazyCoder - added $iSubItem option, Tylo - implemented stable QuickSort algo, Jos van der Zande - changed logic to correctly Sort arrays with mixed Values and Strings, Ultima - major optimization, code cleanup, removed $i_Dim parameter
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _ArraySortEx(ByRef $avArray, $iDescending = 0, $iStart = 0, $iEnd = 0, $iSubItem = 0)
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)

    Local $iUBound = UBound($avArray) - 1

    ; Bounds checking
    If $iEnd < 1 Or $iEnd > $iUBound Then $iEnd = $iUBound
    If $iStart < 0 Then $iStart = 0
    If $iStart > $iEnd Then Return SetError(2, 0, 0)

    ; Sort
    Switch UBound($avArray, 0)
        Case 1
            __ArrayQuickSort1DEX($avArray, $iStart, $iEnd)
            If $iDescending Then _ArrayReverse($avArray, $iStart, $iEnd)
        Case 2
            Local $iSubMax = UBound($avArray, 2) - 1
            If $iSubItem > $iSubMax Then Return SetError(3, 0, 0)

            If $iDescending Then
                $iDescending = -1
            Else
                $iDescending = 1
            EndIf

            __ArrayQuickSort2DEX($avArray, $iDescending, $iStart, $iEnd, $iSubItem, $iSubMax)
        Case Else
            Return SetError(4, 0, 0)
    EndSwitch

    Return 1
EndFunc   ;==>_ArraySort

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __ArrayQuickSort1D
; Description ...: Helper function for sorting 1D arrays
; Syntax.........: __ArrayQuickSort1D(ByRef $avArray, ByRef $iStart, ByRef $iEnd)
; Parameters ....: $avArray - Array to sort
;                 $iStart  - Index of array to start sorting at
;                 $iEnd - Index of array to stop sorting at
; Return values .: None
; Author ........: Jos van der Zande, LazyCoder, Tylo, Ultima
; Modified.......:
; Remarks .......: For Internal Use Only
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func __ArrayQuickSort1DEX(ByRef $avArray, ByRef $iStart, ByRef $iEnd)
    If $iEnd <= $iStart Then Return

    Local $vTmp

    ; InsertionSort (faster for smaller segments)
    If ($iEnd - $iStart) < 15 Then
        Local $vCur
        For $i = $iStart + 1 To $iEnd
            $vTmp = $avArray[$i]

            If IsNumber($vTmp) Then
                For $j = $i - 1 To $iStart Step -1
                    $vCur = $avArray[$j]
                    ; If $vTmp >= $vCur Then ExitLoop
                    If ($vTmp >= $vCur And IsNumber($vCur)) Or (Not IsNumber($vCur) And StringCompare($vTmp, $vCur, 2) >= 0) Then ExitLoop
                    $avArray[$j + 1] = $vCur
                Next
            Else
                For $j = $i - 1 To $iStart Step -1
                    If (StringCompare($vTmp, $avArray[$j], 2) >= 0) Then ExitLoop ;<- !Here!
                    $avArray[$j + 1] = $avArray[$j]
                Next
            EndIf

            $avArray[$j + 1] = $vTmp
        Next
        Return
    EndIf

    ; QuickSort
    Local $L = $iStart, $R = $iEnd, $vPivot = $avArray[Int(($iStart + $iEnd) / 2)], $fNum = IsNumber($vPivot)
    Do
        If $fNum Then
            ; While $avArray[$L] < $vPivot
            While ($avArray[$L] < $vPivot And IsNumber($avArray[$L])) Or (Not IsNumber($avArray[$L]) And StringCompare($avArray[$L], $vPivot, 2) < 0)
                $L += 1
            WEnd
            ; While $avArray[$R] > $vPivot
            While ($avArray[$R] > $vPivot And IsNumber($avArray[$R])) Or (Not IsNumber($avArray[$R]) And StringCompare($avArray[$R], $vPivot, 2) > 0)
                $R -= 1
            WEnd
        Else
            While (StringCompare($avArray[$L], $vPivot, 2) < 0)
                $L += 1
            WEnd
            While (StringCompare($avArray[$R], $vPivot, 2) > 0)
                $R -= 1
            WEnd
        EndIf

        ; Swap
        If $L <= $R Then
            $vTmp = $avArray[$L]
            $avArray[$L] = $avArray[$R]
            $avArray[$R] = $vTmp
            $L += 1
            $R -= 1
        EndIf
    Until $L > $R

    __ArrayQuickSort1DEX($avArray, $iStart, $R)
    __ArrayQuickSort1DEX($avArray, $L, $iEnd)
EndFunc   ;==>__ArrayQuickSort1D

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __ArrayQuickSort2D
; Description ...: Helper function for sorting 2D arrays
; Syntax.........: __ArrayQuickSort2D(ByRef $avArray, ByRef $iStep, ByRef $iStart, ByRef $iEnd, ByRef $iSubItem, ByRef $iSubMax)
; Parameters ....: $avArray  - Array to sort
;                 $iStep    - Step size (should be 1 to sort ascending, -1 to sort descending!)
;                 $iStart   - Index of array to start sorting at
;                 $iEnd  - Index of array to stop sorting at
;                 $iSubItem - Sub-index to sort on in 2D arrays
;                 $iSubMax  - Maximum sub-index that array has
; Return values .: None
; Author ........: Jos van der Zande, LazyCoder, Tylo, Ultima
; Modified.......:
; Remarks .......: For Internal Use Only
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func __ArrayQuickSort2DEX(ByRef $avArray, ByRef $iStep, ByRef $iStart, ByRef $iEnd, ByRef $iSubItem, ByRef $iSubMax)
    If $iEnd <= $iStart Then Return

    ; QuickSort
    Local $vTmp, $L = $iStart, $R = $iEnd, $vPivot = $avArray[Int(($iStart + $iEnd) / 2)][$iSubItem], $fNum = IsNumber($vPivot)
    Do
        If $fNum Then
            ; While $avArray[$L][$iSubItem] < $vPivot
            While ($iStep * ($avArray[$L][$iSubItem] - $vPivot) < 0 And IsNumber($avArray[$L][$iSubItem])) Or (Not IsNumber($avArray[$L][$iSubItem]) And $iStep * StringCompare($avArray[$L][$iSubItem], $vPivot, 2) < 0)
                $L += 1
            WEnd
            ; While $avArray[$R][$iSubItem] > $vPivot
            While ($iStep * ($avArray[$R][$iSubItem] - $vPivot) > 0 And IsNumber($avArray[$R][$iSubItem])) Or (Not IsNumber($avArray[$R][$iSubItem]) And $iStep * StringCompare($avArray[$R][$iSubItem], $vPivot, 2) > 0)
                $R -= 1
            WEnd
        Else
            While ($iStep * StringCompare($avArray[$L][$iSubItem], $vPivot, 2) < 0)
                $L += 1
            WEnd
            While ($iStep * StringCompare($avArray[$R][$iSubItem], $vPivot, 2) > 0)
                $R -= 1
            WEnd
        EndIf

        ; Swap
        If $L <= $R Then
            For $i = 0 To $iSubMax
                $vTmp = $avArray[$L][$i]
                $avArray[$L][$i] = $avArray[$R][$i]
                $avArray[$R][$i] = $vTmp
            Next
            $L += 1
            $R -= 1
        EndIf
    Until $L > $R

    __ArrayQuickSort2DEX($avArray, $iStep, $iStart, $R, $iSubItem, $iSubMax)
    __ArrayQuickSort2DEX($avArray, $iStep, $L, $iEnd, $iSubItem, $iSubMax)
EndFunc   ;==>__ArrayQuickSort2D

[HaeMHuK]

Please, look to an attachment.

[HaeMHuK]

I've just added your code to my script and changed "" to @TAB two times. Everything works fine for now.

Did you make any changes to _arraysort functions?

[water]

Glad the problem is solved

The code has many StringCompare function calls. Just one of them was changed by trancexx. I modified all of them (by adding flag = 2). This seems to have solved the problem.

[HaeMHuK]

Thanks a lot water.

[water]

Glad we got it working. The next version will have a note for other users as reference,

[water]

Version 1.2.0 has been released.

Please test before using in production!

For download please see my signature.

[shornw]

AD.au3 just rocks!! Stupendously useful.Thanks for all your help with the AD_GetPasswordExpired() recently, all working wonderfully in 1.2.0.

AD.au3, Array.au3 and Excel.au3 have become the busiest parts in my life of late

[water]

Glad you like it. Keep on testing in the next few days. Starting 25th of december I will be on vacation for 2 weeks.

[pluto41]

This is a very usefull UDF. When looking trough all the functions i miss two functions which look quite handy to me.

_AD_AddComputerToGroup

_AD_RemoveComputerFromGroup

I have a vbscript which can do this. So if you need the code let me know.

[water]

Please have a look at the following functions. The names may be a bit misleading (I've taken them from the original UDF written by Jonathan Clelland) but you can use them for users and computers.

; Name...........: _AD_AddUserToGroup

; Description ...: Adds a user or computer to the specified group.

; Name...........: _AD_RemoveUserFromGroup

; Description ...: Removes a user or computer from the specified group.

Please make sure that if you specifiy the computer as SamAccountName to append a dollar sign e.g. @ComputerName & "$"

[pluto41]

Water thanks. I just tried it out and works like a charm

I tried it a hour ago but forgot the "$".

[water]

Glad it was that easy

[JLogan3o13]

Just wanted to say thanks for what must have been many hours worth of work to deliver this, I am going through the examples now and see ways to make my job easier at every turn.

One question I have (and I may find it when I have time to get through all the functions) is returning a list of computer objects that have not had their password reset in x number of weeks. This would be something akin to querying the pwdLastSet LDAP property. I've been looking at _AD_IsAccountExpired and _AD_GetAccountsExpired but am not seeing exactly that ability. Is there another function that I could use for this? Thanks again.

[water]

Glad you like the UDF.

Please have a look at function _AD_GetPasswordExpired to do what you need. The current version has some enhancements (please check page 1 of this thread).

[JLogan3o13]

That is exactly what I needed. Thanks again, Water.

[water]

[BullGates]

Hello, Thanks for the great work. I do have a problem with the sample script regarding _AD_GetLastLoginDate() function. It takes a lot of time until I get this error:

AD.au3 (1428) : ==> Error in expression.:

Since I have an huge domain structure I've tried to limit the function to the Site name, but still I always get the same error. Can you please help?

[water]

Which version of the UDF do you use?