Edit part of variable name

[c7aesa7r]

Is it possible to edit part of a variable name?

While 1

    If $name1 = " "
    
    EndIf
    
    If $name2 = " "
    
    EndI

    If $name3 = " "
    
    EndIf
    
    Local newvar = $name(+= 1)
WEnd

I mean adding +1 in the var name instead +1 in var value.

Edited April 1, 2019 by c7aesa7r

[Subz]

Use assign.

[water]

It’s simpler to use arrays in this case.

[c7aesa7r]

Can i have a example please? Im trying change the var name in the end of each loop, name1 became name2 next loop name3 etc.

[Earthshine]

sure, the help file is full of array examples as well as the Assign function

Edited April 1, 2019 by Earthshine

[jchd]

Don't be addict to the name of variables. A name is just a tag you attach to a particular piece of data.

I your case, use an array and vary the index.

[Subz]

As others have mentioned an array would be the better approach as it gives you alot more flexibility, basic example of both using basic array and assign functionality.

expandcollapse popup

;~ Array Example
#include <Array.au3> ;~ Required for _Array functions _ArrayAdd, _ArrayDisplay
Global $aName[3] = ["", 2, "third"] ;~ add data to three array items: $aName[0] = "", $aName[1] = 1 and $aName[2] = "third"
_ArrayDisplay($aName, "Before Changes to $aName array") ;~ You can view the values of your array using _ArrayDisplay
;~ You can check your items using the following, just remember arrays start at 0

If $aName[0] = "" Then ;~ We set the value above to "" above, so this will return true
    MsgBox(4096, "Success", 'Before: $aName[1] = "' & $aName[0] & '"')
    $aName[0] = "First array item"  ;~  ;~ Change the value to "First array item"
    MsgBox(4096, "Success", 'After: $aName[1] = "' & $aName[0] & '"')
EndIf
If $aName[1] = 2 Then ;~ We set the value above to 2 above, so this will return true
    MsgBox(4096, "Success", 'Before: $aName[1] = "' & $aName[1] & '"')
    $aName[1] = "Second array item" ;~  ;~ Change the value to "Second array item"
    MsgBox(4096, "Success", 'After: $aName[1] = "' & $aName[1] & '"')
EndIf
If $aName[2] = "third" Then
    MsgBox(4096, "Success", 'Before: $aName[2] = "' & $aName[2] & '"')
    $aName[2] = "Third array item"  ;~  ;~ Change the value to "Third array item"
    MsgBox(4096, "Success", 'After: $aName[2] = "' & $aName[2] & '"')
EndIf

;~ To add additional items you can use ReDim or use the _ArrayAdd to add any additional items to the array
If UBound($aName) = 3 Then ;~ Check if we've reached the end of the array
    _ArrayAdd($aName, "Forth array item")
EndIf
_ArrayDisplay($aName, "After Changes to $aName array")

;~ You can also loop through the array items using For/Next
For $i = 0 To UBound($aName) - 1
    MsgBox(4096, 'Array Item: "' & $i, "$aName[" & $i & '] = "' & $aName[$i] & '"')
    $aName[$i] = StringUpper($aName[$i]) ;~ Change all the values to uppercase
Next

_ArrayDisplay($aName, "UpperCase")

;~ Assign Example
For $i = 1 To 4
    Assign("name" & $i, $i)
Next

If IsDeclared("name1") Then MsgBox(4096, "Success: Name1 Variable", "$name1 = " & Eval("name1"))
If IsDeclared("name2") Then MsgBox(4096, "Success: Name2 Variable", "$name2 = " & Eval("name2"))
If IsDeclared("name3") Then MsgBox(4096, "Success: Name3 Variable", "$name3 = " & Eval("name3"))
If IsDeclared("name4") Then MsgBox(4096, "Success: Name4 Variable", "$name4 = " & Eval("name4"))
If IsDeclared("name5") Then
    MsgBox(4096, "Success: Name5 Variable", "$name5 = " & Eval("name5")) ;~ This message shouldn't appear as we didn't assign the variable name5
Else
    Assign("name5", 5)
    MsgBox(16, "Failure: Name5 Variable", "$name5 was not declared: " & @CRLF & "$name5 = " & Eval("name5"))
EndIf