Keep ArrayDisplay Open ?

[Chimaera]

I was wondering is there a way after you have opened an _ArrayDisplay Window to be able to isolate it so you can carry on with the script and still read the info from the window as needed?

The script does other things with the data after the window but i need to input column numbers etc from the window for the rest of the script to work from.

Any thoughts on the simplest way to do this?

[czardas]

Make your own ArrayDisplay using a ListView control. This is the best solution (I think). Why does the display need to be open to input column numbers? Can't you determine the column numbers in a different way / automatically?

If you use use ListView, a user could select a column by clicking on it. You have to write the code to make this work though - just a thought.

Edited November 11, 2013 by czardas

[Chimaera]

The columns have header names so its a way of looking to get the correct header (which has a number} and you can input the number in the gui

Array display on big files takes an age to open which isnt good

[czardas]

Array display can only handle a certain amount of data too. An easier / faster solution might be to just create a Combo box with the header names to click on - Select Column (for this operation). I'm assuming this to be csv related from other recent questions.

Edited November 11, 2013 by czardas

[guinness]

Also _ArrayDIsplay() is a debugging function only and shouldn't be used in production code.

[mikell]

Making a custom _ArrayDisplay() from the original one is easy but it means nothing else than czardas' first suggestion

And as you need to remove the included blocking While loop you obviously loose the _ArrayDisplay() 'copy' feature

expandcollapse popup

#include <Array.au3>

Local $avArray[20]
$avArray[0] = "JPM"
$avArray[1] = "Holger"
$avArray[2] = "Jon"
$avArray[3] = "Larry"
$avArray[4] = "Jeremy"
$avArray[5] = "Valik"
$avArray[6] = "Cyberslug"
$avArray[7] = "Nutster"
$avArray[8] = "JdeB"
$avArray[9] = "Tylo"
$avArray[10] = "JPM"
$avArray[11] = "Holger"
$avArray[12] = "Jon"
$avArray[13] = "Larry"
$avArray[14] = "Jeremy"
$avArray[15] = "Valik"
$avArray[16] = "Cyberslug"
$avArray[17] = "Nutster"
$avArray[18] = "JdeB"
$avArray[19] = "Tylo"

$ret = _ArrayDisplay2($avArray, "$avArray")
Msgbox(0,"", "_ArrayDisplay2 didn't block" &@cr&@cr& "handle gui = " & $ret[0] &@cr& "handle LV = " & $ret[1])

;==========================================

Func _ArrayDisplay2(Const ByRef $avArray, $sTitle = "Array: ListView Display", $iItemLimit = -1, $iTranspose = 0, $sSeparator = "", $sReplace = "|", $sHeader = "")
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1) - 1, $iSubMax = UBound($avArray, 2) - 1
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    ; Separator handling
    If $sSeparator = "" Then $sSeparator = Chr(124)

    ;  Check the separator to make sure it's not used literally in the array
    If _ArraySearch($avArray, $sSeparator, 0, 0, 0, 1) <> -1 Then
        For $x = 1 To 255
            If $x >= 32 And $x <= 127 Then ContinueLoop
            Local $sFind = _ArraySearch($avArray, Chr($x), 0, 0, 0, 1)
            If $sFind = -1 Then
                $sSeparator = Chr($x)
                ExitLoop
            EndIf
        Next
    EndIf

    ; Declare variables
    Local $vTmp, $iBuffer = 4094 ; AutoIt max item size
    Local $iColLimit = 250
    Local $iOnEventMode = Opt("GUIOnEventMode", 0), $sDataSeparatorChar = Opt("GUIDataSeparatorChar", $sSeparator)

    ; Swap dimensions if transposing
    If $iSubMax < 0 Then $iSubMax = 0
    If $iTranspose Then
        $vTmp = $iUBound
        $iUBound = $iSubMax
        $iSubMax = $vTmp
    EndIf

    ; Set limits for dimensions
    If $iSubMax > $iColLimit Then $iSubMax = $iColLimit
    If $iItemLimit < 1 Then $iItemLimit = $iUBound
    If $iUBound > $iItemLimit Then $iUBound = $iItemLimit

    ; Set header up
    If $sHeader = "" Then
        $sHeader = "Row  " ; blanks added to adjust column size for big number of rows
        For $i = 0 To $iSubMax
            $sHeader &= $sSeparator & "Col " & $i
        Next
    EndIf

    ; Convert array into text for listview
    Local $avArrayText[$iUBound + 1]
    For $i = 0 To $iUBound
        $avArrayText[$i] = "[" & $i & "]"
        For $j = 0 To $iSubMax
            ; Get current item
            If $iDimension = 1 Then
                If $iTranspose Then
                    $vTmp = $avArray[$j]
                Else
                    $vTmp = $avArray[$i]
                EndIf
            Else
                If $iTranspose Then
                    $vTmp = $avArray[$j][$i]
                Else
                    $vTmp = $avArray[$i][$j]
                EndIf
            EndIf

            ; Add to text array
            $vTmp = StringReplace($vTmp, $sSeparator, $sReplace, 0, 1)

            ; Set max buffer size
            If StringLen($vTmp) > $iBuffer Then $vTmp = StringLeft($vTmp, $iBuffer)

            $avArrayText[$i] &= $sSeparator & $vTmp
        Next
    Next

    ; GUI Constants
    Local Const $_ARRAYCONSTANT_GUI_DOCKBORDERS = 0x66
    Local Const $_ARRAYCONSTANT_GUI_DOCKBOTTOM = 0x40
    Local Const $_ARRAYCONSTANT_GUI_DOCKHEIGHT = 0x0200
    Local Const $_ARRAYCONSTANT_GUI_DOCKLEFT = 0x2
    Local Const $_ARRAYCONSTANT_GUI_DOCKRIGHT = 0x4
    Local Const $_ARRAYCONSTANT_GUI_EVENT_CLOSE = -3
    Local Const $_ARRAYCONSTANT_LVM_GETCOLUMNWIDTH = (0x1000 + 29)
    Local Const $_ARRAYCONSTANT_LVM_GETITEMCOUNT = (0x1000 + 4)
    Local Const $_ARRAYCONSTANT_LVM_GETITEMSTATE = (0x1000 + 44)
    Local Const $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE = (0x1000 + 54)
    Local Const $_ARRAYCONSTANT_LVS_EX_FULLROWSELECT = 0x20
    Local Const $_ARRAYCONSTANT_LVS_EX_GRIDLINES = 0x1
    Local Const $_ARRAYCONSTANT_LVS_SHOWSELALWAYS = 0x8
    Local Const $_ARRAYCONSTANT_WS_EX_CLIENTEDGE = 0x0200
    Local Const $_ARRAYCONSTANT_WS_MAXIMIZEBOX = 0x00010000
    Local Const $_ARRAYCONSTANT_WS_MINIMIZEBOX = 0x00020000
    Local Const $_ARRAYCONSTANT_WS_SIZEBOX = 0x00040000

    ; Set interface up
    Local $iWidth = 640, $iHeight = 280
    Local $hGUI = GUICreate($sTitle, $iWidth, $iHeight, Default, Default, BitOR($_ARRAYCONSTANT_WS_SIZEBOX, $_ARRAYCONSTANT_WS_MINIMIZEBOX, $_ARRAYCONSTANT_WS_MAXIMIZEBOX))
    Local $aiGUISize = WinGetClientSize($hGUI)
    Local $hListView = GUICtrlCreateListView($sHeader, 0, 0, $aiGUISize[0], $aiGUISize[1] , $_ARRAYCONSTANT_LVS_SHOWSELALWAYS)
    GUICtrlSetResizing($hListView, $_ARRAYCONSTANT_GUI_DOCKBORDERS)
    GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE, $_ARRAYCONSTANT_LVS_EX_GRIDLINES, $_ARRAYCONSTANT_LVS_EX_GRIDLINES)
    GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE, $_ARRAYCONSTANT_LVS_EX_FULLROWSELECT, $_ARRAYCONSTANT_LVS_EX_FULLROWSELECT)
    GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE, $_ARRAYCONSTANT_WS_EX_CLIENTEDGE, $_ARRAYCONSTANT_WS_EX_CLIENTEDGE)

    ; Fill listview
    For $i = 0 To $iUBound
        GUICtrlCreateListViewItem($avArrayText[$i], $hListView)
    Next

    ; adjust window width
    $iWidth = 0
    For $i = 0 To $iSubMax + 1
        $iWidth += GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_GETCOLUMNWIDTH, $i, 0)
    Next
    If $iWidth < 250 Then $iWidth = 230
    $iWidth += 20

    If $iWidth > @DesktopWidth Then $iWidth = @DesktopWidth - 100
    WinMove($hGUI, "", (@DesktopWidth - $iWidth) / 2, Default, $iWidth)
    GUISetState(@SW_SHOW, $hGUI)

    Opt("GUIOnEventMode", $iOnEventMode)
    Opt("GUIDataSeparatorChar", $sDataSeparatorChar)

        Local $aret[2]
    $aret[0] = $hGUI
        $aret[1] = GuiCtrlGetHandle($hListView)
        Return $aret
EndFunc   ;==>_ArrayDisplay2

Edited November 11, 2013 by mikell

[guinness]

The function can be stripped even further, because at present it's "bloated" to accommodate everyone's usage.

[Chimaera]

Array display can only handle a certain amount of data too. An easier / faster solution might be to just create a Combo box with the header names to click on - Select Column (for this operation). I'm assuming this to be csv related from other recent questions.

It is CSV related, ill have a read up on Combo stuff

Also _ArrayDIsplay() is a debugging function only and shouldn't be used in production code.

Ok didnt know that, ive never used t like this before so it was only an idea

As to making one i only need to see it nothing else

Thx for the other suggestions

Edited November 11, 2013 by Chimaera

[jdelaney]

Create a compiled script to call.  You will have to transfer the data somehow...maybe create a csv you read in, where the csv is the paramater sent to the second script.

Then it's a second process, and will not hinder the first (called via run())

Edited November 11, 2013 by jdelaney

[guinness]

Or if you're feeling dangerous look at IPC (inter-process communication) e.g. MailSlot or WM_COPYDATA.

[czardas]

Having looked at this particular (or a similar) project in an earlier stage of development, I think the user would find it easiest to select by clicking on a list of column Headers. A ComboBox control would be perfect for this.

Loading the whole csv file into a ListView control (like array display) will take time and potentially use a lot of memory which may then impact on the other processes. It's nice to see everything, but this may not be the most practical route - especially if the csv is quite large. Unless you plan to combine this with a csv viewer, it is my opinion you should keep it simple and try the combobox examples in the helpfile, otherwise you may find you have your work cut out.

The software to view the csv files already exists on your client's machine, otherwise they would not be using csv format in the first place.

Edited November 11, 2013 by czardas