Good coding practices in AutoIt

[BrewManNH]

Declare variables where they are needed.

; Do I need to post an example?

Maybe not an example, but an explanation would be good. Because I THINK I know what you mean, but not really sure.

[guinness]

I could, but learncpp.com does a better job. Read the section labelled Where to declare variables.

Source: http://www.learncpp.com/cpp-tutorial/21-basic-addressing-and-variable-declaration/

[guinness]

Enum is often practical in certain situations:

#include <Constants.au3>

Example()

Func Example()
    ; Create variables in Local scope and enumerate through the variables. Default is to start from 0.
    Local Enum $eCat, $eDog, $eMouse, $eHamster ; $eHamster is equal to the value 3, not 4.

    ; Create an array in Local scope with 4 elements.
    Local $aAnimalNames[4]

    ; Assign each array element with the name of the respective animal. For example the name of the cat is Jasper.
    $aAnimalNames[$eCat] = 'Jasper' ; $eCat is equal to 0, similar to using $aAnimalNames[0]
    $aAnimalNames[$eDog] = 'Beethoven' ; $eDog is equal to 1, similar to using $aAnimalNames[1]
    $aAnimalNames[$eMouse] = 'Pinky' ; $eMouse is equal to 2, similar to using $aAnimalNames[2]
    $aAnimalNames[$eHamster] = 'Fidget' ; $eHamster is equal to 3, similar to using $aAnimalNames[3]

    ; Display the values of the array.
    MsgBox($MB_SYSTEMMODAL, '', '$aAnimalNames[$eCat] = ' & $aAnimalNames[$eCat] & @CRLF & _
            '$aAnimalNames[$eDog] = ' & $aAnimalNames[$eDog] & @CRLF & _
            '$aAnimalNames[$eMouse] = ' & $aAnimalNames[$eMouse] & @CRLF & _
            '$aAnimalNames[$eHamster] = ' & $aAnimalNames[$eHamster] & @CRLF)

    ; Sometimes using this approach for accessing an element is more practical than using a numerical value, due to the fact changing the index value of
    ; the enum constant has no affect on it's position in the array. Therefore changing the location of $eCat in the array is as simple as changing the order
    ; it appears in the initial declaration e.g.

    ; Local Enum $eDog, $eMouse, $eCat, $eHamster

    ; Now $eCat is the 2nd element in the array. If you were using numerical values, you would have to manually change all references of $aAnimalNames[0] to
    ; $aAnimalNames[2], as well as for the other elements which have now shifted.
EndFunc   ;==>Example

Edited January 25, 2013 by guinness

[guinness]

Just so you're aware, if your example demonstrates a good understanding of programming and it benefits the community, I may add it to the help file. For example I've included the Enum demonstration (see above) in the help file. Though it MUST adhere to good coding practice.

So you can make a difference on the future of AutoIt and the help file.

Edit: I'm also far from perfect and make the obvious mistake or two, though isn't that how you learn?

Edited January 25, 2013 by guinness

[czardas]

Declare variables where they are needed.

; Do I need to post an example?

I modified to include a comment about this along with points made by two other members.

[trancexx]

czardas using loop variable outside the loop is not example of good progtamming practice. That goes for any language known to me, including AutoIt.

It can be just tolerated if declared before the loop.

[czardas]

czardas using loop variable outside the loop is not example of good progtamming practice. That goes for any language known to me, including AutoIt.

It can be just tolerated if declared before the loop.

Okay thanks, It's always a pleasure to get advice from you. I'll fix it.

Edited January 25, 2013 by czardas

[czardas]

It's been amended. I hope the post is still useful after these changes.

Don't be shy, please provide examples of good and/or bad coding practices.

Thanks for starting this thread and for putting up with my mistakes. The thread is very useful.

Edited January 27, 2013 by czardas

[guinness]

A couple of tweaks I would make are using $MB_OK instead of 0, but this is only a minor issue.

Thanks for amending and most importantly posting. If you're interested I have been reading this site (http://www.learncpp.com) and I have to say in the last 24 hours my mind has been blown away by the stuff I didn't know.

Edited January 25, 2013 by guinness

[guinness]

I came across this article about 'Coding Standards for AutoIt' though I would argue that it still could be improved further and most of the information listed there has already been covered here.

Don't be shy, please provide examples of good and/or bad coding practices.

[Mat]

May, or may not, have been mentioned already.

UDF Specification wiki page: http://www.autoitscript.com/wiki/UDF-spec

[guinness]

No I don't think it has been referenced. Did you notice the MsgBox in the example?

[guinness]

Learn the unique of art of debugging. (In the end it will save you time.)

Most questions that are found on the Forum can easily be fixed/answered by the developer themselves, with patience and the art of reading back through their code would have resulted in the question being answered before posting in the Forum. 9 times out of 10 it's the user's misunderstanding and NOT AutoIt's fault, which is often the mistake a user makes when posting.

Well structured code and use of appropriate comments will further improve your debugging skills.

Note: Learning to debug is universal across all languages and isn't limited to just AutoIt.

#include <Constants.au3>

; Going through the code line by line will reveal a major flaw in my logic.
Example()

Func Example()
    Local $hWnd = WinGetHandle('myProg') ; Handle of the window titled 'myProg'.
    If Not (Not (@error = 0)) Then MsgBox($MB_SYSTEMMODAL, '', 'An error occurred.') ; Display a message box if an error exists.

    MsgBox($MB_SYSTEMMODAL, '', 'hWnd: ' & $hWnd) ; Display a message box of the handle.
EndFunc   ;==>Example

[Mat]

No I don't think it has been referenced. Did you notice the MsgBox in the example?

that needs to be updated to use the new multiple examples thing too. I'll add it to the list of jobs for tomorrow.

[guinness]

Test your code.

It still surprises me even now, that people ask "does this work" without even giving it a try themselves. What's the worst that can happen? It doesn't work so you go back to the drawing board.

[AZJIO]

I started doing this, but found the "Debug Management" section.

Edited January 29, 2013 by AZJIO

[guinness]

AZJIO,

One word...Dim. That's the definition of irony, creating a debugger that uses a keyword (for variable scope) which is the primary reason users end up debugging.

I like your idea, but try to use Local or Global respectively.

Edited January 29, 2013 by guinness

[Mat]

A very common design pattern:

Local $a[1][2] = [[0, 0]]

For $i = 1 To 10
    $a[0][0] += 1
    ReDim $a[$a[0][0] + 1][2]

    $a[$a[0][0]][0] = $i
    $a[$a[0][0]][1] = 10 * $i
Next

Since AutoIt lacks complex structures, arrays are the only way to store information. As a result, there is always the possibility that I want to add a column to this array. Future-proof yourself:

Local $a[1][2] = [[0, 0]]

For $i = 1 To 10
    $a[0][0] += 1
    ReDim $a[$a[0][0] + 1][UBound($a, 2)]

    $a[$a[0][0]][0] = $i
    $a[$a[0][0]][1] = 10 * $i
Next

Yes, keeping counters in $a[0][0] gets ugly too, but that's not the point

[guinness]

This reinforces what I and others have been saying >>

[guinness]