Returning from a function

[Meerecat 0]

Raising a good point JohnOne made regarding my last program. How do I return from a function without having to recall the function again.

Currently I delete and redraw the GUI:

Func _about()
GUIDelete() 
GUICreate("About", 302, 127)
GUISetBkColor(0xFFFFFF)
$Label2 = GUICtrlCreateLabel("Meerecat Folder Lock", 73, 8, 165, 23)
GUICtrlSetFont(-1, 12, 800, 0, "Leelawadee")
$Label3 = GUICtrlCreateLabel("Meerecat IT Services  ©2011", 152, 104, 145, 18)
GUICtrlSetFont(-1, 8, 400, 0, "Leelawadee")
$Label1 = GUICtrlCreateLabel("Version 2.0", 116, 32, 69, 19)
GUICtrlSetFont(-1, 10, 400, 0, "Leelawadee")
$Label4 = GUICtrlCreateLabel("www.meerecat-itservices.co.uk", 61, 56, 179, 19)
GUICtrlSetFont(-1, 10, 400, 0, "Leelawadee")
$Label5 = GUICtrlCreateLabel("(click here to visit)", 146, 72, 92, 18)
GUICtrlSetFont(-1, 8, 400, 0, "Leelawadee")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _main()

    EndSwitch
WEnd
EndFunc

This hides the main GUI and displays the about box. I would prefer to be able to leave the about box on top of the main gui, then when you close the about box the main gui still exists.

How can I fix this? I looked up Return in the help file, but closing the About box does not return any parameters so don't see how I can use this.

Do I somehow need to create this about gui as a child, so when you close it the parent still exists?

Many Thanks

[guinness 1,465]

Have a look at this >> http://www.autoitscript.com/wiki/Managing_Multiple_GUIs

[Andreik 60]

This can be a way:

Global $MAIN

$MAIN = GUICreate("Main")
$ABOUT = GUICtrlCreateButton("About",5,5,50,20)
GUISetState(@SW_SHOW,$MAIN)

While True
    Switch GUIGetMsg()
        Case $ABOUT
            About()
        Case -3
            Exit
    EndSwitch
    Sleep(10)
WEnd

Func About()
    GUISetState(@SW_HIDE,$MAIN) ;Optional to hide main window
    $ABOUT_GUI = GUICreate("About",250,250,Default,Default,Default,Default,$MAIN)
    GUISetState(@SW_SHOW,$ABOUT_GUI)
    While True
        If GUIGetMsg() = -3 Then ExitLoop
        Sleep(10)
    WEnd
    GUIDelete($ABOUT_GUI)
    GUISetState(@SW_SHOW,$MAIN) ;Optional to show main window [if was hidden]
EndFunc

or another way to process all GUI messages in same loop:

Global $MAIN

$MAIN = GUICreate("Main")
$ABOUT = GUICtrlCreateButton("About",5,5,50,20)
GUISetState(@SW_SHOW,$MAIN)

While True
    $MSG = GUIGetMsg(1)
    Switch $MSG[0]
        Case $ABOUT
            About()
        Case -3
            If $MSG[1] = $MAIN Then
                Exit
            Else
                GUIDelete($MSG[1])
                GUISetState(@SW_SHOW,$MAIN)
            EndIf
    EndSwitch
    Sleep(10)
WEnd

Func About()
    GUISetState(@SW_HIDE,$MAIN)
    $ABOUT_GUI = GUICreate("About",250,250)
    GUISetState(@SW_SHOW,$ABOUT_GUI)
EndFunc

[Meerecat 0]

Perfect. Thank you both very much. Now to go break all the gui's in my 2 programs with these updates