put text files in html table

[superbosu]

Hi all,

I'm new with autoit and I trying to do a script that read from 3 txt files and put all rows in a html file as a table

for example:

file1.txt have this data

row 1

row 2

row 3

row 4

...

row n

file2.txt have this data:

row 1b

row 2b

row 3b

row 4b

....

row nb

file3.txt have this data:

row 1c

row 2c

row 3c

row 4c

....

row nc

my question is if is possible in autoit to put this 3 files in a final.html file in a table like this:

row 1 row 1b row 1c

row 2 row 2b row 2c

row 3 row 3b row 3c

row 4 row 4b row 4c

... ..... .......

row n row nb row nc

Can somebody help with this script? I'know how to read the files but I don't know how to join all together in a table

Tnx for your precious help and sorry for my bad english.

Edited January 15, 2013 by superbosu

[jdelaney]

FileRead to read in the data from the 3 files, to their own strings

StringSplit to split by @crlf to their own arrays

I'd use XML doms to build the html table.

You will need to make lots of nodes (starting at the <table>, then make the 3 <tr>s, then loop through the above arrays, and add <td>s

http://www.w3schools.com/dom/dom_nodes_create.asp

edit: xml dom would probably be overkill, just concat strings with the proper html tag surrounding it.

Edited January 15, 2013 by jdelaney

[GMK]

_FileReadToArray might be simpler than FileRead and StringSplit (although that's what the UDF does).

[guinness]

Or StringRegExp? There are many ways to do this, just use the help file to find out how to use the functions presented to you in this thread.

[superbosu]

tnx for the quick reply all! I tring to read the 3 files with the array function and i created 3 arrays

_FileReadToArray("D:\file1.txt", $Array1)  

_FileReadToArray("D:\file2.txt", $Array2)
 
_FileReadToArray("D:\file3.txt", $Array3)

but I don't know how to use the loop of these 3 arrays to write in the new file concatenated rows like these:

$file = FileOpen("D:\final.txt", 1)
FileWriteLine($file,'<tr>')
    FileWriteLine($file,'<td>'& row 1 &'</td>')  ; how to put there the first value of the array1 ?
    FileWriteLine($file,'<td>'& row 1b &'</td>')   ; how to put there the first value of the array2 ?
    FileWriteLine($file,'<td>'& row 1c &'</td>')    ; how to put there the first value of the array3 ?
    FileWriteLine($file,'</tr>')

I have to use 3 arrays?

[jdelaney]

Use a For loop:

For $i = 1 To UBound ($Array1) - 1
FileWriteLine($file,'<td>' & $Array1[$i] & '</td>')
Next

Make sure to wrap the for loop with your <TR> input

edit: wait a sec, you want the row to be a combo the nTH data point from each file? That's a little different

Edited January 15, 2013 by jdelaney

[jdelaney]

You can do something like this

Edit: I made it dynamic to pick up any number of files...just update the $sFolder to your directory that holds all the files

expandcollapse popup

#include <array.au3>
#include <File.au3>
$sFolder = @DesktopDir & "\DataFiles\"
; Where above dir includes any number of files...example:
; $sFile1 = 'test1a' & @LF & 'test1b' & @LF & 'test1c' ... to however many
; $sFile2 = 'test2a' & @LF & 'test2b' & @LF & 'test2c' ... to however many
; $sFile3 = 'test3a' & @LF & 'test3b' & @LF & 'test3c' ... to however many
; $sFile4 = 'test4a' & @LF & 'test4b' & @LF & 'test4c' ... to however many
$aFiles = _FileListToArray($sFolder, "*", 1)
If $aFiles[0] > 0 Then
 Dim $aFileData[$aFiles[0]]
Else
 MsgBox(1,1,"No files and/or dir=[" & $sFolder & "]")
 Exit
EndIf
; Read in all the file's data
For $i = 1 To UBound ($aFiles) - 1
 Dim $aTemp[1]
 _FileReadToArray($sFolder & $aFiles[$i],$aTemp)
 $aFileData[$i-1] = $aTemp
Next
$iUbound1D = 0
; Get the second dimention needs
For $i = 0 To UBound ($aFileData) - 1
 $aTemp = $aFileData[$i]
 If UBound ($aTemp)-1 > $iUbound1D Then $iUbound1D = UBound ($aTemp)-1
Next
; create an array with proper bounds to house all data
Dim $aAllData[$iUbound1D][$aFiles[0]]
; Transpose the data of the files
For $i = 0 To UBound ($aAllData,2) - 1
 $aTemp = $aFileData[$i]
 For $j = 1 To UBound ($aTemp) - 1
  $aAllData[$j-1][$i] = $aTemp[$j]
 Next
Next
; Just a display of the array
_ArrayDisplay($aAllData)
ConsoleWrite("<HTML>" & @CRLF)
ConsoleWrite("<Table>" & @CRLF)
For $i = 0 To UBound ($aAllData) - 1
 ConsoleWrite("<tr>" & @CRLF)
 For $j = 0 To UBound ($aAllData, 2) - 1
  ConsoleWrite("<td>" & $aAllData[$i][$j] & "</td>" & @CRLF)
 Next
 ConsoleWrite("</tr>" & @CRLF)
Next
ConsoleWrite("</Table>" & @CRLF)
ConsoleWrite("</HTML>" & @CRLF)

output would be:

<HTML>

<Table>

<tr>

<td>test1a</td>

<td>test2a</td>

<td>test3a</td>

<td>test4a</td>

</tr>

<tr>

<td>test1b</td>

<td>test2b</td>

<td>test3b</td>

<td>test4b</td>

</tr>

<tr>

<td>test1c</td>

<td>test2c</td>

<td>test3c</td>

<td>test4c</td>

</tr>

<tr>

<td>test1d</td>

<td>test2d</td>

<td>test3d</td>

<td>test4d</td>

</tr>

<tr>

<td>test1e</td>

<td>test2e</td>

<td>test3e</td>

<td>test4e</td>

</tr>

</Table>

</HTML>

Edited January 15, 2013 by jdelaney

[guinness]

superbosu,

If you don't understand the basics of Arrays, then I suggest reading http://www.autoitscript.com/wiki/Arrays as this is a good start to understanding the basics.

Edited January 15, 2013 by guinness

[superbosu]

WOOOOW jdelaney it works!!

TNX a lot for helping me with this script. It does exactly what I needed. :thumbsup: