If double click Tree Item, opens a program. How to do that?

[bballjoe12]

#include <GUIConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("I'm Too Lazy to Type", 317, 205, 266, 137, -1, BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE))
$MenuItem1 = GUICtrlCreateMenu("File")
$MenuItem3 = GUICtrlCreateMenuItem("Exit", $MenuItem1)
$MenuItem2 = GUICtrlCreateMenu("Options")
$MenuItem4 = GUICtrlCreateMenuItem("Always on Top", $MenuItem2)
GUICtrlSetState(-1, $GUI_CHECKED)
GUISetBkColor(0xC8C8C8)
$TreeView1 = GUICtrlCreateTreeView(10, 12, 297, 161, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER))
$TreeView1_0 = GUICtrlCreateTreeViewItem("CHI", $TreeView1)
$TreeView1_1 = GUICtrlCreateTreeViewItem("Hardware", $TreeView1_0)
$TreeView1_2 = GUICtrlCreateTreeViewItem("Broken desktop/WOW", $TreeView1_1)
$TreeView1_3 = GUICtrlCreateTreeViewItem("Citrix", $TreeView1_0)
$TreeView1_4 = GUICtrlCreateTreeViewItem("Launching errors", $TreeView1_3)
$TreeView1_5 = GUICtrlCreateTreeViewItem("Internet/Websites", $TreeView1_0)
$TreeView1_6 = GUICtrlCreateTreeViewItem("Website workflow", $TreeView1_5)
$TreeView1_7 = GUICtrlCreateTreeViewItem("TRUM", $TreeView1)
$TreeView1_8 = GUICtrlCreateTreeViewItem("Hardware", $TreeView1_7)
$TreeView1_9 = GUICtrlCreateTreeViewItem("Internet/Websites", $TreeView1_7)
GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

How would I insert a code where if the "Broken desktop/WOW" item is double clicked, then it will open an external program?  Would I use an "If, Then" statement there?

Edited September 3, 2017 by bballjoe12

[Andreik]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Global $TreeView1

$Form1 = GUICreate("I'm Too Lazy to Type", 317, 205, 266, 137, -1, BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE))
$MenuItem1 = GUICtrlCreateMenu("File")
$MenuItem3 = GUICtrlCreateMenuItem("Exit", $MenuItem1)
$MenuItem2 = GUICtrlCreateMenu("Options")
$MenuItem4 = GUICtrlCreateMenuItem("Always on Top", $MenuItem2)
GUICtrlSetState(-1, $GUI_CHECKED)
GUISetBkColor(0xC8C8C8)
$TreeView1 = GUICtrlCreateTreeView(10, 12, 297, 161, BitOR($GUI_SS_DEFAULT_TREEVIEW,$WS_BORDER))
$TreeView1_0 = GUICtrlCreateTreeViewItem("CHI", $TreeView1)
$TreeView1_1 = GUICtrlCreateTreeViewItem("Hardware", $TreeView1_0)
$TreeView1_2 = GUICtrlCreateTreeViewItem("Broken desktop/WOW", $TreeView1_1)
$TreeView1_3 = GUICtrlCreateTreeViewItem("Citrix", $TreeView1_0)
$TreeView1_4 = GUICtrlCreateTreeViewItem("Launching errors", $TreeView1_3)
$TreeView1_5 = GUICtrlCreateTreeViewItem("Internet/Websites", $TreeView1_0)
$TreeView1_6 = GUICtrlCreateTreeViewItem("Website workflow", $TreeView1_5)
$TreeView1_7 = GUICtrlCreateTreeViewItem("TRUM", $TreeView1)
$TreeView1_8 = GUICtrlCreateTreeViewItem("Hardware", $TreeView1_7)
$TreeView1_9 = GUICtrlCreateTreeViewItem("Internet/Websites", $TreeView1_7)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
 WEnd

 Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
   #forceref $hWnd, $iMsg, $wParam
   Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTreeview
   $hWndTreeview = GUICtrlGetHandle($TreeView1)
   $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
   $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
   $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
   $iCode = DllStructGetData($tNMHDR, "Code")
   Switch $hWndFrom
      Case $hWndTreeview
         Switch $iCode
            Case $NM_DBLCLK
               RunSomeApp()
               Return 0
      EndSwitch
   EndSwitch
   Return $GUI_RUNDEFMSG
EndFunc

Func RunSomeApp()
   Local $CtrlID = GUICtrlRead($TreeView1)
   If _GUICtrlTreeView_GetChildCount($TreeView1,$CtrlID) = -1 Then
      MsgBox(0,'Run app',_GUICtrlTreeView_GetText($TreeView1,$CtrlID))
   EndIf
EndFunc

 

[careca]

This topic is very similar to the other topic you created, thought you got your answers there.