_SendMessage() does not send my private message

[AndyS01 0]

When I try to send a message to my main GUI window, it never arrives.

Here is my code:

expandcollapse popup

#Include <SendMessage.au3>
#Include <GuiConstantsEx.au3>
Opt("GUICloseOnESC", 1) ; ESC closes GUI
Opt("GUIOnEventMode", 1) ; Change to OnEvent mode
Opt('MustDeclareVars', 1)
Opt("GUIEventOptions", 1) ;0=default, 1=just notification, 2=GuiCtrlRead tab index
 
Global Const $myMESSAGE = 0x00099999
global $hWnd
 
_Main()
 
Func _Main()
    local $iBtn
 
$hWnd = GUICreate("Test", 150, 50)
$iBtn = GUICtrlCreateButton("Click Here", 10, 10, 100, 30)
 
GUISetOnEvent($GUI_EVENT_CLOSE, "Event_GUIClose")
GUICtrlSetOnEvent($iBtn, "handle_button_press")
 
GUISetOnEvent($myMESSAGE, "handle_myMESSAGE") ; Setup a handler for my message
 
GUISetState()
 
While 1
Sleep(500)
WEnd
EndFunc   ;==>_Main
 
Func handle_button_press()
ConsoleWrite("handle_button_press() entered" & @CRLF)
 
_SendMessage($hWnd, $myMESSAGE) ; Send a $myMESSAGE message to the main gui
 
EndFunc   ;==>handle_button_press
 
Func handle_myMESSAGE()
ConsoleWrite("handle_myMESSAGE() entered" & @CRLF)
EndFunc   ;==>handle_myMESSAGE
 
Func Event_GUIClose()
ConsoleWrite("Event_GUIClose() entered" & @CRLF)
Exit(1)
EndFunc   ;==>Event_GUIClose

I've tried a standard message ($GUI_EVENT_CLOSE), but that didn't work either.

[BrewManNH 978]

Try this line

GUIRegisterMsg($WM_COMMAND, "handle_myMESSAGE") ; Setup a handler for my message

In place of this line GUISetOnEvent($myMESSAGE, "handle_myMESSAGE") ; Setup a handler for my message and see if it works as you're expecting. You'll also need to add #include <WindowsConstants.au3> at the top of your script.

[Yashied 194]

Because you must use GUIRegisterMsg() instead of GUICtrlSetOnEvent().

#Include <GUIConstantsEx.au3>
#Include <WinAPI.au3>
 
Opt('GUIOnEventMode', 1)
 
Global Const $WM_MYMESSAGE = _WinAPI_RegisterWindowMessage('MyMessage')
 
Global $hWnd
 
_Main()
 
Func _Main()
    Local $iBtn
    $hWnd = GUICreate('Test', 150, 50)
    GUISetOnEvent($GUI_EVENT_CLOSE, 'Event_GUIClose')
    $iBtn = GUICtrlCreateButton('Click Here', 10, 10, 100, 30)
    GUICtrlSetOnEvent(-1, 'handle_button_press')
    GUIRegisterMsg($WM_MYMESSAGE, 'WM_MYMESSAGE')
    GUISetState()
    While 1
        Sleep(500)
    WEnd
EndFunc   ;==>_Main
 
Func handle_button_press()
    _SendMessage($hWnd, $WM_MYMESSAGE, 10, 99)
EndFunc   ;==>handle_button_press
 
Func Event_GUIClose()
    Exit
EndFunc   ;==>Event_GUIClose
 
Func WM_MYMESSAGE($hWnd, $iMsg, $wParam, $lParam)
    ConsoleWrite('WM_MYMESSAGE  $wParam = ' & Number($wParam) & '  $lParam = ' & Number($lParam) & @CR)
EndFunc   ;==>WM_MYMESSAGE

Edited September 3, 2011 by Yashied

[AndyS01 0]

Thank you, that worked very well.

Also, thanks for including an example, it helped me understand the process.

It might have saved me a lot of time if the help for _SendMessage() had a comment like "The $iMsg parameter value is for known windows message numbers. For a private message, you must register the private message using '_WinAPI_RegisterWindowMessage()'."

Or in the example, show a private message being sent as well as a known windows message.

Anyway, thanks again.

Andy