Read XML Values

[lrstndm]

I was searching the forum too find a way to read XML files. There are many options (also very old options), but my question is which is the best for now and which is the best for my problem?

I have a XML file like this:

<Data>
    <Values>
        <Info>Information value 1</Info>
        <Info>Information value 2</Info>
    </Values>
    <Other>Other information</Other>
</Data>

What I want to have is a function where you can basically call the function 'getValue' or 'getValues' with the path to the value(s)

e.g.

getValue('Data\Other')

or

getValues('Data\Values\Info')

What is the best solution for me? Hope someone can help me out.

Regards,
lrstndm

[MikahS]

Have a look at these links in this link: Link

That should give you an idea of how to start.

[jdelaney]

Example:

;~ Create the temp xml
#include <File.au3>

_FileCreate("Temp")
FileWrite("Temp","<Data><Values><Info>Information value 1</Info><Info>Information value 2</Info></Values><Other>Other information</Other></Data>")


Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load("Temp")

$oOther = $oXML.SelectSingleNode("//Data/Other")            ; or //Other
ConsoleWrite("$oOther.text=[" & $oOther.text & "]" & @CRLF)

$oInfos = $oXML.SelectNodes("//Data/Values/Info")   ; or //Info or //Data//Info or //Values/Info
For $oInfo In $oInfos

    ConsoleWrite("$oInfo.text=[" & $oInfo.text  & "]" & @CRLF)
Next

outputs:

$oOther.text=[Other information]
$oInfo.text=[Information value 1]
$oInfo.text=[Information value 2]

[lrstndm]

jdelaney, Thank you!

This is the thing I was been looking for. With this I can work on.

[KF5WGB]

jdelaney and all coders,,

Long time since this threat started. However, it has just what I needed with one exception.
The first post had only a simple "multiple node" and my xml file has more stuff in the nodes tags. If you run the script and check the created solar.xml you see what I mean.

What it does:
It downloads solardata, writes it to a xml file and then picks a few  infos out of that xml file and displays it in a MsgBox. HAM radio operators use those infos. 

My problem is at the end where a "multiple node" needs to be read and put into strings e.g $band1day, $band2day...... band$4night.

Code:

expandcollapse popup

;Display Solar data in popup
;coded by: KF5WGB
;
;Get the Solar data from the net
        Global $oXML = ObjCreate("Microsoft.XMLHTTP")
        $oXML.Open("GET", "http://www.hamqsl.com/solarxml.php", 0)
        $oXML.Send
        $oReceived = $oXML.ResponseText
        $oStatusCode = $oXML.Status
;and save it as solar.xml
        If $oStatusCode == 200 then
            $file = FileOpen("solar.xml", 2) ; The value of 2 overwrites the file if it already exists
            FileWrite($file, $oReceived)
            FileClose($file)
        EndIf

Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load("solar.xml")

$updated = $oXML.SelectSingleNode("solar/solardata/updated")            ; updated
ConsoleWrite("$updated.text=" & $updated.text & "" & @CRLF)
$sunspots = $oXML.SelectSingleNode("solar/solardata/sunspots")          ; sunspots
ConsoleWrite("$sunspots.text=[" & $sunspots.text & "]" & @CRLF)
$xray = $oXML.SelectSingleNode("solar/solardata/xray")                  ; xray
ConsoleWrite("$xray.text=[" & $xray.text & "]" & @CRLF)
$solarflux = $oXML.SelectSingleNode("solar/solardata/solarflux")        ; solarflux
ConsoleWrite("$solarflux.text=[" & $solarflux.text & "]" & @CRLF)
$aindex = $oXML.SelectSingleNode("solar/solardata/aindex")              ; aindex
ConsoleWrite("$aindex.text=[" & $aindex.text & "]" & @CRLF)
$kindex = $oXML.SelectSingleNode("solar/solardata/kindex")              ; kindex
ConsoleWrite("$kindex.text=[" & $kindex.text & "]" & @CRLF)
$solarwind = $oXML.SelectSingleNode("solar/solardata/solarwind")        ; solarindex
ConsoleWrite("$solarwind.text=[" & $solarwind.text & "]" & @CRLF)

$oInfos = $oXML.SelectNodes("solar/solardata/calculatedconditions/band"); ..and here is the problem
For $oInfo In $oInfos
        ;Local $band[????] = $oInfo.text                                ; array ?? how to read it??
        ConsoleWrite("$oInfo.text=[" & $oInfo.text & "]" & @CRLF)
Next

MsgBox(64,"Solardata @ " & $updated.text,"Sunspots: " & $sunspots.text & @CRLF & "Xray: " & $xray.text & @CRLF & "Solarflux:    " & $solarflux.text & @CRLF & "A:   " & $aindex.text & @CRLF & "K:  " & $kindex.text & @CRLF & "Solarwind:  " & $solarwind.text & @CRLF & @CRLF & $oInfo.text & @CRLF & @CRLF & @CRLF & "       written by:KF5WGB")

As you can see, after running the script, consolewrite shows each value. The Msgbox ($oInfo.text) shows the last value of the "multiple nodes". How would put each value in a string?

Thanks in advance

KF5WGB

 

 

[mikell]

You might try this

$oInfos = $oXML.SelectNodes("solar/solardata/calculatedconditions/band"); ..and here is the problem

$test = ""
For $oInfo In $oInfos
    ;$oAttrs = $oInfo.attributes
    ;$test &= $oAttrs(0).value &" ("& $oAttrs(1).value & "): " & $oInfo.text & @crlf
    $test &= $oInfo.getattribute("name") &" ("& $oInfo.getattribute("time") & "): " & $oInfo.text & @crlf
Next
msgbox(0,"test", $test)

 

Edited December 27, 2017 by mikell
still learning xml :)

[KF5WGB]

mikell,

Awesome. I was happy with the first one but the second one is even better.
Thank you so much. Working the string is easy for me. I started to read the XML tutorial @ w3school.com and I must say.... I have some serious reading to do.

Thanks again

KF5WGB

[van_renier]

This is a great thread.

This might be a dumb/easy question to answer, but how might I be able to read in an XML file, and get the names of the elements? like in the 1st example given.

<Data>
    <Values>
        <Info>Information value 1</Info>
        <Info>Information value 2</Info>
    </Values>
    <Other>Other information</Other>
</Data>

The script examples above clearly helped me get the values of the elements, (i.e. "Information value 1" and 2,) but How would I be able to get the elements of those?, ie. "Data", "Values", "Info", "Other", etc... This is probably more working with object-related coding than the XML file itself.  For example..

 

$oInfos = $oXML.SelectNodes("SMPUBLISH")   ; or //Info or //Data//Info or //Values/Info
For $oInfo In $oInfos
   ConsoleWrite("$oInfo.text=[" & $oInfo.text  & "]" & @CRLF)
 Next

$oInfo.text will retrieve the value within the elements, how would I get the value of the elements themselves?

=================
<SMPUBLISH>
    <SERVER>
        <SHORT_NAME>smpolicysrv </SHORT_NAME>
        <FULL_NAME>SiteMinder Policy Server </FULL_NAME>
        <PRODUCT_NAME>SiteMinder(tm) </PRODUCT_NAME>
        <VERSION>12.52 </VERSION>
    </SERVER>
</SMPUBLISH>
=================
In the above excerpt of an XML file, the elements within a node might change, The scripts earlier allow me/us to get the values of these nodes, but what about getting the name of the nodes too?

Thanks,

Van

 

[mikell]

Do you mean this ?

Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load("Temp")

Local $txt = ""
$oItem = $oXML.SelectSingleNode("SMPUBLISH/SERVER") 

For $oNode In $oItem.childNodes
   $txt &= $oNode.nodename & " = " & $oNode.text & @crlf
Next
Msgbox(0,"", $txt)

 

[KF5WGB]

Hi coders,

Long time, no mess up.  I think I am loosing it. Looking at a little routine for hours and do not see the problem.

I have a huge Settings.xml file and all I need is two node values out of it. The XML looks like this:

<?xml version="1.0" encoding="UTF-8"?>
<unneeded stuff>....</unneeded stuff>
<unneeded stuff>....</unneeded stuff>
<unneeded stuff>....</unneeded stuff>
<N3FJPTCPENABLED>True</N3FJPTCPENABLED>
<N3FJPTCPPORT>1180</N3FJPTCPPORT>
<unneeded stuff>....</unneeded stuff>
<unneeded stuff>....</unneeded stuff>

All I need are those two nodes. The complete XML is attached. So far I use this:

GetServerStat()


Func GetServerStat()

    Local $oXML = ObjCreate("Microsoft.XMLDOM")
    
    If FileExists("Settings.xml") then
            $oXML.load("Settings.xml")
    Else
            MsgBox(0,"ERROR", "File not found")
    EndIf

    Local $TCPENABLED = $oXML.SelectSingleNode("N3FJPTCPENABLED") ; Server on or off
    ConsoleWrite("Server: " & $TCPENABLED.text & @CRLF)

    Local $TCPPORT = $oXML.SelectSingleNode("N3FJPTCPPORT") ; TCP Port
    ConsoleWrite("Port: " & $TCPPORT.text & @CRLF)

EndFunc   ;==>GetServerStat

Consolewrite gives me this:
"G:\Coding\AutoIt\findfile\getsettingsxmldata.au3" (16) : ==> The requested action with this object has failed.:
ConsoleWrite("Server: " & $TCPENABLED.text & @CRLF)
ConsoleWrite("Server: " & $TCPENABLED^ ERROR

 

I take a break for a few hours. Pretty sure I miss something simple.
Anyway... as always... Thanks for any help.

Kf5WGB

Settings.xml

[careca]

I would go with _stringbetween

See this post

[jdelaney]

     Local $TCPENABLED = $oXML.SelectSingleNode("//N3FJPTCPENABLED") ; Server on or off     ConsoleWrite("Server: " & $TCPENABLED.text & @CRLF)     Local $TCPPORT = $oXML.SelectSingleNode("//N3FJPTCPPORT")

[KF5WGB]

9 minutes ago, jdelaney said:

     Local $TCPENABLED = $oXML.SelectSingleNode("//N3FJPTCPENABLED") ; Server on or off     ConsoleWrite("Server: " & $TCPENABLED.text & @CRLF)     Local $TCPPORT = $oXML.SelectSingleNode("//N3FJPTCPPORT")

Hi jdelaney,

I had put those // in before. Did not work. That made me scratch my head and wonder.

[KF5WGB]

1 hour ago, careca said:

I would go with _stringbetween

Works great. Did not know about the _StringBetween func.  Much easier than the xml stuff :-)

Thanks.

 

[jdelaney]

It is until you get complex xml and want to easily parse out specific attribute/values.