Help with TimerInit() and TimerDiff()

[Burgaud 0]

$Clock = TimerInit()

; 3.98 seconds later

TimerDiff($Clock) would give me 3980

Is there a way to "Freeze/Pause" $Clock such that TimerDiff() would not increase?

ie

$Clock = TimerInit()

; 2 seconds later

Pause $Clock

;5 seconds later

TimerDiff($Clock) would give me 2000

unpause $Clock

.

.

.

3 seconds later

TimerDiff($Clock) would give me 5000

Is this possible?

[water 2,068]

No.

What do you try to achieve?

[jdelaney 307]

If when you 'pause' you start another time, you can do some subtraction and get the time:

HotKeySet("b", "PauseTimer")
HotKeySet("c", "escape")
$bConsoleWrite = False
$PausedCummulative = 0
$bPaused = False
$ThePausedTimer = 0
$TheTimer = TimerInit()
While True

    While $bPaused
        Sleep(100)
        $bConsoleWrite = True
    WEnd

    Sleep(100)
    If $bConsoleWrite Then
        $PausedCummulative+=TimerDiff($ThePausedTimer)
        ConsoleWrite(Round(TimerDiff($TheTimer)/1000,2) & @tab & "-" & Round($PausedCummulative/1000,2) & @tab & "=" & Round((TimerDiff($TheTimer)-$PausedCummulative)/1000,2) & @CRLF )
        $bConsoleWrite = False
    EndIf
WEnd

Func PauseTimer()
    $bPaused = Not $bPaused
    If $bPaused Then
        $ThePausedTimer = TimerInit()
        ConsoleWrite("Initiate paused timer" & @CRLF)
    Else
        ConsoleWrite("End paused timer" & @CRLF)
    EndIf
EndFunc

Func escape()
    Exit
EndFunc

[Chimp 557]

also AdlibRegister() may be useful...

#include <GUIConstantsEx.au3>
Global $Paused = True ; True or False
Global $MyTimer = 0 ; Actual timer position

AdlibRegister("MyTimer", 100) ; function fired every 100 ms

$Form1_1 = GUICreate("MyTimer", 120, 70, 100, 100)
$seconds = GUICtrlCreateLabel($MyTimer, 10, 10, 80, 25)

$Toggle_Button = GUICtrlCreateButton("Toggle timer", 10, 40, 100, 20)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Toggle_Button
            ToggleTimer()
    EndSwitch
WEnd

Func MyTimer()
    If Not $Paused Then
        $MyTimer += 0.1
        GUICtrlSetData($seconds, $MyTimer)
    EndIf
EndFunc   ;==>MyTimer

Func ToggleTimer()
    $Paused = Not $Paused
EndFunc   ;==>ToggleTimer

Edited May 9, 2014 by Chimp