Using ControlSetText to Input Data into a Website – Not Working? - (Moved)

[mustilem23]

I'm trying to use ControlSetText in AutoIt to input text into the "Name" and "Fuzzy Name" fields on this web page:
👉 https://www.trade.gov/data-visualization/csl-search

However, it doesn't seem to work. I suspect it's because the page uses modern web technologies (JavaScript-based elements), and maybe ControlSetText can't interact with them properly.

I tried inspecting the elements and using their IDs, but I'm still stuck. I'm very new to this, so I'd really appreciate any help or guidance. Here's the code I'm working with:

<input type="text" class="explorer__form__input" id="name" name="name" value="">

<input type="text" class="explorer__form__input" id="name" name="name" value="">

#include <AutoItConstants.au3>
; Open the browser and navigate to the URL
Run("C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe https://www.trade.gov/data-visualization/csl-search")
WinWaitActive("CSL Search") ; Wait for the window title

Sleep(5000)

; Try to set the text in the "Name" field
ControlSetText("CSL Search", "CSL Search - International Trade Administration", "name", "Kromlüks")

Sleep(500)

 

Edited Tuesday at 11:58 AM by mustilem23

[Nine]

You would need to use WebDriver :

 

 

[ioa747]

The above method is the correct one
However, there is also the beginner's method.
 

;~ Opt("SendKeyDelay", 100) ; Slow motion

; Open the browser and navigate to the URL
Run("C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe https://www.trade.gov/data-visualization/csl-search")

Local $hWnd = WinWaitActive("CSL Search", "", 5) ; Wait Max 5 sec for the window title

If $hWnd Then
    Send("{TAB 19}") ; go to the name field
    Send("Kromlüks") ; set the name

    Send("{TAB 5}") ; go to the search button
    Send("{ENTER}") ; execute the search
Else
    ConsoleWrite("I can't find the 'CSL Search' window." & @CRLF)
EndIf

 

[Melba23]

Moved to the appropriate AutoIt General Help and Support forum, as the Developer General Discussion forum very clearly states:

Quote

General development and scripting discussions.

---

Do not create AutoIt-related topics here, use the AutoIt General Help and Support or AutoIt Technical Discussion forums.

Moderation Team

[mustilem23]

On 4/22/2025 at 3:57 PM, ioa747 said:

Yukarıdaki yöntem doğru olanıdır
Ancak, başlangıç yöntemi de vardır.
 

;~ Opt("SendKeyDelay", 100) ; Slow motion

; Open the browser and navigate to the URL
Run("C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe https://www.trade.gov/data-visualization/csl-search")

Local $hWnd = WinWaitActive("CSL Search", "", 5) ; Wait Max 5 sec for the window title

If $hWnd Then
    Send("{TAB 19}") ; go to the name field
    Send("Kromlüks") ; set the name

    Send("{TAB 5}") ; go to the search button
    Send("{ENTER}") ; execute the search
Else
    ConsoleWrite("I can't find the 'CSL Search' window." & @CRLF)
EndIf

 

Thank you very much for your support. I was actually using a similar scenario myself, but in a video I saw that it’s possible to interact with websites using element IDs, which is why I’ve started researching this approach.

I don't have much coding knowledge, but as you can see, my current scenario isn’t very complex. I plan to improve and develop it further later on.

Edited Friday at 12:06 PM by mustilem23

[argumentum]

29 minutes ago, mustilem23 said:

in a video I saw that it’s possible to interact with websites using element IDs

it may be an old video ? It may not apply to 2025

29 minutes ago, mustilem23 said:

don't have much coding knowledge, but as you can see, my current scenario isn’t very complex.

yes, and you'll need to use what @nine told you.

31 minutes ago, mustilem23 said:

I plan to improve and develop it further later on.

..later on today, this week, as an entry in a bucket list ?

I'd personally do what @ioa747 told you ( in code ) and add send Ctrl-A to select all, then Ctrl-C to copy to clipboard the text.
Because I never used the WebDriver and this copy and paste is easier to a new coder ( you ). Admittedly the WebDriver is the better approach if you know what you're doing.

And seeing what you did on the other thread you show to be very inexperienced, hence this commentary to you.

Ok, good luck and have fun  

[Nine]

Here to start you up.  This is meant to show you that it is not complicated to accomplish what you want :

#include "wd_helper.au3"

Local $sDesiredCapabilities = SetupChrome()
_WD_Startup()
Local $sSession = _WD_CreateSession($sDesiredCapabilities)

_WD_Navigate($sSession, "https://www.trade.gov/data-visualization/csl-search")
_WD_FrameEnter($sSession, 0)
Local $sElement = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//input[@id='name']")
ConsoleWrite($sElement & @CRLF)
_WD_ElementAction($sSession, $sElement, 'value', "Test")

;_WD_DeleteSession($sSession)
_WD_Shutdown()

Func SetupChrome()
  _WD_Option('Driver', 'chromedriver.exe')
  _WD_Option('Port', 9515)
  _WD_Option('DriverParams', '--port=9515 --verbose --log-path="' & @ScriptDir & '\chrome.log"')
  Return '{"capabilities": {"alwaysMatch": {"goog:chromeOptions": {"w3c": true, "excludeSwitches": ["enable-automation"]}}}}'
EndFunc   ;==>SetupChrome

 

Edited Friday at 03:52 PM by Nine

[SOLVE-SMART]

43 minutes ago, Nine said:

This is meant to show you that it is not complicated to accomplish what you want

As long as @mustilem23 knows all the dependencies of the au3WebDriver (WebDriver) project 🤭 . But yes, you're right (like so often), it's not that complicated as long as the documentation is read and understood. At least for the start.

Best regards
Sven