Mapping controlids to an array.

[guinness]

expandcollapse popup

#include <Array.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>

; Proof of concept for using the control id as an index item for an array. I created back on 8th April 2013.
Example()

Func Example()
    ; Create the GUI.
    Local $iHeight = 400, $iWidth = 400
    Local $hGUI = GUICreate('', $iWidth, $iHeight)
    GUISetState(@SW_SHOW, $hGUI)

    ; Declare variables to be used throughout the example.
    Local Const $BUTTON_ROWS_COLUMNS = 8
    Local Enum $eCTRL_HWND, $eCTRL_VALUE, $eCTRL_MAX
    Local $aMsg[1][$eCTRL_MAX], _
            $iButtonHeight = $iHeight / $BUTTON_ROWS_COLUMNS, _
            $iButtonWidth = $iWidth / $BUTTON_ROWS_COLUMNS, _
            $iControlID = 0

    For $i = 0 To $BUTTON_ROWS_COLUMNS - 1
        For $j = 0 To $BUTTON_ROWS_COLUMNS - 1
            $iControlID = GUICtrlCreateButton($i & ',' & $j, $i * $iButtonWidth, $j * $iButtonHeight, $iButtonWidth, $iButtonHeight, $BS_CENTER)

            ; Increase the size of the array if the control id is greater than or equal to the total size of the array.
            If $iControlID >= UBound($aMsg) Then
                ReDim $aMsg[Ceiling($iControlID * 1.3)][$eCTRL_MAX]
            EndIf

            ; Add to the array.
            $aMsg[$iControlID][$eCTRL_HWND] = GUICtrlGetHandle($iControlID)
            $aMsg[$iControlID][$eCTRL_VALUE] = 'Sample string for the control id: ' & $iControlID
        Next
    Next

    ; Clear empty items after the last created control id.
    ReDim $aMsg[$iControlID + 1][$eCTRL_MAX]

    ; Display the array created.
    _ArrayDisplay($aMsg)

    Local $iMsg = 0
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $aMsg[$eCTRL_HWND][$eCTRL_HWND] To UBound($aMsg)
                ; If $iMsg is greater than 0 and between the 0th index of $aMsg and the last item then display in the console.
                If $iMsg > 0 Then
                    ConsoleWrite('Control Hwnd: ' & $aMsg[$iMsg][$eCTRL_HWND] & ', ' & $aMsg[$iMsg][$eCTRL_VALUE] & @CRLF)
                EndIf
        EndSwitch
    WEnd

    GUIDelete($hGUI)
EndFunc   ;==>Example

 

Edited April 22, 2018 by guinness
Minor updates to variable names

[jchd]

With the new Map variant you won't have anymore to worry when/if controlids are out of sequence, nor the need for ReDims btw.

[BrewManNH]

Does the new map allow 2D? If not, then it's not exactly the same thing.

[guinness]

Does the new map allow 2D? If not, then it's not exactly the same thing.

It doesn't, but jchd is correct that this can be converted to use the map data structure. The key would be the controlid and the value would be the output string.

It's the reason I posted, as if/when the map/table type is stable I have an example to work with to show users how it works. As I get the distinct feeling some people are going to have a hard figuring it out.

Edited July 18, 2014 by guinness