How do I set focus to/select a ListViewItem?

[nf67]

Apparently, GUICtrlSetState($ListViewItem, $GUI_Focus) doesn't work for ListViewItems ...

Any alternatives?

Thanks in advance.

Edited June 15, 2011 by nf67

[guinness]

_GUICtrlListView_SetItemFocused() perhaps?

Edited June 15, 2011 by guinness

[nf67]

Can't get it to work for some reason, using _GUICtrlListView_SetItemFocused($ListView, $IndexNumber) and nothing happens .

Also, is there no function which uses the ListViewItem handler, rather than the indexnumber it has in the ListView?

[guinness]

$hWnd - Handle to the control

Are you using the ControlID or the Handle which can be found by using GUICtrlGetHandle($iListView)? Because this uses the Handle not the ControlID. If you still have the problem could you post some code so I can help you

[nf67]

That's actually the handle for the ListView, not the ListViewItem, as can be seen in the example in the helpfile.

(edit: Ah I get what you're saying now, I was using the ControlID for the ListView, it seems to accept both, even though it only says handle in the helpfile.

Still need a 'real' selection though, as described below. And it would be nice if I could use the ControlID or handle for the item itself.)

Also, I now see that it only draws a dotted border around the item and doesn't actually select it the way it happens when you click it (making the item appear blue), which is what I need in the end.

Here's some code to test things with:

expandcollapse popup

#Include <GuiListView.au3>

HotKeySet("q","Quit")
HotKeySet("a","Add")
HotKeySet("f","Focus")

$GUI = GUICreate("GUI",180,300)
$List = GUICtrlCreateListView("#|Random|Random|",0,0,180,300)
GUISetState()

$ItemNumber = 0
$FocusItem = 3 ;Item to set focus to once F is pressed.
dim $Item[21]

While 1
    Sleep(100)
WEnd

Func Add()
    If $ItemNumber < 21 Then
        $Item[$ItemNumber] = GUICtrlCreateListViewItem("",$List)
        GUICtrlSetData($Item[$ItemNumber],$ItemNumber &"|"& Random(0,100,1) &"|"& Chr(Random(65,90,1)))
        $ItemNumber = $ItemNumber + 1
    Else
        MsgBox(0,"","No more than 20 items allowed.")
    EndIf
EndFunc

Func Quit()
    Exit
EndFunc

Func Focus()
    If $FocusItem <= $ItemNumber Then
        _GUICtrlListView_SetItemFocused($List,$FocusItem) ; Set focus to the the $FocusItem-th item.
    Else
        MsgBox(0,"","You haven't even added " & $FocusItem & " item(s) yet!")
    EndIf
EndFunc

Thanks for your help

Edited June 15, 2011 by nf67

[guinness]

Your Example didn't really show anything but if you have a look at GUICtrlCreateListView this Returns a ControlID not a Handle. I was going to use a generic ListView Script I have lying around but I thought it best I just update yours with using GUICtrlGetHandle and passing to the UDF Function, though I couldn't test it fully. Hope this gets you on the right track.

expandcollapse popup

#include <GuiListView.au3>

HotKeySet("q", "Quit")
HotKeySet("a", "Add")
HotKeySet("f", "Focus")

$GUI = GUICreate("GUI", 180, 300)
$iListView = GUICtrlCreateListView("#|Random|Random|", 0, 0, 180, 300)
$hListView = GUICtrlGetHandle(-1) ; <<<<< Handle of ListView.
GUISetState()

$ItemNumber = 0
$FocusItem = 3
Dim $Item[21]

While 1
    Sleep(100)
WEnd

Func Add()
    If $ItemNumber < 21 Then
        $Item[$ItemNumber] = GUICtrlCreateListViewItem("", $iListView)
        GUICtrlSetData($Item[$ItemNumber], $ItemNumber & "|" & Random(0, 100, 1) & "|" & Chr(Random(65, 90, 1)))
        $ItemNumber = $ItemNumber + 1
    Else
        MsgBox(0, "", "No more than 20 items allowed.")
    EndIf
EndFunc   ;==>Add

Func Quit()
    Exit
EndFunc   ;==>Quit

Func Focus()
    If $FocusItem <= $ItemNumber Then
        _GUICtrlListView_SetItemFocused($hListView, $FocusItem) ; Set focus to the the $FocusItem-th item. By using Handle of ListView.
    Else
        MsgBox(0, "", "You haven't even added " & $FocusItem & " item(s) yet!")
    EndIf
EndFunc   ;==>Focus

[BrewManNH]

Try this change:

Func Focus()
    If $FocusItem <= $ItemNumber Then
;~         _GUICtrlListView_SetItemFocused($List,$FocusItem) ; Set focus to the the $FocusItem-th item.
        _GUICtrlListView_SetItemSelected ($List,$FocusItem) ; Set focus to the the $FocusItem-th item.
    Else
        MsgBox(0,"","You haven't even added " & $FocusItem & " item(s) yet!")
    EndIf
EndFunc

[guinness]

BrewManNH's right if you want it to look as though you have clicked on it.

Some Functions will work with both but some won't, I think _GUICtrlListView_DeleteItem is one which only works with the Handle. I found out the hard way by using the ControlID on the ListView UDF Functions as it worked and I had no reason to use the Handle, but then I was stumped as to why I couldn't delete an Item!! So it's best coding practice to use what the Help File says

Edited June 15, 2011 by guinness

[UEZ]

Use _GUICtrlListView_SetItemSelected($List, $FocusItem) instead of _GUICtrlListView_SetItemFocused($List,$FocusItem).

Br,

UEZ

Edit: I was too slow...

Edited June 15, 2011 by UEZ

[nf67]

Ah sweet, yeah that's what I meant. Thanks a bunch!

@guinness: I know it only mentions that the parameter should be a handle in the helpfile, but it works fine if you use the ControlID, no need for GUICtrlGetHandle() apparently. There's no difference.

[guinness]

@guinness: I know it only mentions that the parameter should be a handle in the helpfile, but it works fine if you use the ControlID, no need for GUICtrlGetHandle() apparently. There's no difference.

OK, its just something I personally wouldn't do. I think some others will agree too.

And initially I didn't realise you wanted to show the blue selection

Edited June 15, 2011 by guinness

[wraithdu]

The listview UDF functions try to be smart about the control ID / handle input param. But it's undocumented functionality, and recently I had a problem where it didn't work with _GuiCtrlListView_DeleteItem. If you look at the function, it's a problem because passing a ctrl ID tries to get the item ID via _GUICtrlListView_GetItemParam. But if you didn't create the item with _GuiCtrlListView_AddItem (or similar) with a unique $iParam or with GuiCtrlCreateListViewItem, then the item ID doesn't exist and the function fails. So, be safe and use the handle like the documentation says.

Edited June 15, 2011 by wraithdu

[BrewManNH]

You'll find a few items in the listview UDF that don't work 100% correctly with a control ID, and some that just don't work at all with one. Of course there's functions in the listview UDF that don't work right with a handle unless you know the secret handshake to get it to work right (sorting for instance).