Runing a command against an Array

[norjms]

Ok I'm a bit dumb for the like of me I can't get this to work.

I have a folder with around 500 avi files inside located @ScriptDir\Rip Source\ There are only avi files inside so I don't need to figure out the filetype prior to running the command

I have Handbrake in a folder @ScriptDir\Bin\HandbrakeCLI\HandbrakeCLI.exe

I want to run this command against every file inside the folder:

Handbrake.exe -i @ScriptDir\Rip Source\"thenameofthefile" -o @ScriptDir\Temp\"thenameofthefile minus the .ext avi" -L -f mp4 --strict-anamorphic -e x264 -q 20 -a 1 -E faac -6 dpl2 -R 48 -B 160 -D 0.0 --subtitle 1 --subtitle-burn=1 -x ref=2:bframes=2:subq=6:mixed-refs=0:weightb=0:8x8dct=0:trellis=0 -v 1 <------this is all a one line command switch

Here is the code I have that I am at a loss on how to get it to work.

#Include <File.au3>
#Include <Array.au3>

$root = @ScriptDir



$NormalSwitch = -L -f mp4 --strict-anamorphic  -e x264 -q 20 -a 1 -E faac -6 dpl2 -R 48 -B 160 -D 0.0 --subtitle 1 --subtitle-burn=1 -x ref=2:bframes=2:subq=6:mixed-refs=0:weightb=0:8x8dct=0:trellis=0 -v 1

$FileList =_FileListToArray($root & "\Rip Source","*", 1)
If @Error=1 Then
    MsgBox (0,"","No Files\Folders Found.")
    Exit
EndIf
_ArrayDisplay($FileList,"$FileList")

For $i=1 To $FileList[0]
    RunWait(@ScriptDir & "\Bin\HandbrakeCLI\HanBrakeCLI.exe -i " & @ScriptDir & "\Rip Source\" & $FileList[$i] & " " & "-o " & @ScriptDir & "\temp\" & $FileList[$i])
Next

Thanks for your help

Edited December 4, 2009 by norjms

[water]

Change your script to:

#Include <File.au3>
#Include <Array.au3>

$root = @ScriptDir & "\Rip Source\"
$NormalSwitch = "-L -f mp4 --strict-anamorphic -e x264 -q 20 -a 1 -E faac -6 dpl2 -R 48 -B 160 -D 0.0 --subtitle 1 --subtitle-burn=1 -x ref=2:bframes=2:subq=6:mixed-refs=0:weightb=0:8x8dct=0:trellis=0 -v 1"
$FileList =_FileListToArray($root, "*.*", 1)
If @error>0 Then
    MsgBox (0,"","No Files\Folders Found. Error: " & @error)
    Exit
EndIf
_ArrayDisplay($FileList,"$FileList")

For $i=1 To $FileList[0]
    RunWait(@ScriptDir & "\Bin\HandbrakeCLI\HanBrakeCLI.exe -i " & $root & $FileList[$i] & " " & '-o "' & @ScriptDir & "\temp\" & $FileList[$i] & '" ' & $NormalSwitch)
Next

Edited December 4, 2009 by water

[norjms]

I got what I wanted to do working, but I can't seem to get the error code right.

#Include <File.au3>
#Include <Array.au3>
Global $Configure = (@ScriptDir & "\Configuration\Configure.ini")
$EncodePreset = IniRead($Configure,"Encode Preset","Key","default")
$CompletedExt = IniRead($Configure,"Encode Ext","Key","default")
$RipSource = IniRead($Configure, "DVD Rip Output Path", "Key", "default")
$TransCodePath = IniRead($Configure, "Transcode Path", "Key", "default")
$FileList =_FileListToArray($RipSource, "*.*", 1)
If @Error=1 Then
    MsgBox (0,"","There are no files in " & $RipSource & " " & "to proccess.")
    Exit
EndIf


For $i=1 To $FileList[0]
    $result = StringTrimRight($FileList[$i], 4)
    $myCommand = @ScriptDir&"\HandbrakeCLI\"&"HandBrakeCLI.exe -i " &'"'& $RipSource & "\" & $FileList[$i]&'" ' & '-o "' & $TransCodePath & "\" & $result & $CompletedExt&'" ' & "-preset " & '"' &$EncodePreset&'"'
    RunWait($myCommand)
Next

The error I get is:

Line 1091

Error: Subscript used with non-Array variable

What is the proper way to deal with this error?

[GEOSoft]

If IsArray($FileList) Then
For $i=1 To $FileList[0]
    $result = StringTrimRight($FileList[$i], 4)
    $myCommand = @ScriptDir&"\HandbrakeCLI\"&"HandBrakeCLI.exe -i " &'"'& $RipSource & "\" & $FileList[$i]&'" ' & '-o "' & $TransCodePath & "\" & $result & $CompletedExt&'" ' & "-preset " & '"' &$EncodePreset&'"'
    RunWait($myCommand)
Next
EndIf

Edit: You could also handle it in your existing code by moving the loop.

#Include <File.au3>
#Include <Array.au3>
Global $Configure = (@ScriptDir & "\Configuration\Configure.ini")
$EncodePreset = IniRead($Configure,"Encode Preset","Key","default")
$CompletedExt = IniRead($Configure,"Encode Ext","Key","default")
$RipSource = IniRead($Configure, "DVD Rip Output Path", "Key", "default")
$TransCodePath = IniRead($Configure, "Transcode Path", "Key", "default")
$FileList =_FileListToArray($RipSource, "*.*", 1)
If @Error Then
    MsgBox (0,"","There are no files in " & $RipSource & " " & "to proccess.")
    Exit
Else
For $i=1 To $FileList[0]
    $result = StringTrimRight($FileList[$i], 4)
    $myCommand = @ScriptDir&"\HandbrakeCLI\"&"HandBrakeCLI.exe -i " &'"'& $RipSource & "\" & $FileList[$i]&'" ' & '-o "' & $TransCodePath & "\" & $result & $CompletedExt&'" ' & "-preset " & '"' &$EncodePreset&'"'
    RunWait($myCommand)
Next
EndIf

Edited December 4, 2009 by GEOSoft

[PsaltyDS]

@norjms: There is no array returned from _FileListToArray() if there is an error. You are only testing for @error = 1. What about @error = 4? A better test for failure would be:

If @error Then
    MsgBox (16, "Error", "Error listing files or no matching files in " & $RipSource)
    Exit
EndIf

Edit: Posted before seeing GEOSoft's reply.

Edited December 4, 2009 by PsaltyDS

[GEOSoft]

There is no array returned from _FileListToArray() if there is an error. You are only testing for @error = 1. What about @error = 4? A better test for failure would be:

If @error Then
    MsgBox (16, "Error", "Error listing files or no matching files in " & $RipSource)
    Exit
EndIf

Damn but you're fast today. I was just coming back to change that in my last bit of code.