2 Column Array into a GUI

[hroberts 0]

I have a 2 column array.  Column 1 is the Name of an OU, column 2 is the FQDN.  I want to bring the information from this array into the ComboBox, displaying column 1, but selecting column 2 to be used further in the script.  I believe I have to extract the 2 columns into 2 different arrays but I am not sure how/what to do to get this to work.  Can anyone help me out with getting this to work?

 

Thanks,

[ahmet 10]

This might help you

Global $aData[3][2]
 ; this array contains OU and FQDN
Global $sComboData=""
For $i=0 To 2
 ;just to populate array quickly
    $aData[$i][0]="OU" & $i
    $aData[$i][1]="FQDN" & $i
    $sComboData=$sComboData & $aData[$i][0] & "|"
Next

$hMain=GUICreate("Test")
$idCombo=GUICtrlCreateCombo("",10,10)
GUICtrlSetData($idCombo,$sComboData)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $idCombo
            $sTextSelected=GUICtrlRead($idCombo)
 ;when selection occurs get the text that is displayed
            $iFoundItem=-1
            For $i=0 To UBound($aData,1)-1 ; search for selected text in array of your data
                If $sTextSelected==$aData[$i][0] Then
                    $iFoundItem=$i ; store the index where we found our selection for further use if necessary 
                    ConsoleWrite("OU=" & $sTextSelected & ", FQDN=" & $aData[$i][1] & @CRLF)
                EndIf
            Next
    EndSwitch
WEnd

You could have posted some code

[water 2,500]

Fill the combobox with the elements from column 1. When a user selects an entry you get the displayed text in return. With this text loop through the array and grab the corresponding text from column 2.