Close a GUI without exit

[russell]

I wrote a script that makes several GUI's on one i have it set to contuie the script afer 'OK' is pressed. How do i get it to close that GUI and still contiue...i know i cant use exit or the script will terminate.

[kylomas]

russell,

Use guidelete()

And if you are running a message loop in a function then "return" on $gui_event_close instead of exit.

kylomas

[russell]

thank you very much

[guinness]

russell,

Use guidelete()

And if you are running a message loop in a function then "return" on $gui_event_close instead of exit.

kylomas

ExitLoop is more favourable.

[kylomas]

russell,

guiness is quite right. A boilerplate might look like this

expandcollapse popup

; *** Start added by AutoIt3Wrapper ***
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
; *** End added by AutoIt3Wrapper ***

#AutoIt3Wrapper_Add_Constants=n

;------------------------------------------------------------------------------------------------
;  Main GUI
;------------------------------------------------------------------------------------------------

local $gui010   =   guicreate('Primary Gui')
local $aSize10  =   wingetclientsize($gui010)
local $lbl010   =   guictrlcreatelabel('Click on me for Secondary Gui',0,20,$aSize10[0],50,bitor($ss_sunken,$ss_center))
                    guictrlsetfont(-1,16,600)
                    guisetstate()

while 1
    switch guigetmsg()
        case $gui_event_close
            Exit
        case $lbl010
            _MyFunc()
    EndSwitch
WEnd

;------------------------------------------------------------------------------------------------
;  Secondary GUI
;------------------------------------------------------------------------------------------------

func _MyFunc()

    local $gui020   =   guicreate('Secondary Gui',500,200)
    local $aSize20  =   wingetclientsize($gui020)
    local $lbl020   =   guictrlcreatelabel('My Secondary Gui',20,20,$aSize20[0]-40,50,bitor($ss_sunken,$ss_center))
                        guictrlsetfont(-1,12,800,default,'Comic Sans Serif')
                        guisetstate()

    while 1
        switch guigetmsg()
            case $gui_event_close
                guidelete($gui020)
                Exitloop
        EndSwitch
    WEnd

    Return

endfunc

kylomas

edit: corrected spacing

Edited February 28, 2013 by kylomas

[Amathian]

If you run into the problem, as I did, where you would have to click the Exit button multiple times when using GUIDelete(), change

While 1

to

While $msg <> $GUI_EVENT_CLOSE

It worked for me, not sure if it is the optimal way to do it, though

Edited March 1, 2013 by Amathian

[kylomas]

Amathian,

There is something else wrong with your code. Are you issueing guigetmsg() multiple times, a long sleep in the msgloop, a long running function actioned by a control in the msgloop, etc?

If you post your code we'll take a look...

kylomas