How can I Find and Replace multiple strings in multiple files ?

[jAutomator]

Hello group,

I am new to AutoIt and have a LITTLE experience in VBscript. I am building an AutoIt application with the following goals:

1 - Ask user to supply some strings

2 - Search specific files and replace ANY and ALL of the found strings with the user-supplied strings.

I found and I tweaked Larry's solution to work with a set of files as defined in an Array.

Here is the code I have so far, which DOES work, but I am wondering if a kind Guru here could tell me if there is a more elegant/efficient/safe way to accomplish this task. I will ultimately have in the neighborhood of 30 strings to replace in 15 different files. Some files will have all 30 strings, other files will have only a subset of the strings.

expandcollapse popup

;Define file set
Dim $arrFileSet[10], $filesCount
$arrFileSet[0] = "C:\Test\File0.bat"
$arrFileSet[1] = "C:\Test\File1.xml"
$arrFileSet[2] = "C:\Test\File2.ini"
$arrFileSet[3] = "C:\Test\File3.txt"
$arrFileSet[4] = "C:\Test\File4.txt"
$arrFileSet[5] = "C:\Test\File5.txt"
$arrFileSet[6] = "C:\Test\File6.txt"
$arrFileSet[7] = "C:\Test\File7.txt"
$arrFileSet[8] = "C:\Test\File8.txt"
$arrFileSet[9] = "C:\Test\File9.txt"
 
;Define user input variables
Dim $domain, $user, $pass, $share
$domain = InputBox("","Domain?")
$user = InputBox("","User?")
$pass = InputBox("","Pass?")
$share = InputBox("","Share?")
 
;Create array to store user input
Dim $arrUserInput[4]
$arrUserInput[0] = $domain
$arrUserInput[1] = $user
$arrUserInput[2] = $pass
$arrUserInput[3] = $share
 
;Create array to store to-be-replaced strings
Dim $arrStringsReplace[4], $stringToReplace, $stringCount
$arrStringsReplace[0] = "%domain%"
$arrStringsReplace[1] = "%user%"
$arrStringsReplace[2] = "%pass%"
$arrStringsReplace[3] = "%share%"
 
;Loop through files and strings
For $filesCount = 0 To 3
    $stringToReplace = FileRead($arrFileSet[$filesCount],FileGetSize($arrFileSet[$filesCount]))
  For $stringCount = 0 To 3
   $stringToReplace = StringReplace($stringToReplace, $arrStringsReplace[$stringCount], $arrUserInput[$stringCount])
   FileDelete($arrFileSet[$filesCount])
   FileWrite($arrFileSet[$filesCount],$StringToReplace)
  Next
Next

Thanks in advance!

[czardas]

I don't know why you are using FileDelete. I would be inclined to use FileOpen with mode set to 2 = Write mode (erase previous contents), and then use FileWrite to replace the text, after all the replacements have been made to the text (string variable).

Edited November 2, 2011 by czardas

[jAutomator]

I don't know why you are using FileDelete. I would be inclined to use FileOpen with mode set to 2 = Write mode (erase previous contents), and then use FileWrite to replace the text, after all the replacements have been made to the text (string variable).

I was using FileDelete because that is what I found in That said, I don't NEED to do it that way. So you are suggesting this instead?

FileOpen($arrFileSet[$filesCount], 2)

Edited November 2, 2011 by jsmcpn

[guinness]

Correct. I'll be releasing a renaming example in the next couple of days, check back to the examples section once I've completed it.

[BrewManNH]

There's also the command _ReplaceStringInFile that can do the same thing, it's basically just opening the file with a fileread, and then just finding all the occurences of the string to be replaced, and replaces it. Then writes the file back to the original file.

[jAutomator]

Correct. I'll be releasing a renaming example in the next couple of days, check back to the examples section once I've completed it.

Thanks Guinness, I am looking forward to seeing it.

[guinness]

Preview:

[jAutomator]

There's also the command _ReplaceStringInFile that can do the same thing, it's basically just opening the file with a fileread, and then just finding all the occurences of the string to be replaced, and replaces it. Then writes the file back to the original file.

Excellent! I like that much better. I also added a line to back up each file.

#include <File.au3>
For $filesCount = 0 To 3
FileCopy($arrFileSet[$filesCount], $arrFileSet[$filesCount] & ".bak")
  For $stringsCount = 0 To 3
   _ReplaceStringInFile($arrFileSet[$filesCount],$arrStringsFind[$stringsCount],$arrBuildVars[$stringsCount])
  Next
Next

Edited November 2, 2011 by jsmcpn

[Spiff59]

I'd think you would want your FileWrite() outside of the inner For/Next loop, so you're only executing it once per file, rather than after each variable replacement.

Something like:

#include <File.au3>
 
;Define and load file set
Local $arrFileSet
_FileReadToArray(@ScriptDir & "\files.txt", $arrFileSet)
 
;Define user input variables
Local $stringCount, $string[4] = ["Domain", "User", "Pass", "Share"]
;Define create arrays to store user input and to-be-replaced strings
Local $arrUserInput[4], $arrStringsReplace[4], $stringToReplace
For $x = 0 to 3
  $arrUserInput[$x] = InputBox("", $string[$x] & "?")
  $arrStringsReplace[$x] = "%" & $string[$x] & "%"
Next
 
;Loop through files and strings
For $filesCount = 1 To Ubound($arrFileSet) - 1
    $stringToReplace = FileRead($arrFileSet[$filesCount])
    For $stringCount = 0 To 3
      $stringToReplace = StringReplace($stringToReplace, $arrStringsReplace[$stringCount], $arrUserInput[$stringCount])
    Next
    FileMove($arrFileSet[$filesCount], $arrFileSet[$filesCount] & ".bak", 1)
    FileWrite($arrFileSet[$filesCount], $stringToReplace)
Next

I did a little more tinkering as well. You might find it useful to load your list of filenames from a text file as this example does. Then you can make changes to the list on-the-fly without recompiling your script.

PS - _ReplaceStringInFile() isn't very efficient for your particular needs, as you'll be opening, reading, rewriting, and closing each file 4 times (for each changed string) instead of just once with FileWrite().

Edited November 3, 2011 by Spiff59

[jAutomator]

Thanks Spiff59, I'll experiment with your idea. In the meantime, can you help me with using a 2D array?

EDIT: Nevermind, I figured it out:

($arrFileSet[$filesCount],$arrStringsFindReplace[$stringCount][0],$arrStringsFindReplace[$stringCount][1])

OLD:

I was thinking it would be better to use a single 2D array for find/replace instead of two 1D arrays, but I must be misunderstanding 2D, because I get an error with the code below.

Array variable has incorrect number of subscripts or subscript dimension range exceeded.:

_ReplaceStringInFile($arrFileSet[$filesCount],$arrStringsFindReplace[$stringCount],$arrStringsFindReplace[1])

_ReplaceStringInFile($arrFileSet[$filesCount],^ ERROR

Dim $arrStringsFindReplace[4][2], $stringCount
$arrStringsFindReplace[0][0]  = "%varDomain%"
$arrStringsFindReplace[0][1]  = $varDomain
$arrStringsFindReplace[1][0]  = "%varUser%"
$arrStringsFindReplace[1][1]  = $varUser
$arrStringsFindReplace[2][0]  = "%varPass%"
$arrStringsFindReplace[2][1]  = $varPass
$arrStringsFindReplace[3][0]  = "%varShare%"
$arrStringsFindReplace[3][1]  = $varShare
 
For $filesCount = 0 To UBound($arrFileSet)-1
  FileCopy($arrFileSet[$filesCount], $arrFileSet[$filesCount] & ".bak")
    For $stringCount = 0 To UBound($arrStringsFindReplace)-1
      _ReplaceStringInFile($arrFileSet[$filesCount],$arrStringsFindReplace[$stringCount],$arrStringsFindReplace[1])
  Next
Next

Thanks again all!

Edited November 4, 2011 by jsmcpn