$GUI_EVENT_DROP not working

[TheDcoder 814]

Hello, I am using this GUI to test drag & drops:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiButton.au3>

Global $hGUI = GUICreate("ParentX",500,500,-1,-1,-1,-1)
Global $hInput = GUICtrlCreateLabel("",0,0,507,507,-1,16)
GUICtrlSetState(-1,88)
GUICtrlSetBkColor(-1,"-2")

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

        Case $GUI_EVENT_DROPPED
            MsgBox(64, "Drag & Drop", '@GUI_DragFile = ' & @GUI_DragFile & @CRLF & '@GUI_DragId = ' & @GUI_DragId & @CRLF & '@GUI_DropId = ' & @GUI_DropId)

    EndSwitch
WEnd

But the MsgBox is not working

Thanks in advance, TD

[Melba23 3,049]

TheDcoder,

Look through the extended GUI styles and see if anything jumps out at you.

M23

[TheDcoder 814]

@Melba23 Ummm... No, nothing jumps at me

[Melba23 3,049]

TheDcoder,

Strange - this is the first extended style in the list:

$WS_EX_ACCEPTFILES: - Allow an edit or input control within the created GUI window to receive filenames via drag and drop. The control must have also the $GUI_DROPACCEPTED state set by GUICtrlSetState().

That certainly sounds to me like something you need to add to your script.

M23

 

[TheDcoder 814]

I already did that @Melba23. I use ISN AutoIt Studio BTW

[Melba23 3,049]

TheDcoder,

I do not - so I have no idea how that affects things.  But this version of your script works fine for me:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

Global $hGUI = GUICreate("ParentX", 500, 500, Default, Default, Default, $WS_EX_ACCEPTFILES)
Global $hInput = GUICtrlCreateInput("", 0, 0, 507, 507)
GUICtrlSetState($hInput, $GUI_DROPACCEPTED)

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_DROPPED
            MsgBox($MB_SYSTEMMODAL, "Drag & Drop", '@GUI_DragFile = ' & @GUI_DragFile & @CRLF & _
                                                   '@GUI_DragId = ' & @GUI_DragId & @CRLF & _
                                                   '@GUI_DropId = ' & @GUI_DropId)
    EndSwitch
WEnd

Note that you need an edit/input control on the GUI to use this method of getting the dropped files. If you do not have or want one of those controls then you will have to go a different route.

M23

P.S. And I see you using a lot of magic numbers in your original script - not a good habit to get into.

[TheDcoder 814]

Thanks @Melba23

[water 2,067]

What do we learn from this thread?
CAREFULLY read the help file Almost always the needed information is already there