_GUICtrlListView_AddSubItem

[Tomoya]

I have an array that I am trying to get to display in the ListView on my GUI. I know that the every other row in the array needs to be added as _GUICtrlListView_AddSubItem but I can't seem to get it working.

Here is the snippet that deals with creating the SubItems.

[

For $n = 1 To UBound($array) - 1
$OddCheck = _MathCheckDiv($n, 2)
If $OddCheck = 1 Then
_GUICtrlListView_AddItem($hListView, $array[$n])
ContinueLoop
ElseIf  $OddCheck = 2 Then
$i = 1
_GUICtrlListView_AddSubItem($hListView, $i, $array[$n], $i)
$i = $i + 1
ContinueLoop
EndIf
Next

Maybe it's something I am overlooking. :/

Edited November 12, 2012 by Tomoya

[guinness]

Use the return value of _GUICtrlListView_AddItem as the $iIndex parameter of _GUICtrlListView_AddSubItem.

[Tomoya]

Use the return value of _GUICtrlListView_AddItem as the $iIndex parameter of _GUICtrlListView_AddSubItem.

For $n = 1 To UBound($array) - 1
$OddCheck = _MathCheckDiv($n, 2)
If $OddCheck = 1 Then
$htest = _GUICtrlListView_AddItem($hListView, $array[$n])
ContinueLoop
ElseIf $OddCheck = 2 Then
$i = 1
_GUICtrlListView_AddSubItem($hListView, $htest, $array[$n], $i)
$i = $i + 1
ContinueLoop
EndIf
Next

Worked like a charm... I swear I tried this before, it's early in the morning. I think I need rest, lol. Thanks again!

[Melba23]

Tomoya,

This works for me:

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>

; As you start reading the array from element 1 I have done the same
Global $aArray[11] = [10, "Item 1", "SubItem 1", "Item 2", "SubItem 2", "Item 3", "SubItem 3", "Item 4", "SubItem 4", "Item 5", "SubItem 5"]
Global $iIndex = -1

$hGUI = GUICreate("Test", 500, 500)

$hListView = _GUICtrlListView_Create($hGUI, "", 10, 10, 280, 200)
_GUICtrlListView_AddColumn($hListView, "Item", 140)
_GUICtrlListView_AddColumn($hListView, "SubItem", 140)

; Loop throught he array
For $n = 1 To UBound($aArray) - 1
    ; Is it an odd number?
    If Mod($n, 2) Then
        ; Add the value and save the returned line index
        $iIndex = _GUICtrlListView_AddItem($hListView, $aArray[$n])
    Else
        ; Use the saved line index to position the subitem
        _GUICtrlListView_AddSubItem($hListView, $iIndex, $aArray[$n], 1)
    EndIf
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear?

M23

[guinness]

Tomoya,

I can't understand $i = $i + 1 as you reset it to 1 everytime and you also don't need continueloop.

[Tomoya]

Tomoya,

I can't understand $i = $i + 1 as you reset it to 1 everytime and you also don't need continueloop.

You seem to be several steps ahead of me! I was adding a count column and just came across this. I removed it and just set the value to 1.

Tomoya,

This works for me:

All clear?

M23

Yep that does work. Thanks for the example. Going to use Mod() rather than the _Math function I was calling so I can get rid of the #include. Thanks for the help.

Edited November 12, 2012 by Tomoya