Buttons not working when the script is running ?

[undream]

Here is a fairly simple problem. I'm probobly doing somethingwrong.

There is a GUI button, that I use to run my script loop.

When it is pressed (and my autoit script is runniing) no other buttons on my GUI (including the windows's close button) is not working any more.

I'm asking this to learn the point I am missing.

Waiting for a reply,

Thank you

[Mikeman27294]

You need to supply code or nobody can tell you what needs to be fixed.

[undream]

You are right.

Here is the simplified version of the code which has the very same problem.

I hope this explains the problem,

expandcollapse popup

#NoTrayIcon
#include <GUIListView.au3>
#include <GuiToolbar.au3>

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ###
$Aut = GUICreate("Automator", 335, 163, 438, 207)
$StartButton = GUICtrlCreateButton("START", 8, 120, 105, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$running = 0
$a = 0
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $StartButton
   if $running = 0 Then
    $running = 1
    GUICtrlSetData($StartButton, "STOP")
    init()
   Else
    $running = 0
    GUICtrlSetData($StartButton, "START")
   EndIf
EndSwitch
WEnd

func loop()
$a = $a + 1
Sleep(1000)
if $running = 1 Then
  loop()
EndIf
EndFunc
Func init()
   $a = 0
   loop()
EndFunc

Edited March 14, 2012 by undream

[guinness]

It's because you're sleeping for 1 second and you're looping within the function loop() so it never returns to the while loop where you're monitoring with GUIGetMsg. I would do it something like this & also read a little more of the Help file >>

expandcollapse popup

#NoTrayIcon
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $hTimer, $iCount = 0, $iRunning = 0
    Local $hGUI = GUICreate("Automator", 335, 160, 435, 205)
    Local $iLabel = GUICtrlCreateLabel("", 5, 10, 325, 20)
    Local $iStart = GUICtrlCreateButton("Start", 8, 120, 105, 30)
    GUISetState(@SW_SHOW, $hGUI)

    While 1
        If $iRunning Then ; Check if the $iRunning variable is greater than 0.
            If TimerDiff($hTimer) > 1000 Or $hTimer = 0 Then
                $iCount += 1 ; Add 1 to $iCount.
                _SetData($iLabel, $iCount) ; Set the label control.
                $hTimer = TimerInit() ; Reset the timer or start it depends on the situation.
            EndIf
        EndIf

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $iStart
                If $iRunning Then
                    GUICtrlSetData($iStart, "Start")
                Else
                    GUICtrlSetData($iStart, "Stop")
                EndIf
                $hTimer = 0
                $iRunning = (Not $iRunning) ; Set the variable to Not 'something' e.g. Not 1 would be 0.
                _SetData($iLabel, "")
        EndSwitch

    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>_Main

Func _SetData($iControlID, $sData)
    If GUICtrlRead($iControlID) <> $sData Then ; To stop flickering.
        GUICtrlSetData($iControlID, $sData)
    EndIf
EndFunc   ;==>_SetData

Edited March 14, 2012 by guinness

[undream]

Oh I get it now, thank you for the explanatory example !

I would love to know if ther is a way to use the timer like the sleep command, which I use a lot in my original code (not the simplified one)

Seemslike it will be impossible to use it this way,

How can I turn the timer into something that works almost like

_waitFor(1000)

[guinness]

Well you need to somehow monitor GUIGetMsg for when the button is selected, so perhaps something like this (not tested.)

Func _WaitFor($iTime, $iControlID)
    Local $hTimer = TimerInit(), $iMsg
    While 1
        $iMsg = GUIGetMsg()
        If TimerDiff($hTimer) > $iTime Or $iMsg = $iControlID Then
            ExitLoop
        EndIf
    WEnd
    Return 1
EndFunc   ;==>_WaitFor

[undream]

oh thank you, I will look into this. I got the logic behind it.

By the way, what I'm building overall is pretty simple, but... after your example I have another question in mind:

Is it normal that everything is inside of a big while loop ? I mean, is this what is supposed to be in a program with a gui ?

[guinness]

There should always be a loop to stop the program from exiting promptly, it doesn't matter whether or not you're using GUIGetMsg or GUIEventMode, there is always a loop somewhere. I prefer GUIGetMsg, just because I've been using it since day 1 and it allows me to achieve goals easily such as the one you presented here. But it depends on how you define 'big loop' as the one above I wouldn't class as big nor would I say that I've come close to creating a large loop which has affected performance.

[Chimaera]

Anything that monitors an event will be within the While-Wend, buttons, close events etc etc your functions etc are usually near the bottom and the gui layout and the making of the stuff and laying out the settings are usually above the while wend

Edited March 14, 2012 by Chimaera