List of "windows" opened and not minimized

[akorx]

Hi my friends,

I try to find all the windows opened and not minimized, but it includes the taskbar of windows which is not a "normal" window... I use winlist() but maybe it's not the best solution, so I can use another one.

Have you got a solution to find ONLY all windows opened by "normal" programs (like winword, notepad, firefox, etc) and that are not minimized ?

PS : sorry for my bad english

Edited January 31, 2015 by akorx

[water]

You could use WinGetState on every returned window to check if they are minimized or hidden etc.

[akorx]

Hi MVPs,

I've already tested this solution but windows taskbar appears like the others programs, so it's seems not to be the best solution... another idea? or perhaps I don't use WinGetState() correctly?

[water]

Hi MVPs,

Or perhaps I don't use WinGetState() correctly?

Don't know. You need to post your code.

[water]

BTW: The name of my account is "water". MVPs is the group I belong to.

[akorx]

Ok, this could be an example :

$var = WinList()

For $i = 1 to $var[0][0]
   ; Only display visble windows that have a title
   If $var[$i][0] <> "" AND IsVisible($var[$i][1]) Then ; AND WinGetState($var[$i][0],16)<>16 Then
   ConsoleWrite( "Title=" & $var[$i][0] & " - " & "Handle=" & $var[$i][1] & @CRLF)
   EndIf
Next


Func IsVisible($handle)
If BitAnd( WinGetState($handle), 2 ) Then
Return 1
Else
Return 0
EndIf
EndFunc

[water]

This displays all windows which are visible and not minimized. The Desktop still seems to be included.

$aWinList = WinList()

For $i = 1 To $aWinList[0][0]
    ; Only display visble windows that have a title
    If $aWinList[$i][0] <> "" And IsVisible($aWinList[$i][0], $aWinList[$i][1]) Then
        ConsoleWrite("Title=" & $aWinList[$i][0] & " - " & "Handle=" & $aWinList[$i][1] & @CRLF)
    EndIf
Next

Func IsVisible($sTitle, $hHandle)
    If $sTitle = "Program Manager" Then Return 0
    $iState = WinGetState($hHandle)
    If BitAND($iState, 2) = 2 And _ ; Visible
    BitAND($iState, 16) <> 16 Then ; Not minimized
        Return 1
    Else
        Return 0
    EndIf
EndFunc   ;==>IsVisible

[akorx]

 

This displays all windows which are visible and not minimized. The Desktop still seems to be included.

$aWinList = WinList()

For $i = 1 To $aWinList[0][0]
    ; Only display visble windows that have a title
    If $aWinList[$i][0] <> "" And IsVisible($aWinList[$i][0], $aWinList[$i][1]) Then
        ConsoleWrite("Title=" & $aWinList[$i][0] & " - " & "Handle=" & $aWinList[$i][1] & @CRLF)
    EndIf
Next

Func IsVisible($sTitle, $hHandle)
    If $sTitle = "Program Manager" Then Return 0
    $iState = WinGetState($hHandle)
    If BitAND($iState, 2) = 2 And _ ; Visible
    BitAND($iState, 16) <> 16 Then ; Not minimized
        Return 1
    Else
        Return 0
    EndIf
EndFunc   ;==>IsVisible

Nice work, but I've got this result :

>"C:Program Files (x86)AutoIt3SciTE..autoit3.exe" /ErrorStdOut "D:DocumentsAutoitWindowsGridwindows.au3"    

Title=Démarrer - Handle=0x000100AE

Title=D:DocumentsAutoitWindowsGridwindows.au3 - SciTE-Lite [2 of 2] - Handle=0x00930466

Title=Sans titre - Bloc-notes - Handle=0x002A02D6

Title=Sans nom 1 - LibreOffice Writer - Handle=0x008903E4

>Exit code: 0    Time: 0.09789

and Title=Démarrer - Handle=0x000100AE is not a program like the others ! another idea ?

[water]

I get the same (but in english: Start). Looks like the Window name for the desktop.

When using Alt+Tab to loop through the windows, Desktop seems to be the window named "Start" or "Démarrer" in your case.

[akorx]

So I could use a filter to reject "start" or "démarrer" but it's not nice and furthermore imagine I want to publish my program to people that speak another language that yours and mine, how will I do ?

Antoher idea?

[water]

This >thread does the same. It excludes some windows by name or class.

[akorx]

Yes I see... but I think there is necessarily a better solution, but which, that the question !

Perhaps a way with another autoit function? or with a windows dll?

[TheSaint]

This >thread does the same. It excludes some windows by name or class.

I was just going to say, that Class is what I've used in the past, just getting it to skip known classes for things like the Program Manager (Explorer, etc).

[jguinch]

You can also try to skip windows having the $WS_EX_TOOLWINDOW style (it's just an idea, please do not hit me )

#include <WinAPI.au3>
#include <WindowsConstants.au3>

$aWinList = WinList()

For $i = 1 To $aWinList[0][0]
    ; Only display visble windows that have a title
    ; If $aWinList[$i][0] <> "" Then
    If $aWinList[$i][0] <> "" And IsVisible($aWinList[$i][0], $aWinList[$i][1]) Then
        ConsoleWrite("Title=" & $aWinList[$i][0] & " - " & "Handle=" & $aWinList[$i][1] & @CRLF)
    EndIf
Next

Func IsVisible($sTitle, $hHandle)
    If BitAND( _WinAPI_GetWindowLong($hHandle, $GWL_EXSTYLE), $WS_EX_TOOLWINDOW) Then Return 0
    
    $iState = WinGetState($hHandle)
    If BitAND($iState, 2) = 2 And _ ; Visible
    BitAND($iState, 16) <> 16  Then ; Not minimized
        Return 1
    Else
        Return 0
    EndIf
EndFunc   ;==>IsVisibl

Edited February 3, 2015 by jguinch

[akorx]

Oh nice work jguinch    ! Congratulations !

Thank you very much for your help !

Thank you to the others to for theirs answers too.

And finally thank for "Je suis Charlie" panel, I'm french...