Using StringRegExp() and a delimited list to determine a match.

[guinness]

I was wondering would it be productive to create this Function using StringRegExp() instead? And I've tried searching on stackoverflow.com & regexadvice.com with little success of what Pattern I should use. Thanks.

MsgBox(64, "_IsExcluded()", _IsExcluded("C:\Program Files\Opera.exe", "opera.exe;autoit.exe;SciTE.exe"))

Func _IsExcluded($sFileName, $sExcluded = "opera.exe;autoit.exe;SciTE.exe")
    Local $aStringSplit = StringSplit($sExcluded, ";")
    For $A = 1 To $aStringSplit[0]
        If StringInStr($sFileName, $aStringSplit[$A]) Then
            Return 1
        EndIf
    Next
    Return 0
EndFunc   ;==>_IsExcluded

Edited June 30, 2011 by guinness

[jchd]

Not a formidable use of regexp:

MsgBox(64, "_IsExcluded()", _IsExcluded("C:\Program Files\Opera.exe", "opera\.exe|autoit\.exe|SciTE\.exe"))
MsgBox(64, "_IsExcluded()", _IsExcluded2("C:\Program Files\Opera.exe", "opera.exe;autoit.exe;SciTE.exe"))

Func _IsExcluded($sFileName, $sExcluded = "opera\.exe|autoit\.exe|SciTE\.exe")
    Return StringRegExp($sFileName, '(?i)' & $sExcluded)
EndFunc   ;==>_IsExcluded

Func _IsExcluded2($sFileName, $sExcluded = "opera.exe;autoit.exe;SciTE.exe")
    $sExcluded = StringReplace($sExcluded, '.', '\.')
    $sExcluded = '(?i)' & StringReplace($sExcluded, ';', '|')
    Return StringRegExp($sFileName, $sExcluded)
EndFunc   ;==>_IsExcluded2

[guinness]

No Way! Don't I feel a fool. I have this fear of SRE's which I need to overcome Thanks jchd. I have GEOSoft's PCRE Tool so I don't know why I didn't figure it out

[jchd]

I just meant: "this isn't a situation where regeps are so brilliant, due to glue code needed for dot --> \. and ; to |". I never meant: "how dumb are you for not being able to figure it out yourself".

It isn't fool-proof in this primitive form either:

MsgBox(64, "_IsExcluded()", _IsExcluded("C:\Program Files\this_proggy_is_not_Opera.exe.bad.extension", "opera\.exe|autoit\.exe|SciTE\.exe"))

If you need a more rigourous pattern, just ask.

[guinness]

I knew you weren't calling me dumb And how we I go about making it fool-proof? I've looked through the Help File and http://regexlib.com but I honestly wouldn't know where to begin

[jchd]

Try this:

expandcollapse popup

Local $test[10] = [ _
    "c:opera.exe", _
    "c:\gshogshoi ehofhoi\opera.exe", _
    "\\server\blah blah\opera.exe", _
    "\\server\blah blah\opera.exe\stillgood.com", _
    "it is silly to exclude AutoIt.exe\filezilla.exe", _
    "c:/forward slashes are OK in Windows paths as well - ha ha ha/scite.exe", _
    "Gotcha\scite.bat", _
    "trying to fool you\    opera.exe               ", _
    "trying more subtle workaround using non-break space and similar tricks\" & ChrW(0xA0) & ChrW(0x80) & ChrW(0x83) & "opera.exe", _
    "this time it gets around\opera.exe using this way" _
]

#cs
;; Unicode whitespace or similar codepoints
    {0x000000, 0x000020},   // control characters, most are unlikely
    {0x000080, 0x0000A0},   // control characters, other set also most unlikely
    {0x001680, 0x001680},   // Ogham sp mark
    {0x00180E, 0x00180E},   // Mongolian vowel separator
    {0x002000, 0x00200A},   // En quad, Em quad, En sp, Em sp, 3/em sp, 4/em sp, 6/em sp, Figure sp, Punctuation sp, Thin sp, Hair sp,
    {0x002028, 0x002029},   // Line separator, Paragraph separator
    {0x00205F, 0x00205F},   // Medium mathematical sp
    {0x003000, 0x003000},   // Ideographic sp
    {0x00FEFF, 0x00FEFF},   // BOM
#ce

For $prog In $test
    ConsoleWrite('"' & $prog & '"' & ' allowed : ' & (_IsExcluded($prog) = 0) & @LF)
Next

Func _IsExcluded($sFileName, $sExcluded = "opera.exe;autoit.exe;SciTE.exe")
    $sExcluded = StringReplace($sExcluded, '.', '\.')

    ; I'm investigating why this doesn't work
;~  $sExcluded = '(?i)(?<=^|[\\:/])[\x00-\x20\x80-\xA0\x1680\x180E\x2000-\x200A\x2028-\x2029\x205F\x3000]*(' & StringReplace($sExcluded, ';', '|') & ')[\x00-\x20\x80-\xA0\x1680\x180E\x2000-\x200A\x2028-\x2029\x205F\x3000]*$'
;~  StringRegExp($sFileName, $sExcluded)
;~  ConsoleWrite(@error & ' ' & @extended & @LF)

    $sExcluded = '(?i)(?<=^|[\\:/])[\x00-\x20\x80-\xA0]*(' & StringReplace($sExcluded, ';', '|') & ')[\x00-\x20\x80-\xA0]*$'
    Return StringRegExp($sFileName, $sExcluded)
EndFunc   ;==>_IsExcluded

Now I need to understand what happens for Unicode code points >= 0x1000 in hex form in patterns...

[guinness]

That was quick! You're the SRE Master and there is no way I would have concluded using that pattern. Thanks.

[jchd]

Not that quick. I had hard time with \x{nnnn}, not 100% clear to me still, but at least it's working for what we need.

Apply this change to deal with sneaky attempts:

$sExcluded =  '(?i)(?<=^|[\\:/])[\x00-\x20\x80-\xA0\x{1680}\x{180E}\x{2000}-\x{200A}\x{2028}-\x{2029}\x{205F}\x{3000}]*('  & StringReplace($sExcluded, ';', '|') &  ')[\x00-\x20\x80-\xA0\x{1680}\x{180E}\x{2000}-\x{200A}\x{2028}-\x{2029}\x{205F}\x{3000}]*$'

If you find it inelegant, change that into:

$sExcluded = '(?i)(?(DEFINE)(?<UnicodeWS>[\x00-\x20\x80-\xA0\x{1680}\x{180E}\x{2000}-\x{200A}\x{2028}-\x{2029}\x{205F}\x{3000}]))(?<=^|[\\:/])(?&UnicodeWS)*(' & StringReplace($sExcluded, ';', '|') & ')(?&UnicodeWS)*$'

[guinness]

Brilliant! I'll change it. Thanks jchd.

[jchd]

I'd like others to look at this and find eventually ways to circumvent the barrier. I didn't look at exactly which Unicode whitespace (or similar) Windows would allow around a program name and still ignore it, so this may need adjustment.

The idea is there anyway.

The last example shows the use of a named subroutine in a pattern, which I gave a meaningful name.