Jump to content
satanico64

Problem with _arraytranspose

Recommended Posts

satanico64

hi guys ! nice to see you again !

i've just spend hours on the forum, until it went down... : \

so forum is back and me too, and here's the problem

Problem with array :
i've a 2d array, from which i want to extract 1 row with all it's value , to get a 1d array.

Method:

1 i search my value => got $index in array
2 i _arrayextract 1 row > But it still make a 2d array (1 value by column)
3 i arraytranspose => And it should make 1 d array

but not.... let's have a look with simplified code

Thanks to explain where i am wrong ?

ps: I've just updated latest stable version of autoit because i had bug with extract column zero . it's ok now but my transpose does'nt seems to work anymore...

thanks

nicolas.
Simple code:

#include <Array.au3>

Local $aArray[4][4]
For $i = 0 To 3
    For $j = 0 To 3
        $aArray[$i][$j] = $i & $j
    Next
Next
_ArrayDisplay($aArray, "Original")   ; >Display a 2d array

Local $aExtract = _ArrayExtract($aArray, 0, 0)   ; for me it extract 1 row but still 2d array
_ArrayDisplay($aExtract, "Row 0-0")
ConsoleWrite('dimension:' & UBound($aExtract, $UBOUND_DIMENSIONS ) & @CRLF )  ; It's a 2d array
_ArrayTranspose($aExtract)   ; I thought i should obtain a 1d array with that
_ArrayDisplay($aExtract, "Row 0-0")
ConsoleWrite('dimension:' & UBound($aExtract, $UBOUND_DIMENSIONS ) & @CRLF )  ; It's a 2d array

 

Share this post


Link to post
Share on other sites
water

_ArrayTranspose only swaps rows and columns but it doesn't change the number of dimensions. Seems you have to code it yourself.
But this is no brain surgery.


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (2018-01-27 - Version 1.3.3.1) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites
water

Example:

#include <Array.au3>
Global $aArray2D[3][3] = [[11, 12, 13], [21, 22, 23], [31, 32, 33]]
_ArrayDisplay($aArray2D)
Global $aArray1D[1]
Global $iIndex2D = 1
ReDim $aArray1D[UBound($aArray2D, 2)]
For $i = 0 to UBound($aArray2D, 2) - 1
    $aArray1D[$i] = $aArray2D[$iIndex2D][$i]
Next
_ArrayDisplay($aArray1D)

 


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (2018-01-27 - Version 1.3.3.1) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites
satanico64

hmm i humbly disagree (or i simply don't understand), If you take a 1D array with more than 1 record, and you swap it make a 2d array.

If you swap again it should make a 1D array. (in our case where it has only one row)

 

i take the help file from _ArrayTranspose, it indicate that it transpose array from 1d to 2d, and 2d to 1d

the example provided, i just add consolewrite dimensions and remove first example:

 

#include <Array.au3>

Local $aArray[5] = [1, 2, 3, 4, 5]
ConsoleWrite('Initial 1D dimension :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )
_ArrayDisplay($aArray, "Original 1D")
_ArrayTranspose($aArray)
ConsoleWrite('dimension after transpose of 1D array :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )
_ArrayDisplay($aArray, "Transposed to 2D")
_ArrayTranspose($aArray)
ConsoleWrite('dimension after transpose of 2D array :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )
_ArrayDisplay($aArray, "Re-transposed to 1D")   ;>>>> BUT IT FAILED HERE, still 2D

 

where am i wrong ?

ps: Thanks Water for taking a look, i'm honored, your work helped me a lot, many times.

Share this post


Link to post
Share on other sites
water

As I see it the example is misleading/wrong. The UDF is not able to tell if a 2D array with only a single line should be a 1D array or a 2D array with only one column after transposing.
Will discuss this with the Devs.


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (2018-01-27 - Version 1.3.3.1) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites
satanico64

i've just install old autoit version (3.3.12.0) on other computer, and the same last script transpose from 2d to 1d

 

Nicolas.

Share this post


Link to post
Share on other sites
satanico64

by the way, for my original problem another solution is:

1 find index

2 transpose => still 2D but i 'll extract 1 column and not a row

3 extract one column => 1d array.

 

Edited by satanico64
missed one character

Share this post


Link to post
Share on other sites
water

i've just install old autoit version (3.3.12.0) on other computer, and the same last script transpose from 2d to 1d

Thanks for that info.
Already passed to the Devs.


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (2018-01-27 - Version 1.3.3.1) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites
water

Melba23 has already created this modification. There is a new parameter to specify if you want to get a 1D or 2D array in this special case.
Could you please check and post your findings?

#include <Array.au3>

Local $aArray[5] = [1, 2, 3, 4, 5]
_ArrayDisplay($aArray, "Original 1D")
_ArrayTranspose_Mod($aArray)
_ArrayDisplay($aArray, "Transposed to 2D")
_ArrayTranspose_Mod($aArray)
_ArrayDisplay($aArray, "Re-transposed as 2D")
_ArrayTranspose_Mod($aArray)
_ArrayDisplay($aArray, "Still 2D")
_ArrayTranspose_Mod($aArray, True) ; Force 1D return
_ArrayDisplay($aArray, "Re-transposed to 1D")

Func _ArrayTranspose_Mod(ByRef $aArray, $bForce1D = False)
    Switch UBound($aArray, 0)
        Case 0
            Return SetError(2, 0, 0)
        Case 1
            Local $aTemp[1][UBound($aArray)]
            For $i = 0 To UBound($aArray) - 1
                $aTemp[0][$i] = $aArray[$i]
            Next
            $aArray = $aTemp
        Case 2
            Local $iDim_1 = UBound($aArray, 1), $iDim_2 = UBound($aArray, 2)
            If $iDim_1 <> $iDim_2 Then
                If $iDim_1 = 1 And $bForce1D Then ; If only 1 row and 1D return forced
                    Local $aTemp[$iDim_2]
                    For $i = 0 To $iDim_2 - 1
                        $aTemp[$i] = $aArray[0][$i]
                    Next
                Else ; Stay as 2D
                    Local $aTemp[$iDim_2][$iDim_1]
                    For $i = 0 To $iDim_1 - 1
                        For $j = 0 To $iDim_2 - 1
                            $aTemp[$j][$i] = $aArray[$i][$j]
                        Next
                    Next
                EndIf
                $aArray = $aTemp
            Else ; optimimal method for a square grid
                Local $vElement
                For $i = 0 To $iDim_1 - 1
                    For $j = $i + 1 To $iDim_2 - 1
                        $vElement = $aArray[$i][$j]
                        $aArray[$i][$j] = $aArray[$j][$i]
                        $aArray[$j][$i] = $vElement
                    Next
                Next
            EndIf
        Case Else
            Return SetError(1, 0, 0)
    EndSwitch
    Return 1
EndFunc   ;==>_ArrayTranspose

 


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (2018-01-27 - Version 1.3.3.1) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites
satanico64

It works like a charm.

Thanks all of you.

And I wish you a happy new year from Bordeaux, France.

Nicolas.

my test code:

#include <Array.au3>

Local $aArray[5] = [1, 2, 3, 4, 5]
_ArrayDisplay($aArray, "Original 1D")
ConsoleWrite('Initial 1D dimension :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )

_ArrayTranspose_Mod($aArray)
ConsoleWrite('Dimension Transposed to 2D :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )
_ArrayDisplay($aArray, "Transposed to 2D")

_ArrayTranspose_Mod($aArray)   ; still 2D, but expected.
ConsoleWrite('re transpose to initial without force, dimension :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )
_ArrayDisplay($aArray, "Re-transposed as initial without force ")

_ArrayTranspose_Mod($aArray)
ConsoleWrite('re Transposed to 2D :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF ) ;obvsiouly 2D
_ArrayDisplay($aArray, "Transposed to 2D again")

_ArrayTranspose_Mod($aArray, True) ; Force 1D return  => Now 1D. Hoped. Obtained. Impressed.
ConsoleWrite('Transposed to 1d with force :' & UBound($aArray, $UBOUND_DIMENSIONS ) & @CRLF )
_ArrayDisplay($aArray, "Transposed to initial")


Func _ArrayTranspose_Mod(ByRef $aArray, $bForce1D = False)
    Switch UBound($aArray, 0)
        Case 0
            Return SetError(2, 0, 0)
        Case 1
            Local $aTemp[1][UBound($aArray)]
            For $i = 0 To UBound($aArray) - 1
                $aTemp[0][$i] = $aArray[$i]
            Next
            $aArray = $aTemp
        Case 2
            Local $iDim_1 = UBound($aArray, 1), $iDim_2 = UBound($aArray, 2)
            If $iDim_1 <> $iDim_2 Then
                If $iDim_1 = 1 And $bForce1D Then ; If only 1 row and 1D return forced
                    Local $aTemp[$iDim_2]
                    For $i = 0 To $iDim_2 - 1
                        $aTemp[$i] = $aArray[0][$i]
                    Next
                Else ; Stay as 2D
                    Local $aTemp[$iDim_2][$iDim_1]
                    For $i = 0 To $iDim_1 - 1
                        For $j = 0 To $iDim_2 - 1
                            $aTemp[$j][$i] = $aArray[$i][$j]
                        Next
                    Next
                EndIf
                $aArray = $aTemp
            Else ; optimimal method for a square grid
                Local $vElement
                For $i = 0 To $iDim_1 - 1
                    For $j = $i + 1 To $iDim_2 - 1
                        $vElement = $aArray[$i][$j]
                        $aArray[$i][$j] = $aArray[$j][$i]
                        $aArray[$j][$i] = $vElement
                    Next
                Next
            EndIf
        Case Else
            Return SetError(1, 0, 0)
    EndSwitch
    Return 1
EndFunc   ;==>_ArrayTranspose

 

Share this post


Link to post
Share on other sites
water

Thanks for testing.
I'm glad this little modification solved your problem.
Will tell Melba about the result so he might include it in the Array UDF.

Happy new year from Lake Constance!
 


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (2018-01-27 - Version 1.3.3.1) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • HardXOR
      By HardXOR
      Hello AutoIt community
      I run into speed problem in my script wich i cant solve myself, problem is with decoding texture loop - for better explanation, you need extract from file pallete (16x 16 RGB color) and picture data (224 * 128 byte), then use correct color for your picture data.... nothing extra hard and also texture is quite small 224*256
      it is for my car model viewer/later maybe editor GranTurismo 2 from Playstation 1, so its old dataformat and i cant understand why AutoIt take so long to decode texture when good old Playstation almost 2,5 decades old can do that nearly immediately (when you list through cars in shop or garage)
      My first atempt was create all trought dllstructure, because its easier approach, but it was soooo slow (40-50s for create textures) then i upgrade my routine via arrays, first 3D arrays later only 1D, next i put decoding colors outside loop but it is still not enough, my last version took cca 15s wich is still unacceptable for car model viewer when you click on one carmodel from listview (1100 cars for whole game) and you must wait 15-16s for model to load....  oh and i forgot mention some cars have more then 1 color (much more... 8-9-10 etc) soloading take 8-9-10 times more time
      in attachment i post texture file from GranTurismo 2 for one car (contain only 1 color) and also my dll struct version and array version code
      dll struct version - ± 40 sec (33 without saving)
      #include <FileConstants.au3> Global $IMDT[256][256][4] LoadTexture("ufs9r.cdp") Func LoadTexture($file) $fileHandle = FileOpen($file, $FO_BINARY) $header = FileRead($fileHandle, 0x20) ConsoleWrite("header> " & $header & @CRLF) $PAL = FileRead($fileHandle, 0x200) ConsoleWrite("PAL> " & $PAL & @CRLF) FileSetPos($fileHandle, 0x43A0, $FILE_BEGIN) $IMD = FileRead($fileHandle, 0x7000) ConsoleWrite("IMD> " & $IMD & @CRLF) $st = DllStructCreate("BYTE[512]") DllStructSetData($st, 1, $PAL) $struct_PAL = DllStructCreate("WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16];WORD[16]", DllStructGetPtr($st)) $struct_IMD = DllStructCreate("BYTE[" & 0x7000 & "]") DllStructSetData($struct_IMD, 1, $IMD) $start = TimerInit() For $i = 0 To 15 For $j = 0 To 223 $cn = 0 For $k = 0 To 127 $bt = DllStructGetData($struct_IMD, 1, $j * 128 + $k + 1) $blue = BitShift(DllStructGetData($struct_PAL, $i + 1, BitAND($bt, 0x0F) + 1), 7) $IMDT[$j][$cn][0] = $blue $green = BitShift(DllStructGetData($struct_PAL, $i + 1, BitAND($bt, 0x0F) + 1), 2) $IMDT[$j][$cn][1] = $green $red = BitShift(DllStructGetData($struct_PAL, $i + 1, BitAND($bt, 0x0F) + 1), - 3) $IMDT[$j][$cn][2] = $red If DllStructGetData($struct_PAL, $i + 1, BitAND($bt, 0x0F) + 1) = 0 Then $IMDT[$j][$cn][3] = 0x00 Else $IMDT[$j][$cn][3] = 0xFF EndIf $cn += 1 $blue = BitShift(DllStructGetData($struct_PAL, $i + 1, BitShift($bt, 4) + 1), 7) $IMDT[$j][$cn][0] = $blue $green = BitShift(DllStructGetData($struct_PAL, $i + 1, BitShift($bt, 4) + 1), 2) $IMDT[$j][$cn][1] = $green $red = BitAND(BitShift(DllStructGetData($struct_PAL, $i + 1, BitShift($bt, 4) + 1), - 3), 0xFF) $IMDT[$j][$cn][2] = $red If DllStructGetData($struct_PAL, $i + 1, BitShift($bt, 4) + 1) = 0 Then $IMDT[$j][$cn][3] = 0x00 Else $IMDT[$j][$cn][3] = 0xFF EndIf $cn += 1 Next Next saveTGA($i) Next ConsoleWrite("t " & TimerDiff($start) & @CRLF) ; +- 40 seconds FileClose($fileHandle) EndFunc Func saveTGA($name) Local $tga[18] = [0x00, 0x00, 0x02, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x01, 0x00, 0x01, 0x20, 0x20] Local $data for $i = 0 To 17 $data &= Hex($tga[$i], 2) Next For $i = 0 To 255 For $j = 0 To 255 For $k = 0 To 3 $data &= hex($IMDT[$i][$j][$k], 2) Next Next Next $binary = FileOpen("test\" & $name & ".tga", BitOR($FO_BINARY, $FO_OVERWRITE, $FO_CREATEPATH)) FileWrite($binary, "0x" & $data) FileClose($binary) EndFunc  
      array version - ± 15 sec (under 10s without saving)
      #include <FileConstants.au3> LoadTexture2("ufs9r.cdp") Func LoadTexture2($file) $fileHandle = FileOpen($file, $FO_BINARY) $a = TimerInit() Global $header[0x20] For $i = 0 To UBound($header) - 1 $header[$i] = Int(String(FileRead($fileHandle, 1))) ; read 0x20 bytes Next ConsoleWrite("header " & TimerDiff($a) & @CRLF) $a = TimerInit() Global $PAL[0x100] For $i = 0 To UBound($PAL) - 1 $PAL[$i] = Number(FileRead($fileHandle, 2)) ; read 0x200 (16*16) words Next Global $PALcolor[16 * 16 * 4] For $i = 0 To UBound($PAL) - 1 $PALcolor[$i * 4 + 0] = BitShift($PAL[$i], 7) $PALcolor[$i * 4 + 1] = BitShift($PAL[$i], 2) $PALcolor[$i * 4 + 2] = BitShift($PAL[$i], -3) If $PAL[$i] = 0 Then $PALcolor[$i * 4 + 3] = 0x00 Else $PALcolor[$i * 4 + 3] = 0xFF EndIf Next ConsoleWrite("PAL " & TimerDiff($a) & @CRLF) $a = TimerInit() FileSetPos($fileHandle, 0x43A0, $FILE_BEGIN) Global $IMD[0x7000] For $i = 0 To UBound($IMD) - 1 $IMD[$i] = Int(String(FileRead($fileHandle, 1))) ; read 0x7000 bytes Next ConsoleWrite("IMD " & TimerDiff($a) & @CRLF) Global $IMDT[256*256*4] $a = TimerInit() For $i = 0 To 15 For $j = 0 To 223 $cn = 0 For $k = 0 To 127 $byte = $IMD[$j * 128 + $k] ; byte for decode $index = $j * 1024 + $cn * 4 $index2 = $i * 0x40 + BitAND($byte, 0x0F) * 4 $IMDT[$index + 0] = $PALcolor[$index2 + 0] ; blue $IMDT[$index + 1] = $PALcolor[$index2 + 1] ; green $IMDT[$index + 2] = $PALcolor[$index2 + 2] ; red $IMDT[$index + 3] = $PALcolor[$index2 + 3] ; alpha $cn += 1 $index = $j * 1024 + $cn * 4 $index2 = $i * 0x40 + BitShift($byte, 4) * 4 $IMDT[$index + 0] = $PALcolor[$index2 + 0] ; blue $IMDT[$index + 1] = $PALcolor[$index2 + 1] ; green $IMDT[$index + 2] = $PALcolor[$index2 + 2] ; red $IMDT[$index + 3] = $PALcolor[$index2 + 3] ; alpha $cn += 1 Next Next ;~ $b = TimerInit() saveTGA2($i) ;~ ConsoleWrite("save TGA " & TimerDiff($b) & @CRLF) Next ConsoleWrite("full time " & TimerDiff($a) & @CRLF) ; 16 seconds FileClose($fileHandle) EndFunc Func saveTGA2($name) Local $tga[18] = [0x00, 0x00, 0x02, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x01, 0x00, 0x01, 0x20, 0x20] Local $data For $i = 0 To 17 $data &= Hex($tga[$i], 2) Next For $i = 0 To UBound($IMDT) - 1 $data &= Hex($IMDT[$i], 2) Next $binary = FileOpen("test\" & $name & ".tga", BitOR($FO_BINARY, $FO_OVERWRITE, $FO_CREATEPATH)) FileWrite($binary, "0x" & $data) FileClose($binary) EndFunc if anyone can optimize my code I would be very grateful, or pointing me to better solution, thx
      ufs9r.cdp
    • FMS
      By FMS
      Hello,
      Does somebody knows a quick way to split eash word to an array in a text?
      I've a text and want to have each word in that text in an array.

      I tried to get in some way multiple seperators inside stringsplit but couldn't get it to work.
      I hope to get an array like :
      $aArray[0] = "PARIJS"
      $aArray[1] = "AFN"
      $aArray[2] = "Air"
      ....
      sample text: PARIJS (AFN) - Air France-KLM heeft de financieel directeur van het Franse nuts- en vervoersbedrijf Veolia, Philipe Capron, in het vizier om de nieuwe topman van de luchtvaartcombinatie te worden. Volgens de krant La Tribune wordt Capron als favoriet beschouwd om de topfunctie te gaan vervullen. AdChoices Advertentie Volgens bronnen tegen La Tribune is de keuze voor Capron zelfs al gemaakt door Air France-KLM en zal zijn voordracht volgende week worden voorgelegd aan de raad van toezicht bij het bedrijf. Capron zou dan de opvolger worden van de opgestapte topman Jean-Marc Janaillac. In mei trad Janaillac af nadat het hem niet was gelukt buiten de bonden om zaken te doen met het eigen personeel. Sindsdien heeft een interim-bestuur de dagelijkse leiding. De zestigjarige Capron is sinds 2014 financieel directeur bij Veolia. Daarvoor werkte hij onder meer bij mediaconcern Vivendi. Minder macht Overigens zijn er ook geruchten dat de nieuwe topman van Air France-KLM direct een zetel zou krijgen in de raad van commissarissen van KLM. Binnen de Nederlandse divisie, die juist alles op alles zet om minder macht naar Parijs te laten vloeien, is men volgens ingewijden verbolgen over die gang van zaken. ,,Stank voor dank", zo klinkt het in de wandelgangen. Eerder zou Janaillac ook al hebben geprobeerd om een dikkere vinger in de pap te krijgen bij KLM, dat door de bank genomen beter presteert dan haar Franse zustermaatschappij. Dit lukte eerder niet, onder meer door inmenging van het Nederlandse kabinet. AdChoices Advertentie Geruchten Een woordvoerder van Air France-KLM wilde niet reageren op de geruchtenstroom. Het concern gaat er vanuit dat binnen afzienbare tijd een nieuwe bestuursvoorzitter benoemd zal worden. Minister Cora van Nieuwenhuizen (Infrastructuur) wilde evenmin ingaan op geruchten. ,,Ik heb hierover nog geen contact gehad met KLM, dus dat wil ik eerst even afwachten'', zei ze. Tweede Kamerleden spraken deze week tijdens een debat nog maar eens hun zorg uit over de ontwikkelingen bij Air France-KLM. Zij drongen aan op herbevestiging van oude afspraken over de relatief zelfstandige positie van KLM binnen de groep.>Exit code: 0 Time: 28.52  
    • VollachR
      By VollachR
      Hi,
      I'm looking for a way to take a number value from a Row2 of a 2D array and according to this check if files that appear in rows 3-11 in the array exists.
      For example, if the number in Row2 is 5 I need to check for the files in Row 3-6 only, if it is 6 than rows 3-7 and so on.
      I thought on using a FOR loop but I have very little experience with those.
      Can you suggest the best way to do what I need?
      BTW, the files in Rows 3-11 will usually have blank value for any row above the number in Row2 (e.g. Row2 = 5 so Rows3-6 will have values but 8-11 be empty), The values I need are in Column 1 of the array, the name of the key from the INI file that the array was created from is in Column 0.
      Full Example:
      Row2 of Array:
      Col0 = Games# - Col1 = 5
      Rows3-6
      Col0 = Exe2 - Col1 = Path To File
      Col0 = Exe3 - Col1 = Path To File
      Col0 = Exe4 - Col1 = Path To File
      Col0 = Exe5 - Col1 = Path To File
      I need that if Row2 is 5 to check these above for rows if the file exists, if it was 6 then the next row as well and so on up until number 10 in Row2 as it can't go above 10.
      So basically for whatever number in Row2 from 2-10 need to check 1-9 rows from 3-11 to see if the files in Col1 exists and if any of them don't exist it should call a function that shows an error message.
      I'm pretty sure I have the first line of the for look correct:
      For $i = 1 To $aAIO[2][1] Just not sure how to continue from there, also not sure if $i should be equal 1 or 2.
      Help will be appreciated.
    • FMS
      By FMS
      Hello,
      I'm trying to get data from twitter to an array and so far I found an Twitter UDF whish lookes very intresting but couldn't get it to work.
      It lookes not supported any more(2010) and buggy when i read all te replies.
      More around this subject (autoit and twitter) i couldn't find on this forum.
      Is there sombody who know's a good way to get live data from twitter to an array inside autoit?
      (I kinda doubt that this isn't tackled before)
      In the end I was hoping to get all tweets from date to date from an specific subject inside a 2D array to work whit.
    • AndreasNWWWWW
      By AndreasNWWWWW
      I got a question:  i am trying to run different functions based upon what i select in these radio buttons.(code below)
      it needs to check server 1. then run function 1 or function 2 after what i selected in the checkbox.
      once that function is done it moves to the next one, until it has been trough all 5 
       
      iv'e tried using while loops with different while $i equals to something but then i manualy need to go in and edit the script every time.
      #include <ButtonConstants.au3> #include <GUIConstantsEx.au3> #include <StaticConstants.au3> #include <WindowsConstants.au3> #Region ### START Koda GUI section ### Form= $Form1 = GUICreate("Form1", 615, 437, 192, 124) $Server2 = GUICtrlCreateLabel("Server2", 216, 95, 41, 17) $server1 = GUICtrlCreateLabel("Server1", 216, 72, 41, 17) $server4 = GUICtrlCreateLabel("Server4", 216, 144, 41, 17) $server3 = GUICtrlCreateLabel("Server3", 216, 119, 41, 17) $server5 = GUICtrlCreateLabel("Server5", 216, 170, 41, 17) $Start = GUICtrlCreateButton("Start", 240, 248, 147, 25) $Checkbox1 = GUICtrlCreateCheckbox("function1", 288, 72, 97, 17) $Checkbox2 = GUICtrlCreateCheckbox("function2", 392, 72, 97, 17) $Checkbox3 = GUICtrlCreateCheckbox("function1", 288, 96, 97, 17) $Checkbox4 = GUICtrlCreateCheckbox("function2", 392, 96, 97, 17) $Checkbox5 = GUICtrlCreateCheckbox("function1", 288, 120, 97, 17) $Checkbox6 = GUICtrlCreateCheckbox("function2", 392, 120, 97, 17) $Checkbox7 = GUICtrlCreateCheckbox("function1", 288, 144, 97, 17) $Checkbox8 = GUICtrlCreateCheckbox("function2", 392, 144, 97, 17) $Checkbox9 = GUICtrlCreateCheckbox("function1", 288, 170, 97, 17) $Checkbox10 = GUICtrlCreateCheckbox("function2", 392, 170, 97, 17) GUISetState(@SW_SHOW) #EndRegion ### END Koda GUI section ### While 1 $nMsg = GUIGetMsg() Switch $nMsg Case $GUI_EVENT_CLOSE Exit EndSwitch WEnd  
×