Listview issue creating items

[EndFunc]

I'm trying to add items to a list view from an array. Somehow it does show the actual items but it's populating the list because i see the scrollbar get smaller and I can move it up and down but yet there is no data.

Local $ListItem[UBound($aADResults)]
For $i = 1 To $aADResults[0]
$ListItem[$i] = GUICtrlCreateListViewItem("", $ADlist)
GUICtrlSetData($ListItem[$i], $aADResults[$i])
Next

I've tried it a number of ways and just can't get it to work. Anyone have suggestions?

Edited January 27, 2011 by EndFunc

[guinness]

_GUICtrlListView_AddArray() >> Search in the Help File for a good Example

[EndFunc]

_GUICtrlListView_AddArray() >> Search in the Help File for a good Example

Thanks

I tried that, just keeps erroring and exiting the script. Kept giving me that subscript variable exceeded error message.

So I was just trying to do them dynamically one at a time. That should work. It just won't show the data. And the top is preselected even though there is no text there.

[guinness]

I tried that, just keeps erroring and exiting the script. Kept giving me that subscript variable exceeded error message.

Maybe if you post some code I could have a look Because it sounds like a problem with the Code and not the Function! Edited January 27, 2011 by guinness

[EndFunc]

Maybe if you post some code I could have a look Because it sounds like a problem with the Code and not the Function!

Here is a little gui I maybe really quickly which is what Im using within my main gui.

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>

$ADResults = GUICreate("ADResults", 362, 254, 230, 154)
$ListView1 = GUICtrlCreateListView("", 16, 24, 329, 145, BitOR($LVS_REPORT,$LVS_SINGLESEL,$LVS_SHOWSELALWAYS,$WS_VSCROLL))
$adselect = GUICtrlCreateButton("Select", 40, 188, 105, 33, $WS_GROUP)
$adcancel = GUICtrlCreateButton("Cancel", 211, 188, 105, 33, $WS_GROUP)
Local $ListItem[UBound($aADResults)]
GUISetState(@SW_SHOW)
For $i = 1 To $aADResults[0]
GUICtrlSetData($ListItem[$i], $aADResults[$i])
Next
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

The array $aADResults comes from a query I do in Active Directory so I can't give you the array info. But it can be manually declared for testing.

BTW _arraydisplay works fine but I can't manipulate that.

Edited January 27, 2011 by EndFunc

[guinness]

I did this before I saw your reply >>

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    Local $ListView = GUICtrlCreateListView("Column 1", 10, 10, 200, 150)

    Local $Array[10] = [9, "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST"]
    Local $ListItem[UBound($Array, 1) - 1]
    For $i = 1 To $Array[0]
        $ListItem[$i - 1] = GUICtrlCreateListViewItem("", $ListView)
        GUICtrlSetData($ListItem[$i - 1], $Array[$i])
    Next
    GUISetState()

    Do
        Sleep(50)
    Until GUIGetMsg() = -3
EndFunc   ;==>Example

Edit: With your Example there a couple of things that won't work, so its best to have a look at my Example and any problems let me know

Edited January 27, 2011 by guinness

[guinness]

OK, so this is your Example with a few changes >>

_Example()

Func _Example()
    GUICreate("ADResults", 362, 254, 230, 154)
    Local $ListView = GUICtrlCreateListView("Column 1", 16, 24, 329, 145, BitOR($LVS_REPORT, $LVS_SINGLESEL, $LVS_SHOWSELALWAYS, $WS_VSCROLL))
    Local $OK= GUICtrlCreateButton("Select", 40, 188, 105, 33, $WS_GROUP)
    Local $Cancel = GUICtrlCreateButton("Cancel", 211, 188, 105, 33, $WS_GROUP)
    Local $aADResults[9] = ["TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST"]
    Local $ListItem[UBound($aADResults, 1) + 1]

    For $i = 0 To UBound($aADResults, 1) - 1
        $ListItem[$i] = GUICtrlCreateListViewItem("", $ListView)
        GUICtrlSetData($ListItem[$i], $aADResults[$i])
    Next
    GUISetState(@SW_SHOW)
    While 1
        Switch GUIGetMsg()
            Case -3, $Cancel
                Exit

        EndSwitch
    WEnd
EndFunc   ;==>_Example

[EndFunc]

I did this before I saw your reply >>

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    Local $ListView = GUICtrlCreateListView("Column 1", 10, 10, 200, 150)

    Local $Array[10] = [9, "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST", "TEST"]
    Local $ListItem[UBound($Array, 1) - 1]
    For $i = 1 To $Array[0]
        $ListItem[$i - 1] = GUICtrlCreateListViewItem("", $ListView)
        GUICtrlSetData($ListItem[$i - 1], $Array[$i])
    Next
    GUISetState()

    Do
        Sleep(50)
    Until GUIGetMsg() = -3
EndFunc   ;==>Example

Edit: With your Example there a couple of things that won't work, so its best to have a look at my Example and any problems let me know

Thank you for steering me in the right direction. The problem all along was I did not put a name for the first column. After I did that it worked.

$ListView1 = GUICtrlCreateListView("Name", 16, 24, 329, 145, BitOR($LVS_REPORT,$LVS_SINGLESEL,$LVS_SHOWSELALWAYS,$WS_VSCROLL))

Its the little things you over look. Thanks for your help.

[guinness]

Good, also the Example provided didn't work because $ADResults was a Handle of the GUI and not a 'fake' array!