Trapping WM_CHAR

[JosephE 0]

Ok, so i have this code:

#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>


; Test

Global $myGui = GUICreate("Hello", 500, 400)

GUIRegisterMsg($WM_CHAR, "HandleChar")

GUISetState(@SW_SHOW, $myGui)

While True
  $msg = GuiGetMsg()
  If $msg = $GUI_EVENT_CLOSE Then
    ExitLoop
  EndIf
WEnd

Func HandleChar($hWnd, $msgID, $wParam, $lParam)
  MsgBox(0, "Handled!", "It was handled. Character code: " & $wParam)
EndFunc

There's no edit control, so the WM_CHAR message should cause the HandleChar() function to be called, but it's not. I need to be able to handle that message, as I need a way of handling key presses for my custom text widget I'm rendering in GDI+.

Any help would be very much appreciated!

[Yashied 194]

Some controls consume internally specific Windows Message ID, so registrating them will have no effect, e.g; WM_CHAR, WM_KEYDOWN, WM_KEYUP are consumed by an edit control.

[JosephE 0]

I'm well aware of that, but i do not have an edit control present in my window. Obviously.

[eukalyptus 37]

Same problem here! WM_Char is not working

but WM_KEYDOWN does:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $hGui = GUICreate("Test", 500, 400)
GUIRegisterMsg($WM_KEYDOWN, "WM_KEYDOWN")
GUISetState(@SW_SHOW, $hGui)

While True
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
        ExitLoop
    EndIf
WEnd

Func WM_KEYDOWN($hWnd, $msg, $wParam, $lParam)
    Local $uScancode = BitAND(BitShift($lParam, 16), 0xFF)

    Local $tData = DllStructCreate("byte[256];")
    Local $pData = DllStructGetPtr($tData)
    Local $aResult = DllCall("user32.dll", "int", "GetKeyboardState", "ptr", $pData)

    Local $tChar = DllStructCreate("char[2];")
    Local $pChar = DllStructGetPtr($tChar)
    $aResult = DllCall("user32.dll", "int", "ToAscii", "uint", $wParam, "uint", $uScancode, "ptr", $pData, "ptr", $pChar, "uint", 0)
    If @error Then Return 'GUI_RUNDEFMSG'

    If $aResult[0] > 0 Then ConsoleWrite("! <" & DllStructGetData($tChar, 1) & ">" & @CRLF)

    Return 'GUI_RUNDEFMSG'
EndFunc   ;==>WM_KEYDOWN

[Yashied 194]

WM_KEYDOWN is used by some native AutoIt functions. In some cases, it may not work properly.

[monoscout999 9]

but WM_KEYUP works with all cases.