Getting first 10 characters of each line in a BIG txt file

[ThePoro 2]

Hello,

I have a problem with getting first 10 characters with a big txt file, about 50k lines. I only want 10 characters of each line and save it into another file. I tried to use Stringleft every line and save it into another file but it was really slow to do it. I tried to save it into a variation like $var=$var&stringleft($file,10)&@CRLF. It's faster but still really slow.

Can anybody help me with this

Thank you so much

[FrancescoDiMuro 465]

@ThePoro
Did you try to use the handle of the File with FileReadToArray()?

expandcollapse popup

#include <FileConstants.au3>

Global $strSourceFileName =  @ScriptDir & "\SourceFile.txt", _
       $strDestFileName = @ScriptDir & "\DestFile.txt", _
       $hdlSourceFile, _
       $arrSourceFileContent, _
       $hdlDestFile, _
       $strRandomString = "", _
       $hdlTimer

$hdlTimer = TimerInit()

$hdlSourceFile = FileOpen($strSourceFileName, $FO_OVERWRITE)

For $i = 1 To 50000 Step 1

    For $j = 1 To 30 Step 1
        $strRandomString &= Chr(Random(65, 90, 1))
    Next

    FileWriteLine($hdlSourceFile, $strRandomString)
    $strRandomString = ""
Next

FileClose($hdlSourceFile)

ConsoleWrite("It tooks " & Round(TimerDiff($hdlTimer)/1000, 2) & " seconds to generate the test file." & @CRLF)

$hdlTimer = TimerInit()

$hdlSourceFile = FileOpen($strSourceFileName, $FO_READ)
$hdlDestFile = FileOpen($strDestFileName, $FO_OVERWRITE)

;~ $arrSourceFileContent = FileReadToArray($hdlSourceFile)

;~ For $i = 0 To UBound($arrSourceFileContent) - 1 Step 1
;~  FileWriteLine($hdlDestFile, StringLeft($arrSourceFileContent[$i], 10))
;~ Next

FileWrite($hdlDestFile, StringRegExpReplace(FileRead($hdlSourceFile), '(?m)^.{10}\K.*', ''))

FileClose($hdlDestFile)
FileClose($hdlSourceFile)

ConsoleWrite("It tooks " & Round(TimerDiff($hdlTimer)/1000, 2) & " seconds to read 10 characters from each line of the source file." & @CRLF)

EDIT: with the @jchd suggestion, it is even faster!

Edited October 20, 2019 by FrancescoDiMuro

[jchd 1,823]

FileDelete("output.txt")
FileWrite("output.txt", StringRegExpReplace(FileRead("input.txt"), "(?m)^.{10}\K.*", ""))

 

[spudw2k 276]

Why not forego the RegEx and just use the count parameter in the FileRead function?

FileDelete("output.txt")
$iCharacterCount = 10
FileWrite("output.txt", FileRead("input.txt", $iCharacterCount))

 

[Bilgus 169]

Quote

Why not forego the RegEx and just use the count parameter in the FileRead function?

how would you be sure you read a line 10 characters long and not 10 lines 1 chr long?

Edited October 21, 2019 by Bilgus

[ThePoro 2]

Thank you guys very much, faster a million times 👍

[jchd 1,823]

10 hours ago, spudw2k said:

Why not forego the RegEx and just use the count parameter in the FileRead function?

Because the OP doesn't want the first 10 characters of the file, but

17 hours ago, ThePoro said:

I only want 10 characters of each line

 

[spudw2k 276]

ah, sorry.  misread.  Thank you for correcting me.

Edited October 22, 2019 by spudw2k