Update my App

[Nunos]

Good day all,

 

I am trying to find out what approach you guys take to update your app say from a file or web server to make sure the latest version is always being used. I looked through the help file and UDF's but I am not seeing anything for this, perhaps I am looking for the wrong terms.

[Marc]

Well, I have a location on one of our servers in the LAN and on every start the local version is compared to the version on the server.

General way of updating the compiled exe is:

1. rename current exe to _old.exe (yes, the exe file is able to rename itself)
2. copy the new exe to the local computer
3. run the new exe

expandcollapse popup

Func Updateholen()
    Local $updatepfad = "\\server\myprogram\" ; Folder to get the Updates
    Local $updatequelle = $updatepfad & "myfile.exe" ; FileName to check for
    Local $tmp1 = ""
    Local $tmp2 = ""

    If FileExists(@ScriptDir & "\myfile_old.exe") Then FileDelete(@ScriptDir & "\myfile_old.exe") ; delete possibly existing old version
    If Not @Compiled Then Return ; only try to update if started as a compiled exe

    If @AutoItX64 = 1 Then $updatequelle = $updatepfad & "myfile_x64.exe"

    If Not Ping("server", 50) Then Return ; if server is not online, update can not be retrieved

    If FileExists($updatequelle) Then
        $tmp1 = FileGetTime($updatequelle, 0, 1)
        $tmp2 = FileGetTime(@AutoItExe, 0, 1)
        If $tmp1 > $tmp2 Then

            ; rename the currently running exe file
            $tmp1 = FileMove(@AutoItExe, @ScriptDir & "\userinfo_alt.exe")
            If $tmp1 <> 1 Then
                MsgBox(16, "Problem", "Could not rename the running exe")
                Exit
            EndIf

            ; copy the new exe file to our PC
            $tmp1 = FileCopy($updatequelle, @AutoItExe)
            If $tmp1 <> 1 Then
                MsgBox(16, "Problem", "Could not copy the update")
                Exit
            EndIf

            ; notify user about the update and display version history
            If FileExists($updatepfad & "history.htm") Then ShellExecute($updatepfad & "history.htm")
            Run(@AutoItExe)
            Exit
        EndIf
    EndIf
EndFunc   ;==>Updateholen

 

Edited May 25, 2019 by Marc
typo

[water]

A good place to start is this thread:

 

[Nunos]

Awesome thank you all I will start working on this and post back.