iniread with accents (non English strings) - (Moved)

[Graeme]

I have a script that uses GUIs and iniread to create labels in given languages, French, German and Korean for example.

I have just realised that after the update to 3.3.16.0 the script no longer reads non English strings correctly.

This GUI

used to show as as Mettre à jour and Masquer la fênetre.

Is there a way of correcting this with an option or something?

[Graeme]

I tried running a program compiled before I updated to 3.3.16.0 and that read the inifile correctly with the accents. However I went back to 3.3.14.2 which is the version I was using and restarted my computer and it still shows as above.

[Melba23]

Moved to the appropriate AutoIt General Help and Support forum, as the Developer General Discussion forum very clearly states:

Quote

General development and scripting discussions.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Moderation Team

[ioa747]

try when you put this lines in your SciTEUser.properties

code.page=65001
output.code.page=65001
NewFileEncoding=UTF8
utf8.auto.check=4

and restart SciTE

Edited April 3, 2023 by ioa747

[Nine]

As per help file in IniWrite :

Quote

If you want to use an ini file with Unicode encoding, first create an .ini file by using the FileOpen() function with the mode parameter set to a Unicode parameter.

 

[SOLVE-SMART]

Hi @Graeme,

I assume (I understood) you already have one or more ini files that don't show for example german "umlauts" correct in the GUI. In this case you can simple rewrite the ini file to "UTF-16 LE" which will display the correct umlauts in the GUI.

Try these test data:

[SectionOne]
KeyOne = Default text
KeyTwo = German umlaut ÄäÜüÖöß

Create a ini file (ini-read-test.ini) and save this example content (as UTF-8 which should be the default encoding for SciTE or VSCode). Then run the following script:

expandcollapse popup

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_Run_Au3Stripper=y
#AutoIt3Wrapper_UseUpx=n
#Au3Stripper_Parameters=/sf /sv /mo /rm /rsln

_Actions()

Func _Actions()
    Local Const $sIniFile = @ScriptDir & '\ini-read-test.ini'

    ;~ _RewriteIniFileToUtf16LittleEndian($sIniFile) ; You just have to use that ini rewrite one time, that's it.

    Local Const $sValueOne = IniRead($sIniFile, 'SectionOne', 'KeyOne', '')
    Local Const $sValueTwo = IniRead($sIniFile, 'SectionOne', 'KeyTwo', '')
    Local Const $hGui      = _CreateGui($sValueOne, $sValueTwo)

    _GuiEventListener()
    _DisposeAndExit($hGui)
EndFunc

Func _RewriteIniFileToUtf16LittleEndian($sFile)
    Local Const $iReadWithUtf8NoBom          = 256
    Local Const $iWriteWithUtf16LittleEndian = 32 + 2

    Local $hFile = FileOpen($sFile, $iReadWithUtf8NoBom)
    Local Const $sFileContent = FileRead($hFile)
    FileClose($hFile)

    $hFile = FileOpen($sFile, $iWriteWithUtf16LittleEndian)
    FileWrite($hFile, $sFileContent)
    FileClose($hFile)
EndFunc

Func _CreateGui($sLabelTextOne, $sLabelTextTwo)
    Local Const $hGui = GUICreate('ini-read-test')

    GUICtrlCreateLabel($sLabelTextOne, 15, 15)
    GUICtrlCreateLabel($sLabelTextTwo, 15, 50)
    GUISetState(@SW_SHOW, $hGui)

    Return $hGui
EndFunc

Func _GuiEventListener()
    Local Const $iGuiCloseEventFlag = -3

    While True
        Switch GUIGetMsg()
            Case $iGuiCloseEventFlag
                ExitLoop
        EndSwitch
    WEnd
EndFunc

Func _DisposeAndExit($hGui)
    GUIDelete($hGui)
    Exit
EndFunc

💡 First run should display the incorrect version of the german umlauts. Please activate line 12 _RewriteIniFileToUtf16LittleEndian() and run again. Now your ini is rewritten an the GUI displays the correct characters.

✨ Conclusion: Open your ini file(s) and rewrite them as "UTF-16 LE" (_RewriteIniFileToUtf16LittleEndian($sIniFile)) one time and you can use your script/program like before (I hope 🤞😀).

Best regards
Sven

Edited April 3, 2023 by SOLVE-SMART