Looking for a way to automate MsWord

[computelgt]

Hello is there a way to autosave all open word docments to MyDocs every 5 min. The reason I need a real saved copy instead the autosave option in MsWord does not really save a copy.

[water]

You can either use the Word UDF that comes with AutoIt. Or write the code yourself (I can provide some assistance here).

[computelgt]

I would apreciate any help I would like for it to save all open word documents to MyDocs every 5min. I used the search function on this forum like I always do this is the first time I cant find an answer.

[water]

Something like this?

$oWord_Error = ObjEvent("AutoIt.Error", "_Word_ErrorHandler") ; Creates a custom error handler
$oWord_Appl = ObjGet("", "Word.Application") ; Connect to the Word application
If @error Then Exit MsgBox(16, "Error", "Error returned when connecting to the Word application. @error = " & @error)
For $oWord_Doc In $oWord_Appl.Documents ; Loop through all documetns
    $oWord_Doc.Save                  ; Save the document
    If @error Then Exit MsgBox(16, "Error", "Error returned when saving document " & $oWord_Doc.FullName & ". @error = " & @error)
Next
Exit


Func _Word_ErrorHandler()

    Local $bHexNumber = Hex($oWord_Error.number, 8)
    Local $sWord_Error = "COM Error Encountered in " & @ScriptName & @CRLF & _
            "@AutoItVersion = " & @AutoItVersion & @CRLF & _
            "@AutoItX64 = " & @AutoItX64 & @CRLF & _
            "@Compiled = " & @Compiled & @CRLF & _
            "@OSArch = " & @OSArch & @CRLF & _
            "@OSVersion = " & @OSVersion & @CRLF & _
            "Scriptline = " & $oWord_Error.scriptline & @CRLF & _
            "NumberHex = " & $bHexNumber & @CRLF & _
            "Number = " & $oWord_Error.number & @CRLF & _
            "WinDescription = " & StringStripWS($oWord_Error.WinDescription, 2) & @CRLF & _
            "Description = " & StringStripWS($oWord_Error.description, 2) & @CRLF & _
            "Source = " & $oWord_Error.Source & @CRLF & _
            "HelpFile = " & $oWord_Error.HelpFile & @CRLF & _
            "HelpContext = " & $oWord_Error.HelpContext & @CRLF & _
            "LastDllError = " & $oWord_Error.LastDllError
    MsgBox(64, "Word UDF - Debug Info", $sWord_Error)

EndFunc   ;==>_Word_ErrorHandler

[computelgt]

Thank you I have been using yout autoit code and it seems to be working just fine.

[water]

Glad you got your problem solved