_SingletonHWID() - Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.

[TheSaint]

It's not that I can't determine what I need to do myself to do what I want, so much as following/knowing all the rules/guidelines for doing a UDF for others. And you have made a great start, though I've realized there is a significant difference in our objectives now. I really need time to think through how to modify yours for what I want, because I've now anticipated some stumbling blocks, that weren't obvious initially ... but then, I'd been pulled into your topic by curiosity, and then imagining on the fly ever since. It's not like I started with a firm objective ... it's just been coalescing as we went through suggested additions to yours.

EDIT

I may call on your help though, if a significant stumbling block halts my attempt. That's supposing I find the time to getting around to an attempt. So thanks for the offer.

Edited December 20, 2012 by TheSaint

[guinness]

If you do decide to edit it then I would like to know the additional options you added. Right now I see the function as feature complete as it doesn't overwhelm the end user with an array of flags and they can do what they like with the GUI handle.

[TheSaint]

Yes, well I think we are talking about a whole different animal now, as much as they would share similarities.

It's not a matter of me making a version of your script/udf, as it will serve a different purpose.

I don't see a scenario for minimize or show, hide, etc. I just see it as -

1) Report to user that the program is already running, and maybe give an option to run another instance or not.

2) Don't report to the user, and don't allow another instance.

3) Don't report to the user, and allow another instance (possibly with determining criteria).

4) Don't report to the user, don't allow another instance, and restore the first instance to prominence.

That's pretty much it as i see it. 4 flags if you like.

The difficulties I envisage, and where perhaps our main difference lies, is where each program needs a unique marker automatically ... md5 hash perhaps?

Edited December 21, 2012 by TheSaint

[guinness]

1) Report to user that the program is already running, and maybe give an option to run another instance or not.

$iFlag option 1. If they want to run another instance they let the script continue otherwise they Exit.

2) Don't report to the user, and don't allow another instance.

$iFlag option 0. It will Exit automatically.

3) Don't report to the user, and allow another instance (possibly with determining criteria).

What criteria? Also why would you use _Singleton in this instance? Or just use $iFlag option 1/2 and let the script continue and don't display any message box.

4) Don't report to the user, don't allow another instance, and restore the first instance to prominence.

$iFlag option 1 (PID) or 2 (hWnd) and the user can determine how to restore the instance. What happens if the user's application doesn't have a GUI? How would you restore the first instance?

_Singleton will always report if another instance is running or not. It's what the end user does with that information that is the deciding factor.

The difficulties I envisage, and where perhaps our main difference lies, is where each program needs a unique marker automatically ... md5 hash perhaps?

PID + occurrence name. Edited December 21, 2012 by guinness

[guinness]

Is this what you really wanted?

 

expandcollapse popup

#include <APIDiagConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIDiag.au3>

; Use the HWID id of the user's system and return the hWnd set previously.
Local $hSingleton = _SingletonHWID(Default, 2)

If $CmdLine[0] = 0 Then
    If @Compiled Then
        Run(@ScriptFullPath & ' /OneInstance', @WorkingDir)
    Else
        Run(@AutoItExe & ' "' & @ScriptFullPath & '" /OneInstance', @WorkingDir)
    EndIf
EndIf

If $hSingleton = 0 Then
    Example()
Else
    MsgBox($MB_SYSTEMMODAL, '', 'There is another instance running. The hWnd of the first instance is: ' & $hSingleton & @CRLF & _
            'The window will be focused once this MsgBox has been closed.')
EndIf

Func Example()
    Local $hGUI = GUICreate('', 400, 300)
    Local $iClose = GUICtrlCreateButton('Close', 310, 265, 85, 30)
    GUISetState(@SW_SHOW, $hGUI)

    WinSetTitle($hGUI, '', 'PID: ' & @AutoItPID & ', hWnd: ' & $hGUI)

    ; Set the handle returned by GUICreate to be used by other applications that call _SingletonHWID.
    _SingletonHWID(Default, -1, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iClose
                ExitLoop

        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonHWID
; Description ...: Enforce a design paradigm where only one instance of the script may be running with using a unique id based on the user's hardware.
; Syntax ........: _SingletonHWID([$sOccurenceName = Default[, $iFlag = 0[, $hGUI = Default]]])
; Parameters ....: $sOccurenceName      - [optional] String to identify the occurrence of the script with the unique id. Default is Blank.
;                                         If this is left blank then the unqiue hardware id is use.
;                  $iFlag               - [optional] Optional parameters. Default is 0.
;                  -1 - Set the $hGUI parameter to be used later by other applications that call _SingletonHWID.
;                  0 - Exit the script with the exit code -1 if another instance already exists.
;                  1 - Return the PID of the main executable and without exiting the script too.
;                  2 - Return the hWnd of the main executable and without exiting the script too. This will set the hWnd into focus.
;                  $hGUI                - [optional] A valid GUI handle. Default is 0x0000000000000000 (no handle.)
; Return values .: Success - 0 No other process is running.
;                  Failure - The PID or hWnd of the main executable. See flags for return type.
; Author ........: guinness with initial ideas by Valik for _Singleton & KaFu for _EnforceSingleInstance.
; Remarks .......: Requires WinAPIEx.au3 & APIConstants.au3.
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonHWID($sOccurenceName = Default, $iFlag = 0, $hGUI = Default)
    If $iFlag = Default Then
        $iFlag = 0
    EndIf
    If $sOccurenceName = Default Then
        $sOccurenceName = ''
    EndIf
    Local $sGUID = _WinAPI_UniqueHardwareID(BitOR($UHID_MB, $UHID_BIOS, $UHID_HDD)) & '_' & StringStripWS($sOccurenceName, 8)
    Local $hWnd = WinGetHandle($sGUID)
    If @error Then
        AutoItWinSetTitle($sGUID)
        $hWnd = WinGetHandle($sGUID)
        If IsHWnd($hGUI) = 0 Then
            $hGUI = '0x0000000000000000'
        EndIf
        ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), 'PID:' & @AutoItPID & '|hWnd:' & $hGUI)
    Else
        Local $sData = ControlGetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'))
        If $sData = '' Then
            $sData = 'PID:' & @AutoItPID & '|hWnd:0x0000000000000000'
        EndIf
        Local $aSRE = StringRegExp($sData, 'PID:(\d+)|hWnd:(0x[[:xdigit:]]+)', 3)
        $aSRE[0] = Number($aSRE[0])
        If $iFlag = -1 And IsHWnd($hGUI) And ($aSRE[0] = @AutoItPID) Then
            ControlSetText($hWnd, '', ControlGetHandle($hWnd, '', 'Edit1'), 'PID:' & $aSRE[0] & '|hWnd:' & $hGUI)
            Return -2
        EndIf
        If Not ($aSRE[0] = @AutoItPID) Then
            If BitAND($iFlag, 1) Then
                Return $aSRE[0] ; Return PID when $iFlag is 1.
            ElseIf BitAND($iFlag, 2) Then
                $aSRE[1] = HWnd($aSRE[1])
                If BitAND(WinGetState($aSRE[1]), 16) Then ; Window is minimised.
                    WinSetState($aSRE[1], '', @SW_RESTORE)
                Else
                    WinSetState($aSRE[1], '', @SW_SHOW)
                EndIf
                Return $aSRE[1] ; Return hWnd when $iFlag is 2.
            EndIf
            Exit -1
        EndIf
    EndIf
    Return 0
EndFunc   ;==>_SingletonHWID

Edited April 23, 2014 by guinness

[TheSaint]

What criteria? Also why would you use _Singleton in this instance?

Perhaps another process running that might cause issues, especially during program startup?

I haven't devoted much thought to it, as its a scenario I feel unlikely to use personally, but I can imagine there may be scenarios where it can be ok to have multiple instances running, as there would be to not, even if only temporarily.

What happens if the user's application doesn't have a GUI? How would you restore the first instance?

Does that matter?

Surely you wouldn't set the flag if there wasn't a GUI.

PID + occurrence name.

That may do the trick?

Have to think it through though, as the occurrence name at least, by my reckoning would be identical every time (i.e. Author's name). I'm a slow thinker and have too many distractions at the moment, but PID seems reasonable.

EDIT

I'll have to check your latest example above later and get back to you ... too many things on the go right now ... heads almost spinning. Brain fatigue here I come.

Edited December 22, 2012 by TheSaint

[guinness]

Does that matter?

Surely you wouldn't set the flag if there wasn't a GUI.

No it doesn't and no you wouldn't. I was merely pointing out that to 'give focus' to the first instance isn't always a possible option.

That may do the trick?

Have to think it through though, as the occurrence name at least, by my reckoning would be identical every time (i.e. Author's name). I'm a slow thinker and have too many distractions at the moment, but PID seems reasonable.

The occurrence name would be static of course, but the PID would change with every instance of the application. I can also think of other approaches to changing the occurrence name and using AutoIt's hidden window.

I will leave you to look into this though, as it seems to be veering away from my initial design brief.

[guinness]

Updated both examples by replacing 4096 with the constant variable $MB_SYSTEMMODAL and chaged the return value datatype of the PID from a double to a Int32 number.

[guinness]

Updated code in certain parts of this thread, as the Forum software removed backslashes for the regular expression.

[guinness]

Updated the first post only. I kind of feel this function was badly designed from the start so don't feel like updating it any more.

[TheSaint]

Just the other month, I became aware of flag/parameter you can use with _Singleton, so I crafted something, that I updated today, based on a recent discussion here in Examples.

I don't recall being aware of the flag during our older discussions above.

Anyway, even though I haven't yet catered (and may never do) for renaming by a user, I decided to share my simple basic effort here. It essentially does what I asked for in this topic.

[guinness]

Why not make your code a UDF, as right now it's difficult to configure not to mention you're exposing a lot of global variables which are generic in naming. Let me know if you need help.

Edited December 6, 2015 by guinness

[TheSaint]

Thanks for the offer, but it was just something I whipped up for myself, that I thought might be worth sharing. So just an example, a snippet of code really. It no doubt could do with some improvements, like catering for a name change by user, etc.

Others of course can utilize it how they wish, even make a UDF if they feel so motivated.

It's not really that hard to adjust, just a couple of program name changes, plus naming of variables and magic numbers to whatever is the accepted practice, if that is of concern.

P.S. I don't usually share snippets in Examples, but as it was something that I've discussed before here, and I needed to make a change to my code tonight anyway, I thought I would ... as it adds some meat to that earlier discussion.

[guinness]

You say it's a couple of changes but then I am thinking of those who aren't skilled at adapting snippets and simply copy and paste. Maybe some comments would help too as I must admit I am not skilled at reading other people. Thanks for sharing and making me aware of your solution.

Edited December 7, 2015 by guinness

[TheSaint]

No worries.

People here will do what they need to, just as you and I have. We've both done plenty of adapting in our time.

It fits in with my philosophy of not handing everything over on a glass platter anyway.

And of course all are free to ask when not sure about something.

Most comments of course, are in the Help file for each command I use, and so hopefully the additional ones I have given etc are enough on top of that. It is a pretty simple script/snippet anyway. But perhaps I should add some more.

My aim is to be helpful while at the same time, get others to engage their grey cells.

I'd hate for any of us to be hampered or deterred from offering snippets and examples, because we can't find the motivation or time to go that extra mile and create something like a UDF for instance ... or heaps of comments.

My idea, is your provide the basics so that others have a starting point at least. Where they go from there, is up to them.

But each of us to their own approach. Your view is just as valid as mine ... possibly more .... but then you are more of a perfectionist than I am ... hence your well earned position.

[Shark007]

I've tried several singleton solutions and guinness' detection does it best.
I also like TheSaints' approach on how to handle the positive detection.
Below is my mashup of the work you 2 created separately. (which works beautifully)

 

expandcollapse popup

#include <APIDiagConstants.au3>
#include <StringConstants.au3>
#include <WinAPIDiag.au3>

; FYI - user needs to configure  'MyApp.exe' and 'This is MyApp'
; FYI No other changes required

#Region ;Single app enforcement
SingleApp()
Func SingleApp()
    Local $iSingleton = _SingletonHWID('MyApp.exe')
    If $iSingleton <> "" Then
        Local $script, $wins, $w, $handle, $Scriptname
        $Scriptname = 'This is MyApp'
        $script = @AutoItPID
        $wins = WinList($Scriptname, "")
        For $w = 1 To $wins[0][0]
            $handle = $wins[$w][1]
            WinSetState($handle, "", @SW_RESTORE)
            WinActivate($handle)
        Next
        ProcessClose($script)
    EndIf
EndFunc   ;==>SingleApp

Func _SingletonHWID($sUniqueName)
    Local $iReturn
    Local $sOccurenceName = _WinAPI_UniqueHardwareID($UHID_MB)
    $sOccurenceName &= '_' & $sUniqueName
    Local $hAutoItWnd = WinGetHandle($sOccurenceName)
    If @error Then
        AutoItWinSetTitle($sOccurenceName & @AutoItPID)
        $hAutoItWnd = WinGetHandle($sOccurenceName & @AutoItPID)
        AutoItWinSetTitle($sOccurenceName)
        Local Const $hControl = ControlGetHandle($hAutoItWnd, '', 'Edit1')
        ControlSetText($hAutoItWnd, '', $hControl, ControlGetText($hAutoItWnd, '', $hControl) & @CRLF & _
                '|SINGLETON_HWID:' & @AutoItPID & @CRLF)
    Else
        $iReturn = Int(StringRegExp(ControlGetText($hAutoItWnd, '', ControlGetHandle($hAutoItWnd, '', 'Edit1')) & @CRLF & _
                '|SINGLETON_HWID:0' & @CRLF, _
                '\|SINGLETON_HWID:(\d+)\R', $STR_REGEXPARRAYGLOBALMATCH)[0])
    EndIf
    Return $iReturn
EndFunc   ;==>_SingletonHWID
#EndRegion ;Single app enforcement

 

Edited November 29, 2019 by Shark007
only use the motherboard ID

[guinness]

Thanks for the feedback, much appreciated