_ArrayDisplay() and MsgBox() at same time

[pixelsearch]

Hi everyone
I wanted to display a Msgbox (with Retry/Cancel options) while _ArrayDisplay() is being shown.
This allows the user to choose an option, with a complete error message in Msgbox, while he can analyze the results in the _ArrayDisplay() window, scroll into it etc...

To try this, this is a quick script I prepared, unfinished, but you got the idea :

#include <Array.au3>
#include <MsgBoxConstants.au3>

Global $aArray[4] = ["element 0", "element 4", "element 2", "element 3"]

AdlibRegister("MyAdLibFunc", 500) ; each half second (500ms)
_ArrayDisplay($aArray, "Elements")
AdlibUnRegister("MyAdLibFunc")

Func MyAdLibFunc()
    If WinExists("Elements") Then
        AdlibUnRegister("MyAdLibFunc")
        MsgBox(BitOr($MB_TOPMOST, $MB_RETRYCANCEL), "Error in Array", _
            "Element 4 shouldn't be placed in Row 1")
        WinClose("Elements")
    EndIf
EndFunc   ;==>MyAdLibFunc

Is there another easy way you're thinking of, instead of using AdlibRegister ?
(though it shouldn't consume too much CPU load as it's called each half second)
Thanks

Edited January 22, 2019 by pixelsearch

[BrewManNH]

Don't use _ArrayDisplay for this, create your own listview. _ArrayDisplay is a blocking function and should only be used for troubleshooting an array's contents. If you want your script to do other things while displaying the contents of an array without using a workaround, you should build it yourself.

[Nine]

Run(@AutoItExe & ' /AutoIt3ExecuteLine "MsgBox(.....)')
_ArrayDisplay (....)

 

[pixelsearch]

Thanks for your both answers

[LarsJ]

Try this:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#pragma compile(AutoItExecuteAllowed, True)

Opt( "MustDeclareVars", 1 )

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>

Example()

Func Example()
  Local $hGui = GUICreate( "My GUI", 250, 100 )

  GUIRegisterMsg( $WM_USER, "WM_USER" )
  Local $sMbTitle = "Error in Array", $sMbText = "Element 4 shouldn't be placed in Row 1"
  Run( @AutoItExe & ' /AutoIt3ExecuteLine "DllCall(''user32.dll'', ''lresult'', ''SendMessageW'', ''hwnd'', ""' & $hGui & '"", ''uint'', ""' & $WM_USER & '"", ''wparam'', ""' & 0 & '"", ''lparam'', MsgBox( ""' & $MB_TOPMOST+$MB_RETRYCANCEL & '"", ""' & $sMbTitle & '"", ""' & $sMbText & '"" ))"' )

  GUISetState()

  Local $aArray = ["element 0", "element 4", "element 2", "element 3"]
  _ArrayDisplay( $aArray )

  While 1
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE
        ExitLoop
    EndSwitch
  WEnd

  GUIDelete( $hGui )
EndFunc

Func WM_USER( $hWnd, $iMsg, $wParam, $lParam )
  Switch $lParam
    Case $IDCANCEL
      ConsoleWrite( "MsgBox Cancel" & @CRLF )
    Case $IDRETRY
      ConsoleWrite( "MsgBox Retry" & @CRLF )
  EndSwitch
  #forceref $hWnd, $iMsg, $wParam
EndFunc

 

[pixelsearch]

Thanks LarsJ, it works too