[SOLVED] Problem with _ResourceGetAsImage() & _GUIImageList_Create()

[guinness]

Problem: The Images don't show in the ListView when using _GUIImageList_Create()

I am using 16 x 16 PNG Images as Resources, before I was converting these from PNG to Bitmap Images using this Function... and it was working perfectly (see the Script at the bottom of this post) So what I am doing wrong when using _ResourceGetAsImage() because I was under the impression from looking at the Function that it Returns a Bitmap Image. I also tried _ResourceGetAsBitmap() when I manually converted them to Bitmap and it was working. So why not PNG? If anyone has any idea it would be much appreciated.

This Function:

Func _GUIImageList_Convert($gc_Image)
    Local $gc_Bitmap = _GDIPlus_BitmapCreateFromFile($gc_Image)
    Local $gc_PNG = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gc_Bitmap)
    _GDIPlus_ImageDispose($gc_Bitmap)
;~  _WinAPI_DeleteObject($gc_PNG) ; <<<<< Delete the Object.
    Return $gc_PNG
EndFunc   ;==>_GUIImageList_Convert

Problem Script:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#AutoIt3Wrapper_UseX64=N
#AutoIt3Wrapper_Run_Obfuscator=Y
#Obfuscator_Parameters=/SF /SV /OM /CF=0 /CN=0 /CS=0 /CV=0
#AutoIt3Wrapper_Res_File_Add=Image0.png, 10, IMAGE0
#AutoIt3Wrapper_Res_File_Add=Image1.png, 10, IMAGE1
#AutoIt3Wrapper_Res_File_Add=Image2.png, 10, IMAGE2

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>

#include "Resources.au3"

_Main()
_GDIPlus_Shutdown()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView Set Image List", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Load images
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_Add($hImage, _ResourceGetAsBitmap("IMAGE0")) ; Index 0
    _GUIImageList_Add($hImage, _ResourceGetAsBitmap("IMAGE1")) ; Index 1
    _GUIImageList_Add($hImage, _ResourceGetAsBitmap("IMAGE2")) ; Index 2
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)

    ; Add items
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

    For $A = 4 To 20
        _GUICtrlListView_AddItem($hListView, "Item " & $A, Round(Random(0, 2))) ; RANDOM
    Next

    MsgBox(4160, "Information", "What is the Image Index of Item 1. It is >> Index " & _GUICtrlListView_GetItemImage($hListView, 1))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Working Script:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_GDIPlus_Startup()
_Main()
_GDIPlus_Shutdown()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView Set Image List", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Load images
    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_Add($hImage, _GUIImageList_Convert(@ScriptDir & "\Image0.png")) ; Index 0
    _GUIImageList_Add($hImage, _GUIImageList_Convert(@ScriptDir & "\Image1.png")) ; Index 1
    _GUIImageList_Add($hImage, _GUIImageList_Convert(@ScriptDir & "\Image1.png")) ; Index 2
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)

    ; Add items
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

    For $A = 4 To 20
        _GUICtrlListView_AddItem($hListView, "Item " & $A, Round(Random(0, 2))) ; RANDOM
    Next

    MsgBox(4160, "Information", "What is the Image Index of Item 1. It is >> Index " & _GUICtrlListView_GetItemImage($hListView, 1))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func _GUIImageList_Convert($gc_Image) ; Created by guinness 2011
    Local $gc_Bitmap = _GDIPlus_BitmapCreateFromFile($gc_Image)
    Local $gc_PNG = _GDIPlus_BitmapCreateHBITMAPFromBitmap($gc_Bitmap)
    _GDIPlus_ImageDispose($gc_Bitmap)
;~  _WinAPI_DeleteObject($gc_PNG) ; <<<<< Delete the Object.
    Return $gc_PNG
EndFunc   ;==>_GUIImageList_Convert

Edited January 6, 2011 by guinness

[guinness]

ARGHHH! Solved it! I used _ResourceGetAsBitmap() with the PNG Files and it worked. What an idiot! Updated OP!

Edited January 6, 2011 by guinness