AutoIt ConsoleWrite (using "builtin" Autoit Hidden window)

[boomingranny]

Use this UDF to add a console gui to your script (with log file):
It uses the Hidden Autoit window (that you probably didn't even know existed)
Closing Console window will terminate script.

example of console:

expandcollapse popup

#include-once
#include <GuiEdit.au3>

EnableConsoleGui("example.log")

;example:
;------------------------
ConsoleWrite ("Hello World")
For $i = 1 To 10
    ConsoleWrite (".")
    Sleep(200)
Next
ConsoleWrite ("done")
ConsoleWrite(@CRLF)
ConsoleWrite ("close me to exit"&@CRLF)
While 1
    Sleep(1000)
WEnd

;------------------------
;end of example code

Func EnableConsoleGui($Logfile="")
    ;EnableConsoleGUI
    ;by Daniel Barnes 20/04/2018
    ;Uses AutoIt's Hidden window as a console (output only)

    Global $pidChild

    ;if we don't have a parent (as the parent window would have our script name)
    If Not WinExists(StringTrimRight(@ScriptName,4)) Then

        Opt("TrayIconHide",1)

        ;get Autoit's hidden window handle
        local $hWnd = WinGetHandle(AutoItWinGetTitle())

        ;move the autoit hidden window to the middle of the screen
        WinMove($hWnd, "", (@DesktopWidth / 2) - 250, (@DesktopHeight / 2) - 250, 500, 500)

        ;get the Handle of the edit box in Autoit's hidden window
        $hEditBox = ControlGetHandle($hWnd,"","[CLASS:Edit; INSTANCE:1]")

        ;show it
        WinSetState($hWnd, "", @SW_SHOW)

        ;set its title = our script name
        WinSetTitle($hWnd,"",StringTrimRight(@ScriptName,4))

        ;Spawn a child "copy" of the script, enabling reading of its console...
        If @Compiled Then
            ;2 = $STDOUT_CHILD. This avoids requiring the AutoItConstants.au3 in this sample code
            $pidChild= Run( FileGetShortName(@ScriptFullPath),@ScriptDir,"",2)
        Else
            ;2 = $STDOUT_CHILD. This avoids requiring the AutoItConstants.au3 in this sample code
            $pidChild= Run( FileGetShortName(@AutoItExe) & " " & FileGetShortName(@ScriptFullPath),@ScriptDir,"",2)
        EndIf

        OnAutoItExitRegister("EnableConsoleGui_CloseChildPID")

        ;read the console, while the child window exists (and the console window is visible)
        While ProcessExists($pidChild)
            $ConsoleRead = StdoutRead($pidChild)
            If $ConsoleRead then
                $text = StringLeft(ControlGetText($hWnd,"",$hEditBox),65535)
                If $Logfile Then FileWrite($Logfile,$ConsoleRead)
                $text &= $ConsoleRead
                ControlSetText($hWnd,"",$hEditBox,$text)
                ConsoleWrite($ConsoleRead)
                ;scroll to bottom of console edit window
                _GUICtrlEdit_SetSel($hEditBox, 65535, 65535)
            endif
            Sleep(250)
        WEnd
        exit
    endif
EndFunc

Func EnableConsoleGui_CloseChildPID()
    ;if this func isn't used
    ;when you close the console gui
    ;the child "clone" of your script will keep running
    ProcessClose($pidChild)
EndFunc

Edited April 26, 2018 by boomingranny

[guinness]

Nice idea. I would however rename the internal window first to something unique (like adding the PID) and then get the title.

[Skysnake]

Would you care to provide a use case?

[boomingranny]

On 5/5/2018 at 4:45 AM, Skysnake said:

Would you care to provide a use case?

It is useful if you use ConsoleWrite in your script to debug,
when it is uncompiled you can still use Scite to debug, and when it is compiled (and perhaps on another computer) you can see the ConsoleWrite text on the screen, and later in the log file.

(I know what you might be thinking...you can just compile as a console EXE...that is very true)

The reason I made it was because I read another post about the "AutoIt hidden Window" that, even though I had used AutoIt for years, i had never seen,
Once i saw it I wondered what it was all about and why it had a textbox with no text. So I took it as a challenge...

[boomingranny]

On 4/30/2018 at 11:28 PM, guinness said:

Nice idea. I would however rename the internal window first to something unique (like adding the PID) and then get the title.

Sounds smart!

How do you rename the window before getting its title?
Is there another way to get its handle?

[guinness]

@boomingranny check how I do it in