NewMailEx - (Moved)

[HighlanderSword]

Hello,

When using NewMailEx, it does not appear to capture every new email that comes in on a Outlook Exchange email account.

 

I'm trying to capture any new emails and then process a set of rules against the new emails , and taken action based on specific details of the emails. The Process seems to capture 1 or 2 messages but then misses the next email that appear in inbox right after the others do.

Below is snippet of the code I'm using , any suggestions on what I'm Missing 

 

Global $oOApp = ObjCreate("Outlook.Application")
Global $test = ObjEvent($oOApp, "oOApp_")


Func oOApp_NewMailEx()


Process_Rules() ; Function that parses the emails and takes the appropaite actions 



EndFunc

 

[water]

How fast do the mails come in (1 per minute, 50 per second ...)?
How long does it take to process a mail by function Process_Rules (0.01 seconds, 5 seconds ...)?
Is there a blocking function in process-Rules (like a GUI, MsgBox ...)?

 

[HighlanderSword]

Email come in like 5 per seconds , then nothing for a few minutes , then more email 

takes less than 1 second to process the email 

no gui in Process rules function it just process the emails , no msgbox etc....

[Melba23]

Moved to the appropriate forum, as the AutoIt Example Scripts forum very clearly states:

Quote

Share your cool AutoIt scripts, UDFs and applications with others.

---

Do not post general support questions here, instead use the AutoIt Help and Support forums.

Moderation Team

[JLogan3o13]

1 hour ago, HighlanderSword said:

Email come in like 5 per seconds , then nothing for a few minutes , then more email 

takes less than 1 second to process the email 

no gui in Process rules function it just process the emails , no msgbox etc....

The point I believe @water was trying to subtly make is that you're asking for help fixing a script but don't post enough of said script for us to do that. That function could be doing any number of things that could be changed to improve performance. So we are left to first guess at what you're doing and then try to troubleshoot. It makes it a whole lot easier on everyone if you post either your script or, if it is too long or has sensitive data, a reproducer that demonstrates the issue. Help us help you

 

Edited October 10, 2019 by JLogan3o13

[water]

AFAIR there could be a problem when too many mails arrive while the function is already busy.
Will have to ask Google ...

[water]

Good (but maybe a bit outdated) reading: https://www.add-in-express.com/creating-addins-blog/2011/10/03/outlook-newmail-event/

[water]

I think the solution can be found here:
https://docs.microsoft.com/en-us/office/vba/api/outlook.application.newmailex 
  and
https://docs.microsoft.com/en-us/previous-versions/office/developer/office-2003/aa171304(v=office.11) (Outlook 2003 but better wording, including an example).

Quote

Occurs when one or more new items are received in the Inbox. This event passes a list of entry IDs of all the items received in the Inbox since the last time the event was fired.
The entry IDs are comma-delimited.

 

Edited October 11, 2019 by water

[water]

The script should look similar to this:

#include <OutlookEX.au3>

; *****************************************************************************
; Example Script
; Handle Outlook NewmailEX event when one/multiple new mail(s) arrive(s).
; This script loops until Shift-Alt-E is pressed to exit.
; *****************************************************************************
HotKeySet("+!e", "_Exit") ;Shift-Alt-E to Exit the script
MsgBox(64, "OutlookEX UDF Example Script", "Hotkey to exit the script: 'Shift-Alt-E'!")

Global $oOApp = ObjCreate("Outlook.Application")
Global $test = ObjEvent($oOApp, "oOApp_")

While 1
    Sleep(10)
WEnd

; Outlook 2007 - NewMailEx event - http://msdn.microsoft.com/en-us/library/bb147646%28v=office.12%29.aspx
Func oOApp_NewMailEx($sEntryIDs)

    ConsoleWrite("OutlookEX UDF Example Script - New mail has arrived!" & @CRLF & @CRLF)
    Local $oItem, $aEntryIDs = StringSplit($sEntryIDs, ",", $STR_NOCOUNT)
    For $i = 0 To UBound($aEntryIDs) - 1
        $oItem = $oOApp.Session.GetItemFromID($aEntryIDs[$i], Default)
        ConsoleWrite("From:    " & $oItem.SenderName & @CRLF & _
                "Subject: " & $oItem.Subject & @CRLF)
    Next
EndFunc   ;==>oOApp_NewMailEx

Func _Exit()
    Exit
EndFunc   ;==>_Exit

 

[HighlanderSword]

Thanks, I will apply those changes and see how it goes,

Many Thanks Water for your Help