StdinWrite and StdoutRead question

[Nunos]

I am trying to make an input box pop up and ask for a user to enter a url and then pass that to nslookup and read the results that come back and display them. The most recent version is below but I can not get the thing to exit and I am not getting all of the expected returned results. Not sure where I messed this up but if someone will teach me what I did wrong I would appreciate it.

#include 

$NSLookupURL = InputBox("NSLookup", "Enter the URL to perform the Name Server Lookup on.", "www.bing.com")
Local $nslookup = Run(@ComSpec & " /c nslookup", @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDERR_MERGED)

StdinWrite($nslookup,$NSLookupURL)
Local $line
While 1
$line = StdoutRead($nslookup)
If @error Then ExitLoop
MsgBox(0, "STDOUT read:", $line)
WEnd

While 1
$line = StderrRead($nslookup)
If @error Then ExitLoop
MsgBox(0, "STDERR read:", $line)
WEnd

MsgBox(0, "Debug", "Exiting...")

[water]

This code works for me:

#include <Constants.au3>
$NSLookupURL = InputBox("NSLookup", "Enter the URL to perform the Name Server Lookup on.", "www.bing.com")
Local $pid = Run(@ComSpec & " /c nslookup " & $NSLookupURL, @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD + $STDERR_CHILD)
If @error Then Exit MsgBox(0, "Error", "Error " & @error & " occurred when running NSLOOKUP")
StdinWrite($pid, @CRLF)
StdinWrite($pid)
; STDOUT
$sSTDOUT = ""
While 1
    $sOutput = StdoutRead($pid)
    If @error Then ExitLoop
    If $sOutput <> "" Then $sSTDOUT = $sSTDOUT & @CRLF & $sOutput
WEnd
; STDERR
$sSTDERR = ""
While 1
    $sOutput = StderrRead($pid)
    If @error Then ExitLoop
    If $sOutput <> "" Then $sSTDERR = $sSTDERR & @CRLF & $sOutput
WEnd
ConsoleWrite("STDOut: " & $sSTDOUT & @LF)
ConsoleWrite("STDErr: " & $sSTDERR & @LF)

[BrewManNH]

I'd do it this way myself.

#include <Constants.au3>
Global $OutLine = ""

$NSLookupURL = InputBox("NSLookup", "Enter the URL to perform the Name Server Lookup on.", "www.bing.com")
Local $nslookup = Run(@ComSpec & " /c nslookup", @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDERR_MERGED)
Sleep(1000) ; Just in case it needs time to start up
StdinWrite($nslookup, $NSLookupURL & @CRLF) ; Needs the enter key hit before it will process what's on the line
Local $line
StdinWrite($nslookup) ; Close the stream so it reads what you've sent to it.
While 1
    $line = StdoutRead($nslookup)
    If @error Then ExitLoop
    $OutLine &= $line 
WEnd
MsgBox(64, "", $OutLine) ; one message box rather than 100's
$OutLine = ""
While 1
    $line = StderrRead($nslookup)
    If @error Then ExitLoop
    $OutLine &= $line
WEnd
MsgBox(64, "", $OutLine)

MsgBox(0, "Debug", "Exiting...")

I'm not sure your StdInWrite would work for this command, because you never close the stream or send the Enter key after the data.

Edited December 19, 2012 by BrewManNH

[Nunos]

Awesome thanks for the help!!! I appreciate you taking your time to explain it to me so I can learn better.

[water]

Glad to be of service

[Nunos]

Sorry to bring this back up again but I was wondering if there is a way to have a user Copy/Paste the results from the msgbox? I thought if I made it Modal they could copy and paste the results into a chat window but I couldn't. Would I need to get the output into something like a GUI window or something else?

[somdcomputerguy]

You might be able to ClipGet the results and then paste it wherever.

[Nunos]

I am sorry I am not sure if that will allow someone else to copy the results from the msgbox and paste them say into like a chat room window.

[somdcomputerguy]

What I was thinking: use ClipGet in your program, the person running the program can then paste into whatever.

[Nunos]

I will research that some and see if I can make it work thank you for the help.

[somdcomputerguy]

You bet. Hope it helps you out. Good luck.