Create array in a loop

[blumi]

How to create an array in a loop?

I don't know how many values are added to the array.

Do I have to create the array before start of the loop or do I create it in the loop?

Thanks

[guinness]

Like this...the key is ReDim. You should have a basic understanding of Arrays before you continue.

#include <Array.au3>

Example()

Func Example()
    Local $aArray[1] = [0] ; 0th index holds the number of items in the Array.

    For $i = 1 To 100
        $aArray[0] += 1 ; Increase the total count by 1 as we're going to add another value.
        ReDim $aArray[$aArray[0] + 1] ; Increase the array by 1 to accomodate the new value (but look at _ReDim in my signature.)
        $aArray[$aArray[0]] = $i ; Since we've increased the count by 1, add the data to that index.
    Next
    _ArrayDisplay($aArray)
EndFunc   ;==>Example

Also look in my signature at _ReDim it tells you how to increase the size of an array effectively without affecting performance.

[Melba23]

blumi,

At all costs avoid using ReDim on each pass through the loop - it is a really slow function, especially when arrays get big.

Here is a good way to create an array of unknown size in a loop - double the array size when necessary and then trim the unfilled elements at the end:

#include <Array.au3>

; Declare the array with a count
Global $aList[1] = [0]

; This is what we start with
_ArrayDisplay($aList, "Start")

For $i = 1 To 25

    ; Increase count
    $aList[0] += 1
    ; Double array size if too small (fewer ReDim needed)
    If UBound($aList) <= $aList[0] Then
        ReDim $aList[UBound($aList) * 2]
    EndIf
    ; Add item
    $aList[$aList[0]] = "Item " & $i

Next

; This is what we get after the loop
_ArrayDisplay($aList, "Filled")

; Now get rid of any unfilled elements
ReDim $aList[$aList[0] +1]

; And here is the result
_ArrayDisplay($aList, "Trimmed")

If you have some idea of the final size of the array, you can declare it with a much larger initial value - uses even fewer ReDims then.

M23

[guinness]

Directly taken from my article, 5000 items added to an Array, time is in milliseconds.

9015.65737361414 ; Increasing by 1 everytime.

76.3449705440588 ; Effectively increasing when required and by multiplying the size by 2, as suggested by Melba23.

You can see the difference is quite substantial. Edited March 28, 2012 by guinness