Form with combobox and 3 buttons

[Clanity184]

Hi everyone, I need some help. Is there an example to work on a form with a combo box that lets you select from a specific folder a .txt file for which then has to be manipulated by copying and renaming it? Sorry for my bad English.

Thanks for reading.

Edited November 25, 2016 by Clanity184

[water]

What have you tried so far?

[Clanity184]

Hello water,

i did some tests, but without getting anything..

Here the skeleton code:

 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Importa_Preventivo()

Func Importa_Preventivo()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Importa Preventivi", 440, 540)

    ; Create a button control.
    Local $DaNuovo = GUICtrlCreateButton("Importa preventivo da [Nuovo scontrino]", 20, 330, 395, 35)
    Local $DaTipRig = GUICtrlCreateButton("Importa preventivo da campo [Tipo rigo]", 20, 380, 395, 35)
    Local $Close = GUICtrlCreateButton("Esci", 20, 430, 395, 35)


    Local $idCombo

    ; Create GUI
    $idCombo = GUICtrlCreateCombo("", 20, 20, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))

    GUISetState(@SW_SHOW)

    ; Add files
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, "C:\Users\Pc\Desktop\orig\" & "\*.txt")
    _GUICtrlComboBox_EndUpdate($idCombo)





    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ;Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $Close
                ExitLoop

            Case $DaNuovo

            Case $DaTipRig

            Case $Close



        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

EndFunc   ;==>Importa_Preventivo

 

Edited November 25, 2016 by Clanity184

[water]

Something like this?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiComboBox.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>

Importa_Preventivo()

Func Importa_Preventivo()

    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Importa Preventivi", 440, 540)
    ; Create a button control.
    Local $DaNuovo = GUICtrlCreateButton("Importa preventivo da [Nuovo scontrino]", 20, 330, 395, 35)
    Local $DaTipRig = GUICtrlCreateButton("Importa preventivo da campo [Tipo rigo]", 20, 380, 395, 35)
    Local $Close = GUICtrlCreateButton("Esci", 20, 430, 395, 35)
    Local $idCombo = GUICtrlCreateCombo("", 20, 20, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState(@SW_SHOW)
    ; Add files
    Local $aFiles = _FileListToArray("C:\temp\", "*.txt") ; <== Modify
    Local $sFiles = _ArrayToString($aFiles, Default, 1)
    GUICtrlSetData($idCombo, $sfiles)
    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    ;Local $iPID = 0
    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $Close
                ExitLoop
            Case $DaNuovo
            Case $DaTipRig
            Case $Close
        EndSwitch
    WEnd
    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

EndFunc   ;==>Importa_Preventivo

 

[Clanity184]

Something wrong..

 

[water]

In my example the line I marked as "; <== Modify" should read:

Local $aFiles = _FileListToArray("C:\users\PC\desktop\orig\", "*.txt") ; <== Modify

Note: You had a "&" where there should be a ",".

[Clanity184]

You're right, thanks!!

[water]

[Clanity184]

Sorry water, i'm a beginner. Something don't turn the right way..

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiComboBox.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>

Importa_Preventivo()

Func Importa_Preventivo()

    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Importa Preventivi", 440, 540)
    ; Create a button control.
    Local $DaNuovo = GUICtrlCreateButton("Importa preventivo da [Nuovo scontrino]", 20, 330, 395, 35)
    Local $DaTipRig = GUICtrlCreateButton("Importa preventivo da campo [Tipo rigo]", 20, 380, 395, 35)
    Local $Close = GUICtrlCreateButton("Esci", 20, 430, 395, 35)
    Local $idCombo = GUICtrlCreateCombo("", 20, 20, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState(@SW_SHOW)
    ; Add files
    Local $aFiles = _FileListToArray("C:\Users\Pc\Desktop\orig\", "*.txt") ; <== Modify
    Local $sFiles = _ArrayToString($aFiles, Default, 1)
    GUICtrlSetData($idCombo, $sfiles)
    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    MsgBox($MB_SYSTEMMODAL, "", $idCombo & "  */|\*  " & $sfiles)

    ;Local $iPID = 0
    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $Close
                ExitLoop
            Case $DaNuovo

                Local $aFiles = _FileListToArray("C:\Users\Pc\Desktop\orig\", "*.txt") ; <== Modify
                Local $sFiles = _ArrayToString($aFiles, Default, 1)
                MsgBox($MB_SYSTEMMODAL, "", $idCombo & "/|\" & $sfiles)


            Case $DaTipRig
            Case $Close
        EndSwitch
    WEnd
    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

EndFunc   ;==>Importa_Preventivo

What i need is a variable that contains the full path of the file (only one at a time)  that I chose from the combobox.

 

Edited November 26, 2016 by Clanity184

[water]

As the path is fixed it is easy to display the full path. I added the marked block of code to display the full path for the selected file:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiComboBox.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>

Importa_Preventivo()

Func Importa_Preventivo()

    Local $sPath = "C:\temp\", $sFilter = "*.txt" ; <== Modify
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Importa Preventivi", 440, 540)
    ; Create a button control.
    Local $DaNuovo = GUICtrlCreateButton("Importa preventivo da [Nuovo scontrino]", 20, 330, 395, 35)
    Local $DaTipRig = GUICtrlCreateButton("Importa preventivo da campo [Tipo rigo]", 20, 380, 395, 35)
    Local $Close = GUICtrlCreateButton("Esci", 20, 430, 395, 35)
    Local $idCombo = GUICtrlCreateCombo("", 20, 20, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState(@SW_SHOW)
    ; Add files
    Local $aFiles = _FileListToArray($sPath, $sFilter)
    Local $sFiles = _ArrayToString($aFiles, Default, 1)
    GUICtrlSetData($idCombo, $sFiles)
    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    ;Local $iPID = 0
    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $Close
                ExitLoop
            Case $DaNuovo
                $aFiles = _FileListToArray($sPath, $sFilter)
                $sFiles = _ArrayToString($aFiles, Default, 1)
            Case $DaTipRig
            Case $Close
                ; Following selection has been added
            Case $idCombo
                $sComboRead = GUICtrlRead($idCombo)
                MsgBox($MB_ICONINFORMATION, "Selection", "Selected file: " & $sPath & $sComboRead)
        EndSwitch
    WEnd
    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

EndFunc   ;==>Importa_Preventivo

 

[Clanity184]

Now is working.. you're big.. 

[water]