PeteF

WinGetPos Incorrectly Returning Sizes

5 posts in this topic

#1 ·  Posted (edited)

Full script w/details in comments below, just in case you need to run it to see the problem.  Basically WinGetPos is incorrectly returning the W & H sizes, while at the same time correctly returning the positions. To compound the problem, I ran the same script on 2 different PCs and it gets2 different results as follows:

Win7 Pro PC.. GUICreate used to set W:300, H:100.       WinGetPos returns W:307, H:127  (PC screen res: 1366x768)

WinXP PC..... GUICreate used to set W:300, H:100.       WinGetPos returns W:308, H:134   (PC screen res: 1152x864)

The bigger problem occurs when you consider I want to save the Window sizes and recreate the window at a later date. but due to this problem, each time I ran the program the Window would get larger and larger.    --pete

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; SCRIPT DESC.: Simple script here. Create & display one Window of a specific
; size & position. This Window is always ON TOP of other windows.
; User may resize the window to cover up unwanted content (as in use with a Web-Browser).
; Upon user closing the Window, DEBUG msgbox in script returns window size & position
; to be used in further development of this script.
;
; PROBLEM: If user does not resize the Window and simply clicks "X" to close the window,
; the DEBUG msgbox is reporting the wrong SIZES. It's actually the AutoIt WinGetPos
; function that is returning correct positions, but incorrectly returning the sizes.
; It should be returning 300 (W), 100 (H), but it's incorrectly  returning 307 (W), 127 (H)
;
_MAIN()

Func _MAIN()

    ;Local $sFilePath = "..\GUI\logo4___.gif"
    Local $l_SizeWidth_1, $l_SizeHeight_1, $l_PosLeft_1, $l_PosTop_1

    ; Defaults for Window 1  Size and Position
    $l_SizeWidth_1 = 300
    $l_SizeHeight_1 = 100
    $l_PosLeft_1 = 50
    $l_PosTop_1 = 50


    ; Create re-sizable GUI window/form that is blank with a black background and stays on TOP over over windows.
    Local $hGUI = GUICreate("COVER UNWANTED CONTENT", $l_SizeWidth_1, $l_SizeHeight_1, $l_PosLeft_1, $l_PosTop_1, _
            $WS_OVERLAPPEDWINDOW, $WS_EX_TOPMOST)

    ; Black Background
    GUISetBkColor(0x000000)

    ;GUICtrlCreatePic("..\GUI\msoobe.jpg", 0, 0, 400, 100)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)


    ; Create a picture control with a transparent image.
    ;GUICtrlCreatePic($sFilePath, 0, 0, 169, 68)

    ; Display the Window
    GUISetState(@SW_SHOW)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()

            ; CASE IF USER X's out, CLOSE THE WINDOWS & QUIT
            Case $GUI_EVENT_CLOSE
                ExitLoop

                ; CASE Open a second window


        EndSwitch
    WEnd

    ; Obtain the window(s) Size & Positions
    _WindowPositionAndSize($hGUI)


    ; Save the window(s) size & positions
    ; TBD


    ; Delete the previous GUIs and all controls.
    GUIDelete($hGUI)


EndFunc   ;==>_MAIN


Func _WindowPositionAndSize($WindowID)

    ; Retrieve the position as well as height and width of the window.
    Local $aPos = WinGetPos($WindowID)

    ; DEBUG msgbox
    ; Display the array values returned by WinGetPos.
    MsgBox(0, "", "X-Pos: " & $aPos[0] & @CRLF & _
            "Y-Pos: " & $aPos[1] & @CRLF & _
            "Width: " & $aPos[2]  & @CRLF & _
            "Height: " & $aPos[3] )

            ; DEBUG notes
            ; Width 300 off by a factor of.. 0.9740261
            ; Height 100 off by a factor of.. 0.7874017
            ; I was hoping to add in some correction factors, but thse factors
            ; change dramatically at different Width & Height settings. Need a better fix!

EndFunc   ;==>_WindowPositioAndSize

 

 

Edited by PeteF

Share this post


Link to post
Share on other sites



I confirm, i get 306x129.


Spoiler

Paster - Main function is to paste text, but has more functions.

OpenW - Open With... alternative, Open any file with any application, set it's icon, set application as default.

Renamer - Rename files and folders, remove portions of text from the filename etc.

BeatsPlayer - Music player.

Params Tool - Right click an exe to see it's parameters or execute them.

Regedit Control - Registry browsing history, quickly jump into any saved key.

Time4Shutdown - Write the time for shutdown in minutes.

Power Profiles Tool - Set a profile as active, delete, duplicate, export and import.

Firefox Profile Backup - Backup/restore previously saved profile.

Finished Task Shutdown - Shuts down pc when specified window/Wndl/process closes.

NetworkSpeedShutdown - Shuts down pc if download speed goes under "X" Kb/s.

IUIAutomation - Topic with framework and examples

Share this post


Link to post
Share on other sites

From AutoIt help file>GUICreate function>Remarks:- "The size specified is the size of the client area of the window. The border and title bar will make the window slightly larger than specified. Using menu controls will also change the windows height."

WinGetPos() returns the outside dimensions of a window.
WinGetClientSize() will return the window's client area, as specified in the GUICreate() function.

2 people like this

Share this post


Link to post
Share on other sites

Ok Malkey, that's it!  Thank you!  So, I need to get the POSITIONS using WinGetPos () and the SIZES using WinGetClientSize (). I read the part you quoted from the Help file, but I didn't quite understand what it meant. Your explanation cleared up the confusion.

In the spirit of helping others, below is the full script all fixed up, and I took it one step further to return the POS & SIZE values back to the _MAIN function where the msgbox displays the results.   Very cool, Thanks again! 

One last thing. I'm just a few weeks into using AutoIt and something puzzles me about Functions related to Return Values of the array type.

HELP for WinGetClientSize states..

Return Value

  a 2-element array containing the following information:
    $aArray[0] = Width of window's client area
    $aArray[1] = Height of window's client area

 

My function  _WindowPositionAndSize  utilizes 2 AutoIt functions (WinGetPos  and WinGetClientSize).  So how does AutoIT know to assign the $aArray[0]  to the array variables I specify in my function?  This is especially puzzling when you consider that WinGetPos has a 4 element array and WinGetClientSize has a 2 element array and I used 2 separate arrays in my function and AutoIt assigned the values perfectly.  Amazing, but I don't quite understand how it works or what the rules are.

Can you explain how it works, or is this array thing explained in more detail anywhere in the HELP system?

--pete--

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; SCRIPT DESC.: Simple script here. Create & display & 1 Window of a specific
; size & position. This Window is always ON TOP of other windows.
; User may resize the window to cover up unwanted content (as in use with a Web-Browser).
; Upon user closing the Window, DEBUG msgbox in script returns window size & position
; to be used in further development of this script.
;
;
_MAIN()

Func _MAIN()

    ;Local $sFilePath = "..\GUI\logo4___.gif"
    Local $l_SizeWidth_1, $l_SizeHeight_1, $l_PosLeft_1, $l_PosTop_1 ;Set values
    Local $l_SizeWidth, $l_SizeHeight, $l_PosLeft, $l_PosTop ;Returned values

    ; Defaults for Window 1  Size and Position
    $l_SizeWidth_1 = 300
    $l_SizeHeight_1 = 100
    $l_PosLeft_1 = 50
    $l_PosTop_1 = 50


    ; Create re-sizable GUI window/form that is blank with a black background and stays on TOP over over windows.
    Local $hGUI = GUICreate("COVER UNWANTED CONTENT", $l_SizeWidth_1, $l_SizeHeight_1, $l_PosLeft_1, $l_PosTop_1, _
            $WS_OVERLAPPEDWINDOW, $WS_EX_TOPMOST)

    ; Black Background
    GUISetBkColor(0x000000)

    ;GUICtrlCreatePic("..\GUI\msoobe.jpg", 0, 0, 400, 100)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)


    ; Create a picture control with a transparent image.
    ;GUICtrlCreatePic($sFilePath, 0, 0, 169, 68)

    ; Display the Window
    GUISetState(@SW_SHOW)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()

            ; CASE IF USER X's out, CLOSE THE WINDOWS & QUIT
            Case $GUI_EVENT_CLOSE
                ExitLoop

                ; CASE Open a second window


        EndSwitch
    WEnd

    ; Obtain the window(s) Size & Positions
    _WindowPositionAndSize($hGUI, $l_SizeWidth, $l_SizeHeight, $l_PosLeft, $l_PosTop)

    ;Debug
    MsgBox(0, "", "Pos-Left: " & $l_PosLeft & @CRLF & _
            "Pos-Top: " & $l_PosTop & @CRLF & _
            "Width: " & $l_SizeWidth & @CRLF & _
            "Height: " & $l_SizeHeight)


    ; Save the window(s) size & positions
    ; TBD


    ; Delete the previous GUIs and all controls.
    GUIDelete($hGUI)


EndFunc   ;==>_MAIN



Func _WindowPositionAndSize($WindowID, ByRef $SizeWidth, ByRef $SizeHeight, ByRef $PosLeft, ByRef $PosTop)

    ; Retrieve the positions
    Local $aPos = WinGetPos($WindowID)

    ; Retrieve the sizes
    Local $aSize = WinGetClientSize($WindowID)

    $PosLeft = $aPos[0]
    $PosTop = $aPos[1]
    $SizeWidth = $aSize[0]
    $SizeHeight = $aSize[1]

EndFunc   ;==>_WindowPositionAndSize
Quote

 

 

Share this post


Link to post
Share on other sites

#5 ·  Posted (edited)

Just as the author/s of the functions WinGetPos and WinGetClientSize  had these functions return arrays, so to your _WindowPositionAndSize function can be rewritten to return an array.

Func _WindowPositionAndSize($WindowID)

    ; Retrieve the positions
    Local $aPos = WinGetPos($WindowID)

    ; Retrieve the sizes
    Local $aSize = WinGetClientSize($WindowID)

    Local $aRetArray[4] ; One array returned can have 4 values.  Global variables not required.

    $aRetArray[0] = $aPos[0]
    $aRetArray[1] = $aPos[1]
    $aRetArray[2] = $aSize[0]
    $aRetArray[3] = $aSize[1]

    Return $aRetArray
EndFunc   ;==>_WindowPositionAndSize

 

Edited by Malkey
Grammar correction
1 person likes this

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now

  • Similar Content

    • davidacrozier
      By davidacrozier
      I am attempting to drag and drop a file from one windows explorer window to another windows explorer window (henceforth referred to as window1 and window2).  I am not using the web.  I have used autowinexp.au3 (taken from LarsJ's automatewindowsexplorer.au3) to give focus (function GetFileFocus)  to a file on window1.   The problem is that sometimes the file with the focus is not displayed on window1 because it is farther down the list than what is displayed in window1.  There are other ways to accomplish this (like copy and paste) but I want to emulate the GUI doing a drag and drop.  I work as a digital forensicator and my task is to examine what artifacts are left behind on move/copy vs a drag and drop.  Please note that when I open window1 and window2 they are on top of each other, so I drag window2 over about 1150 pixels and that part works great.    
      My code is listed below.  Please understand that I have tried several different methods to accomplish this task.  The last one was to estimate that the top of the window1 header is approximately 320 pixels and to multiply the index of the file by 20 pixels since that appears to be the approximate height of individual files using the AutoIT Windows Info tool.  Ideally the program would search window1 for the file name text and provide a mouse position for it.  Or the program would allow me to scroll to where the file name is located.  Any and all ideas are welcome.
      Using Windows 10
      AutoIT v3.3.14.2
      Thanks!
      DavidaCrozier
      PS Any problems in autowinexp.au3 are mine and not the author of automatewindowsexplorer.au3.  
       
      DragAndDropForum.au3
      autowinexp.au3
    • Reizvoller
      By Reizvoller
      Func workSpaceSetup () ConsoleWrite ("workSpaceSetup" &@CRLF) $workSpace = WinGetHandle ("some site - Google Chrome") ConsoleWrite ($workSpace&@CRLF) $pos1 = WinGetPos ($workSpace) WinMove ($workSpace , "", $pos1[0] , $pos1[1] , 1366, 768, 0) EndFunc So the script is first, the error I get is second in the quote.
      This is one function of many for an app I am building but it is the first one that runs so I know there aren't other things at play here.
      The idea is to keep the window in the same space it is when the script runs but just resize it as this app is used across multiple computers with different screen resolutions.
      Could someone please elaborate upon what "Subscript used on non-accessible variable" means? 
      Oh and the variable is declared as "Global $pos1 = 0" at the top outside of any functions with the other global variables.
      Any advice would be greatly appreciated!
      -Reiz
    • nitekram
      By nitekram
      I am trying to do something, but it appears that I am having issues with trying to get the right functions called, in the right order.
      What I want to do is move a window to a certain position and then move it back, but as stated, the order appears to be an issue, as if the window is minimized, the wingetclientsize is not able to pull the info, not is the wingetpos. It appears to be able to get the size and position of the window in question is activated, but I have to activate it first, but that defeats the purpose, as once activated, the functions called to get the position and size, are not correct, as the screen is now active. I have tried to use wingetstate, to get the state first, but I am not sure how to move the window back to the original location with the right state.
      If window is minimized, I want it to go back to minimized state, as well as keeping the window size the same, so if the user activates the window, the user does not have to resize it.
      If the window is active and is on another screen, it appears I do not have the same issue.
      Here is my attempt, but I have tried other combinations. Has anyone got an idea on how to resolve this issue?
      Func MoveVNC($Move) CreateLogEntry("Called MoveVNC($Move) $Move = " & $Move) Local $aStartBar = StartBar() Local $bMove = False Local $VNC = 'NAMEOFWINDOW' Static $aWin_VNC_Pos = '' Static $iWin_VNC_State = '' Static $aWin_VNC_Size = '' #cs ;$aWin_VNC_Pos = WinGetPos($VNC, '') MsgBox('','VNC POS','') _ArrayDisplay(WinGetPos($VNC, '')) MsgBox('','VNC STATE',WinGetState($VNC, '')) WinActivate($VNC) Sleep(20) WinWaitActive($VNC, '', 10) Sleep(20) Local $aSize = WinGetClientSize($VNC, '') MsgBox('','VNC SIZE','') _ArrayDisplay($aSize) #ce If $Move = 'Get' Then Opt("WinTitleMatchMode", -1) ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase If WinExists($VNC) Then WinActivate($VNC) Sleep(20) WinWaitActive($VNC, '', 10) Sleep(20) $aWin_VNC_Pos = WinGetPos($VNC, '') Sleep(20) ;_ArrayDisplay($aWin_VNC_Pos, '$aWin_VNC_Pos') $iWin_VNC_State = WinGetState($VNC, '') Sleep(20) $aWin_VNC_Size = WinGetClientSize($VNC, '') ;_ArrayDisplay($aWin_VNC_Size) ;MsgBox('','$VNC',$VNC) ;MsgBox('', '$iWin_VNC_State', $iWin_VNC_State) ;WinSetState($VNC, '', @SW_MAXIMIZE) ;Sleep(20) WinMove($VNC, '', 0, 0, 1600, 950) ; - (3 * $aStartBar[3]) Sleep(20) ;MouseClick('Left', 1764, 174) $bMove = True Else MsgBox($MB_TOPMOST, 'ERROR GET', 'Window ' & $VNC & ' Does not exists - VNC is not running!') EndIf If Not $bMove Then CreateLogEntry("MoveVNC(GET) FAILED") Return False Else CreateLogEntry("MoveVNC(GET) PASSED") Return True EndIf ElseIf $Move = 'Put' Then CreateLogEntry("Called MoveVNC($Move) $Move = " & $Move) If WinExists($VNC) Then ;WinSetState($VNC, '', @SW_RESTORE) ;If @error Then MsgBox('', '', @error) ;Sleep(20) WinMove($VNC, '', $aWin_VNC_Pos[0], $aWin_VNC_Pos[1], $aWin_VNC_Pos[2], $aWin_VNC_Pos[3]) If @error Then MsgBox('', '', @error) Sleep(20) ;WinSetState($VNC, '', $iWin_VNC_State) ;If @error Then MsgBox('', 'Not setting state', @error & ' ' & $VNC) ;Sleep(20) $bMove = True Else MsgBox($MB_TOPMOST, 'ERROR PUT', 'Window ' & $VNC & ' Does not exists - VNC is not running!') EndIf If Not $bMove Then CreateLogEntry("MoveVNC(PUT) FAILED") Return False Else CreateLogEntry("MoveVNC(PUT) PASSED") Return True EndIf EndIf CreateLogEntry(" Returned from MoveVNC()") EndFunc ;==>MoveVNC  
    • momar33
      By momar33
      I am seeing a buttons position change when the following happens.
      1. GUI created at 800 x 600
      2. GUI info is stored using WinGetPos
      3. GUI changed to full-screen using WinMove
      4. Button info is stored using ControlGetPos
      5. Button is deleted
      6. Button is re-created using the stored data from item 4.
      7. GUI is restored to the info gathered in item 2.
      The button starts with this info:
      Button Left:   408 Button Top:    84 Button Width:  80 Button Height: 24   and after the events above the button has this info: Button Left:   409 Button Top:    83 Button Width:  80 Button Height: 24   Here is some code that can reproduce the issue: (press space, f, space, f, then look in the console) #Region Includes #include <WindowsConstants.au3> #include <StaticConstants.au3> #include <GUIConstantsEx.au3> #include <Array.au3> #EndRegion Includes Const $HT_KEY_FULLSCREEN = "f" Const $HT_KEY_SPACE = "{SPACE}" Global $btnAddRebuy[21] Global $btnRemovePlayer[21] Global $fFullscreen = False Global $aGuiInfo Global $aGuiInfo2 Global $guiWidth = 800 Global $guiHeight = 600 #Region Dimensions for Settings Screen ; Player Global $lblPlayerTop = 60 Global $playerLabelSpace = 24 ; Add Rebuy Button Global $btnRebuyLeft = 320 Global $btnRebuyWidth = 80 Global $btnRebuyHeight = 24 ; Remove Player Global $btnRemoveLeft = 408 Global $btnRemoveWidth = 80 Global $btnRemoveHeight = 24 #EndRegion Dimensions for Settings Screen $hMain = GUICreate("Timer", $guiWidth, $guiHeight, -1, -1, BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX,$WS_SIZEBOX,$WS_THICKFRAME,$WS_SYSMENU,$WS_CAPTION,$WS_OVERLAPPEDWINDOW,$WS_TILEDWINDOW,$WS_POPUP,$WS_POPUPWINDOW,$WS_GROUP,$WS_TABSTOP,$WS_BORDER,$WS_CLIPSIBLINGS)) For $i = 1 To 5 Step 1 $btnAddRebuy[$i] = GUICtrlCreateButton("Button", $btnRebuyLeft, $lblPlayerTop + ($playerLabelSpace * $i), $btnRebuyWidth, $btnRebuyHeight) GUICtrlSetResizing($btnAddRebuy[$i], $GUI_DOCKAUTO) GuiCtrlSetState($btnAddRebuy[$i], $GUI_DISABLE) $btnRemovePlayer[$i] = GUICtrlCreateButton("Button", $btnRemoveLeft, $lblPlayerTop + ($playerLabelSpace * $i), $btnRemoveWidth, $btnRemoveHeight) ;GUICtrlSetResizing($btnRemovePlayer[$i], $GUI_DOCKAUTO) Next GUISetState(@SW_SHOW) HotKeySet($HT_KEY_FULLSCREEN, "Fullscreen") HotKeySet($HT_KEY_SPACE, "Redraw") While 1 $msg = GUIGetMsg() If $msg = $GUI_EVENT_CLOSE Then ExitLoop EndIf WEnd Func Fullscreen() If WinActive($hMain) Then If $fFullscreen Then ;GUISetStyle(BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX,$WS_SIZEBOX,$WS_THICKFRAME,$WS_SYSMENU,$WS_CAPTION,$WS_OVERLAPPEDWINDOW,$WS_TILEDWINDOW,$WS_POPUP,$WS_POPUPWINDOW,$WS_GROUP,$WS_TABSTOP,$WS_BORDER,$WS_CLIPSIBLINGS), Default, $hMain) $aGuiInfo2 = WinGetPos($hMain) ConsoleWrite("******* Fullscreen *******" & @LF) ConsoleWrite("Win Left: " & $aGuiInfo2[0] & @LF) ConsoleWrite("Win Top: " & $aGuiInfo2[1] & @LF) ConsoleWrite("Win Width: " & $aGuiInfo2[2] & @LF) ConsoleWrite("Win Height: " & $aGuiInfo2[3] & @LF & @LF) ;WinMove($hMain, Default, $aGuiInfo[0], $aGuiInfo[1], $aGuiInfo[2], $aGuiInfo[3]) WinMove($hMain, Default, 238, 179, 816, 638) $fFullscreen = False $aCtrlInfo = ControlGetPos($hMain, "", $btnRemovePlayer[1]) ConsoleWrite("******* Button Info after Restored *******" & @LF) ConsoleWrite("Button Left: " & $aCtrlInfo[0] & @LF) ConsoleWrite("Button Top: " & $aCtrlInfo[1] & @LF) ConsoleWrite("Button Width: " & $aCtrlInfo[2] & @LF) ConsoleWrite("Button Height: " & $aCtrlInfo[3] & @LF & @LF) Else ;GUISetStyle($WS_POPUP, Default, $hMain) $aGuiInfo = WinGetPos($hMain) ConsoleWrite("******* Start Size *******" & @LF) ConsoleWrite("Win Left: " & $aGuiInfo[0] & @LF) ConsoleWrite("Win Top: " & $aGuiInfo[1] & @LF) ConsoleWrite("Win Width: " & $aGuiInfo[2] & @LF) ConsoleWrite("Win Height: " & $aGuiInfo[3] & @LF & @LF) WinMove($hMain, Default, 0, 0, @DesktopWidth, @DesktopHeight) $fFullscreen = True $aCtrlInfo = ControlGetPos($hMain, "", $btnRemovePlayer[1]) ConsoleWrite("******* Button Info after Fullscreened *******" & @LF) ConsoleWrite("Button Left: " & $aCtrlInfo[0] & @LF) ConsoleWrite("Button Top: " & $aCtrlInfo[1] & @LF) ConsoleWrite("Button Width: " & $aCtrlInfo[2] & @LF) ConsoleWrite("Button Height: " & $aCtrlInfo[3] & @LF & @LF) EndIf Else HotKeySet($HT_KEY_FULLSCREEN) Send($HT_KEY_FULLSCREEN) HotKeySet($HT_KEY_FULLSCREEN, "Fullscreen") EndIf EndFunc Func Redraw() Local $aCtrlInfo $aCtrlInfo = ControlGetPos($hMain, "", $btnRemovePlayer[1]) ConsoleWrite("******* Button Info before Redraw *******" & @LF) ConsoleWrite("Button Left: " & $aCtrlInfo[0] & @LF) ConsoleWrite("Button Top: " & $aCtrlInfo[1] & @LF) ConsoleWrite("Button Width: " & $aCtrlInfo[2] & @LF) ConsoleWrite("Button Height: " & $aCtrlInfo[3] & @LF & @LF) GuiCtrlDelete($btnRemovePlayer[1]) $btnRemovePlayer[1] = GUICtrlCreateButton("Button", $aCtrlInfo[0], $aCtrlInfo[1], $aCtrlInfo[2], $aCtrlInfo[3]) ;GUICtrlSetResizing(-1, $GUI_DOCKAUTO) $aCtrlInfo = ControlGetPos($hMain, "", $btnRemovePlayer[1]) ConsoleWrite("******* Button Info after Redraw *******" & @LF) ConsoleWrite("Button Left: " & $aCtrlInfo[0] & @LF) ConsoleWrite("Button Top: " & $aCtrlInfo[1] & @LF) ConsoleWrite("Button Width: " & $aCtrlInfo[2] & @LF) ConsoleWrite("Button Height: " & $aCtrlInfo[3] & @LF & @LF) EndFunc Is there a way to fix this, or is the issue built in to how windows get resized?  
    • MarkRobbins
      By MarkRobbins
      I'm using WindowBlinds, VOX 2 Style. When I WinMove() the width and height show quite a bit short when measured on screen (14px!), WinGetPos() returns the proper numbers, but when attempting placement of windows this is quite a pain. Is there a solution for this other than constant compensation?